build.gradle

buildscript {
    repositories {
        mavenCentral()
        jcenter()
    }
    dependencies {
        classpath 'com.android.tools.build:gradle:2.3.0'
    }
}

allprojects {
    repositories {
        mavenCentral()
        maven {
            url 'https://oss.sonatype.org/content/repositories/snapshots/'
        }
        flatDir {
            dirs 'libs'
        }
    }
}

apply plugin: 'com.android.application'

File keystoreProperties = rootProject.file("keystore.properties")
def props = new Properties()
if (keystoreProperties.exists()) {
    props.load(new FileInputStream(keystoreProperties))
} else {
    props['keystorefile'] = 'none';
}

android {
    compileSdkVersion 25
    buildToolsVersion '25.0.2'

    defaultConfig {
        minSdkVersion 14
        targetSdkVersion 25
        versionCode System.getenv("BUILD_NUMBER") as Integer ?: 291
        versionName "8.8.1"
    }

    File keystore = new File(props['keystorefile'])
    if (keystore.exists()) {
        signingConfigs {
            release {
                storeFile keystore
                storePassword props['keystorepassword']
                keyAlias props['keyalias']
                keyPassword props['keypassword']
            }
            debug {
                storeFile file("debug.keystore")
                storePassword "android"
                keyAlias "androiddebugkey"
                keyPassword "android"
            }
        }

        buildTypes {
            debug {
                signingConfig signingConfigs.debug
            }
            release {
                minifyEnabled false
                signingConfig signingConfigs.release
            }
        }
    } else {
        signingConfigs {
            debug {
                storeFile file("debug.keystore")
                storePassword "android"
                keyAlias "androiddebugkey"
                keyPassword "android"
            }
        }
        buildTypes {
            debug {
                signingConfig signingConfigs.debug
            }
        }
    }

    lintOptions {
        abortOnError false
    }
}

dependencies {

    compile 'com.android.support:support-v13:25.0.0'
    compile 'com.astuetz:pagerslidingtabstrip:1.0.1'
    compile 'com.github.castorflex.smoothprogressbar:library:0.5.1'
    compile 'com.pushbullet:android-extensions:1.0.4@aar'
    compile 'com.klinkerapps:android-smsmms:0.1.3-SNAPSHOT@aar'
    compile 'com.klinkerapps:logger:1.0.3'
    compile 'com.google.code.gson:gson:2.2.4'
    compile 'com.koushikdutta.ion:ion:1.1.7'

    compile files('libs/android-vcard.jar')
    compile files('libs/dashclock-api-r2.0.jar')
    compile files('libs/dropbox-android-sdk-1.5.4.jar')
    compile files('libs/httpmime-4.0.3.jar')
    compile files('libs/json_simple-1.1.jar')
    compile files('libs/jsoup-1.7.2.jar')
    compile files('libs/stickygridheaders.jar')

    compile(name:'datetimepicker', ext:'aar')
    compile(name:'android-photoview', ext:'aar')
    compile(name:'CardsUILib', ext:'aar')
    compile(name:'fn-extension', ext:'aar')
    compile(name:'slidingmenu', ext:'aar')
    compile(name:'AppMsg', ext:'aar')
    compile(name:'android-ColorPickerPreference', ext:'aar')
    compile(name:'MessageBar', ext:'aar')
    compile(name:'MultipleImagePick', ext:'aar')
    compile(name:'android-lockpattern', ext:'aar')
    compile(name:'listviewanimations-2.6.0', ext:'aar')
    compile(name:'dragsortlistview', ext:'aar')
}