forked from robertstarr/ulp_user
-
Notifications
You must be signed in to change notification settings - Fork 0
/
Copy patheagle2svg-1_4_1.ulp
1385 lines (1202 loc) · 32 KB
/
eagle2svg-1_4_1.ulp
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
347
348
349
350
351
352
353
354
355
356
357
358
359
360
361
362
363
364
365
366
367
368
369
370
371
372
373
374
375
376
377
378
379
380
381
382
383
384
385
386
387
388
389
390
391
392
393
394
395
396
397
398
399
400
401
402
403
404
405
406
407
408
409
410
411
412
413
414
415
416
417
418
419
420
421
422
423
424
425
426
427
428
429
430
431
432
433
434
435
436
437
438
439
440
441
442
443
444
445
446
447
448
449
450
451
452
453
454
455
456
457
458
459
460
461
462
463
464
465
466
467
468
469
470
471
472
473
474
475
476
477
478
479
480
481
482
483
484
485
486
487
488
489
490
491
492
493
494
495
496
497
498
499
500
501
502
503
504
505
506
507
508
509
510
511
512
513
514
515
516
517
518
519
520
521
522
523
524
525
526
527
528
529
530
531
532
533
534
535
536
537
538
539
540
541
542
543
544
545
546
547
548
549
550
551
552
553
554
555
556
557
558
559
560
561
562
563
564
565
566
567
568
569
570
571
572
573
574
575
576
577
578
579
580
581
582
583
584
585
586
587
588
589
590
591
592
593
594
595
596
597
598
599
600
601
602
603
604
605
606
607
608
609
610
611
612
613
614
615
616
617
618
619
620
621
622
623
624
625
626
627
628
629
630
631
632
633
634
635
636
637
638
639
640
641
642
643
644
645
646
647
648
649
650
651
652
653
654
655
656
657
658
659
660
661
662
663
664
665
666
667
668
669
670
671
672
673
674
675
676
677
678
679
680
681
682
683
684
685
686
687
688
689
690
691
692
693
694
695
696
697
698
699
700
701
702
703
704
705
706
707
708
709
710
711
712
713
714
715
716
717
718
719
720
721
722
723
724
725
726
727
728
729
730
731
732
733
734
735
736
737
738
739
740
741
742
743
744
745
746
747
748
749
750
751
752
753
754
755
756
757
758
759
760
761
762
763
764
765
766
767
768
769
770
771
772
773
774
775
776
777
778
779
780
781
782
783
784
785
786
787
788
789
790
791
792
793
794
795
796
797
798
799
800
801
802
803
804
805
806
807
808
809
810
811
812
813
814
815
816
817
818
819
820
821
822
823
824
825
826
827
828
829
830
831
832
833
834
835
836
837
838
839
840
841
842
843
844
845
846
847
848
849
850
851
852
853
854
855
856
857
858
859
860
861
862
863
864
865
866
867
868
869
870
871
872
873
874
875
876
877
878
879
880
881
882
883
884
885
886
887
888
889
890
891
892
893
894
895
896
897
898
899
900
901
902
903
904
905
906
907
908
909
910
911
912
913
914
915
916
917
918
919
920
921
922
923
924
925
926
927
928
929
930
931
932
933
934
935
936
937
938
939
940
941
942
943
944
945
946
947
948
949
950
951
952
953
954
955
956
957
958
959
960
961
962
963
964
965
966
967
968
969
970
971
972
973
974
975
976
977
978
979
980
981
982
983
984
985
986
987
988
989
990
991
992
993
994
995
996
997
998
999
1000
#usage "<b>Eagle schematic exporting tool version 1.4 </b>\n"
"<p>"
"This ULP can convert an Eagle CAD schematics into SVG files."
"<p>"
"Load any schematic and execute the ULP in the eagle."
"<p>"
"<author>Author: xtitoris</author><br>"
"based on eagle2svg by [email protected]<br>"
"<br>"
"Known issues in board export:<ul>"
"<li>elongated pads are not supported"
"<li>layers are not placed correctly"
"</ul>"
real VERSION = 1.4;
string DESCR = "";
/*
* CHANGELOG================================================
* 1.4 (15.07.2012): Added support for all text alignments, fixed text, drill holes, white colored wires (as in native print-to-pdf, exports as black), zero-width wires
* 1.3 (02.07.2012): Fixed pads output, added dimensions output for Eagle 6
* 1.2 (29.11.2010): Fixed drill holes, optimized stylesheet generation
* 1.1 (??.04.2008): SVG export for board files
* 1.0 (16.04.2008): Some bugfixes
* 0.2 (11.04.2008): Using CSS for layer-styles
* 0.1 (08.03.2008): Initial version
*
*/
/* ==========================================================================
* License: This file is released under the license of the GNU Public license
* Version 2.
* ==========================================================================*/
int g_monochrome = 0;
int g_only_visible = 1;
int g_used_layers[];
int zero_width = 1600;
//------------------------------------------------------
// generate html color code
//------------------------------------------------------
string htmlcolor(int col)
{
string result;
sprintf(result, "#%06x", col);
return result;
}
//------------------------------------------------------
// replace xml reserved chars and build 2-byte utf-8 characters
//------------------------------------------------------
string encodeText(string strText)
{
string newText = "";
int i=0;
while (strText[i])
{
char c = strText[i++];
switch(c)
{
case '<': newText += "<"; break;
case '>': newText += ">"; break;
case '&': newText += "&"; break;
case '°': newText += "°"; break;
default:
if (c>=0xc0)
{
newText += char(0xc3);
newText += char(c-0x40);
}
else if (c>=0x80)
{
newText += char(0xc2);
newText += char(c);
}
else
{
newText += c;
}
}
}
return newText;
}
//------------------------------------------------------
// SVG output functions
//------------------------------------------------------
string svgLineStyle(int width, int cap)
{
string lineCap;// = "round";
switch (cap)
{
case CAP_FLAT: lineCap = "butt"; break;
case CAP_ROUND: lineCap = "round"; break;
default: lineCap = "round"; break;
}
//Zero-width line fix.
//TODO: Move to options?
if (width == 0)
width = zero_width;
string style;
sprintf(style, "stroke-width:%f; stroke-linecap:%s",
u2mm(width), lineCap);
return style;
}
string svgTransform(int x, int y, real angle)
{
string trans, rot, res;
sprintf(trans, "translate(%f,%f)", u2mm(x), u2mm(-y));
sprintf(rot, "rotate(%f)", -angle);
return "transform='"+trans+" "+rot+"'";
}
void svgWriteLine(int x1, int y1, int x2, int y2, int layer, string style)
{
printf("<line class='l%d' x1='%f' y1='%f' x2='%f' y2='%f' style='%s'/>\n",
layer,
u2mm(x1), u2mm(-y1),
u2mm(x2), u2mm(-y2),
style);
}
void svgWriteArc(int x1, int y1, int x2, int y2, int radius, char longpath, int layer, string style)
{
printf("<path class='l%d' d='M %f,%f A %f %f 0 %c 0 %f,%f' style='%s'/>\n",
layer,
u2mm(x1), u2mm(-y1),
u2mm(radius), u2mm(radius),
longpath,
u2mm(x2), u2mm(-y2),
style);
}
void svgWriteRect(int x1, int y1, int x2, int y2, real angle, int layer)
{
string rotation="";
if (angle!=0.0)
{
sprintf(rotation, " transform='rotate(%f,%f,%f)'",
-angle,
u2mm(x1+x2)/2.0, u2mm(-y1-y2)/2.0);
}
printf("<rect class='l%d' x='%f' y='%f' width='%f' height='%f'%s/>\n",
layer,
u2mm(x1), u2mm(-y2),
u2mm(x2-x1), u2mm(y2-y1),
rotation);
}
void svgWriteRectCenter(int x, int y, int dx, int dy, real angle, int layer)
{
string rotation = svgTransform(x, y, angle);
printf("<rect class='l%d' x='%f' y='%f' width='%f' height='%f' %s/>\n",
layer,
u2mm(-dx/2), u2mm(-dy/2),
u2mm(dx), u2mm(dy),
rotation);
}
void svgWriteOctCenter(int x, int y, int dx, int dy, real angle, int layer)
{
string rotation = svgTransform(x, y, angle);
real x1 = u2mm(dx)/2;
real y1 = u2mm(dy)/2;
real x2 = u2mm(dx)/(2*(1+1.414213562));
real y2 = u2mm(dy)/(2*(1+1.414213562));
printf("<polygon class='l%d' points='%f %f, %f %f, %f %f, %f %f, %f %f, %f %f, %f %f, %f %f' %s/>\n",
layer,
-x1, -y2,
-x2, -y1,
x2, -y1,
x1, -y2,
x1, y2,
x2, y1,
-x2, y1,
-x1, y2,
rotation);
}
void svgWriteRoundRectCenter(int x, int y, int w, int h, int roundness, real angle, int layer)
{
//if any of that is 0 do nothing
if (x & y & w & h == 0)
{ return; }
string rotation = svgTransform(x, y, angle);
if (w<h)
{ roundness = w*roundness/200; }
else
{ roundness = h*roundness/200; }
printf("<rect class='l%d' x='%f' y='%f' width='%f' height='%f' rx='%f' %s/>\n",
layer,
u2mm(-w/2), u2mm(-h/2),
u2mm(w), u2mm(h),
u2mm(roundness),
rotation);
}
void svgWriteDot(int x, int y, int diameter, int layer)
{
printf("<circle class='j%d' cx='%f' cy='%f' r='%f'/>\n",
layer,
u2mm(x), u2mm(-y),
u2mm(diameter)/2.0);
}
void svgWriteCircle(int x, int y, int radius, int lwidth, int layer)
{
if (lwidth == 0)
{
svgWriteDot(x, y, 2*radius, layer);
return;
}
printf("<circle class='l%d' cx='%f' cy='%f' r='%f' style='stroke-width:%f'/>\n",
layer,
u2mm(x), u2mm(-y),
u2mm(radius),
u2mm(lwidth));
}
void svgWriteText(string text, int x, int y, real angle, int size, int align, int valign, int xflip, int layer, int font)
{
string style;
sprintf(style, "font-size:%fpt;", u2mm(size)*1.1);
if (font==FONT_FIXED)
{style+="font-family:courier new;";}
int dy = 0;
if (align == -1)
{ style += " text-anchor:end;"; }
else if (align == 0)
{ style += " text-anchor:middle;"; }
if (valign == -1)
{ dy = size;}
else if (valign == 0)
{ dy = size/2; }
string trn1 = ""; //translate position
string rot = ""; //rotate
string scl = ""; //flip
string trn2 = ""; //translate valign
sprintf(trn1, "translate(%f, %f)", u2mm(x), u2mm(-y));
if (angle!=0)
{ sprintf(rot, " rotate(%f)", angle); }
if (xflip!=1)
{ sprintf(scl, " scale(%d, 1)", xflip); }
if (dy!=0)
{ sprintf(trn2," translate(0, %f)", u2mm(dy)); }
printf( "<text class='l%d' style='%s' transform='%s%s%s%s'>%s</text>\n",
layer,
style,
trn1, rot, scl, trn2,
text);
}
void svgWritePathStart(int layer, string style)
{
printf( "<path class='l%d' style='%s' d='", layer, style);
}
void svgWritePathLine(int x1, int y1, int x2, int y2)
{
printf( " M %f,%f L %f,%f", u2mm(x1), u2mm(-y1), u2mm(x2), u2mm(-y2));
}
void svgWritePathArc(int x1, int y1, int x2, int y2, int radius, char longpath)
{
printf(" M %f,%f A %f %f 0 %c 0 %f,%f",
u2mm(x1), u2mm(-y1),
u2mm(radius), u2mm(radius),
longpath,
u2mm(x2), u2mm(-y2));
}
void svgWritePathEnd()
{
printf( "'/>\n");
}
//------------------------------------------------------
// write UL piece
//------------------------------------------------------
void write_piece(UL_WIRE W)
{
if (g_used_layers[W.layer]==0)
{ return; }
string style = svgLineStyle(W.width, W.cap);
if (W.arc)
{
char longpath;
if( abs(W.arc.angle2-W.arc.angle1) < 180.0 )
{
longpath='0';
}
else
{
longpath='1';
}
svgWriteArc(W.arc.x1, W.arc.y1, W.arc.x2, W.arc.y2, W.arc.radius, longpath, W.layer, style);
}
else
{
svgWriteLine(W.x1, W.y1, W.x2, W.y2, W.layer, style);
}
}
//------------------------------------------------------
// write UL piece
//------------------------------------------------------
void write_piece_segment(UL_WIRE W)
{
if (g_used_layers[W.layer]==0)
{ return; }
if (W.arc)
{
char longpath;
if( abs(W.arc.angle2-W.arc.angle1) < 180.0 )
{ longpath='0'; }
else
{ longpath='1'; }
svgWritePathArc(W.arc.x1, W.arc.y1, W.arc.x2, W.arc.y2, W.arc.radius, longpath);
}
else
{
svgWritePathLine(W.x1, W.y1, W.x2, W.y2);
}
}
//------------------------------------------------------
// write UL wire
//------------------------------------------------------
void write_wire(UL_WIRE W)
{
if (g_used_layers[W.layer]==0)
{ return; }
if ( W.style == WIRE_STYLE_LONGDASH || W.style == WIRE_STYLE_SHORTDASH || W.style == WIRE_STYLE_DASHDOT )
{
W.pieces(P)
{
write_piece(P);
}
}
else if (W.arc)
{
string style = svgLineStyle(W.arc.width, W.cap);
char longpath;
if( abs(W.arc.angle2-W.arc.angle1) < 180.0 )
{
longpath='0';
}
else
{
longpath='1';
}
svgWriteArc(W.arc.x1, W.arc.y1, W.arc.x2, W.arc.y2, W.arc.radius, longpath, W.layer, style);
}
else
{
string style = svgLineStyle(W.width, W.cap);
svgWriteLine(W.x1, W.y1, W.x2, W.y2, W.layer, style);
}
}
//------------------------------------------------------
// write UL wire
//------------------------------------------------------
void write_wire_segment(UL_WIRE W)
{
if (g_used_layers[W.layer]==0)
{ return; }
if ( W.style == WIRE_STYLE_LONGDASH || W.style == WIRE_STYLE_SHORTDASH || W.style == WIRE_STYLE_DASHDOT )
{
W.pieces(P)
{ write_piece(P); }
}
else if (W.arc)
{
char longpath;
if( abs(W.arc.angle2-W.arc.angle1) < 180.0 )
{ longpath='0'; }
else
{ longpath='1'; }
svgWritePathArc(W.arc.x1, W.arc.y1, W.arc.x2, W.arc.y2, W.arc.radius, longpath);
}
else
{
svgWritePathLine(W.x1, W.y1, W.x2, W.y2);
}
}
//------------------------------------------------------
// write UL rectangle
//------------------------------------------------------
void write_rectangle(UL_RECTANGLE R)
{
if (g_used_layers[R.layer]==0)
{ return; }
svgWriteRect(R.x1, R.y1, R.x2, R.y2, R.angle, R.layer);
}
//------------------------------------------------------
// write UL vector text
//------------------------------------------------------
void write_vector_text(UL_TEXT T)
{
int cnt=0;
T.wires(W)
{
string lineCap;
if (cnt==0)
{
string style = svgLineStyle(W.width, W.cap);
svgWritePathStart(W.layer, style);
}
svgWritePathLine(W.x1, W.y1, W.x2, W.y2);
cnt++;
}
if (cnt>0)
{
svgWritePathEnd();
}
}
//------------------------------------------------------
// write UL proportional text
//------------------------------------------------------
void write_prop_text(UL_TEXT T)
{
string newText = encodeText(T.value);
int posX = T.x;
int posY = T.y;
int textAngle = T.angle;
int textSize = T.size;
int hmodei, vmodei; //1:bottom left, 0:center, -1:top right
hmodei = 1;
vmodei = 1;
int xflip = 1;
switch(T.align)
{
case 0: break; //ALIGN_BOTTOM_LEFT:
case 1: hmodei = 0; break; //ALIGN_BOTTOM_CENTER:
case 2: hmodei = -1; break; //ALIGN_BOTTOM_RIGHT:
case 3: vmodei = 0; break; //ALIGN_CENTER_LEFT:
case 4: vmodei = 0; hmodei = 0; break; //ALIGN_CENTER:
case 5: vmodei = 0; hmodei = -1; break; //ALIGN_CENTER_RIGHT:
case 6: vmodei = -1; break; //ALIGN_TOP_LEFT:
case 7: vmodei = -1; hmodei = 0; break; //ALIGN_TOP_CENTER:
case 8: vmodei = -1; hmodei = -1; break;//ALIGN_TOP_RIGHT:
}
if (textAngle > 90 && textAngle < 270 && T.spin == 0)
{
hmodei *= -1;
vmodei *= -1;
textAngle -= 180;
}
if (T.mirror > 0)
{
xflip = -1;
textAngle = -textAngle;
}
svgWriteText(newText, posX, posY, -textAngle, textSize, hmodei, vmodei, xflip, T.layer, T.font);
}
//------------------------------------------------------
// write UL general text
//------------------------------------------------------
void write_text(UL_TEXT T)
{
if (g_used_layers[T.layer] == 0)// && (current_layer != 0 || T.layer != current_layer))
{ return; }
if (T.font==FONT_VECTOR)
{
write_vector_text(T);
}
else
{
write_prop_text(T);
}
}
//------------------------------------------------------
// write UL circle
//------------------------------------------------------
void write_circle(UL_CIRCLE C)
{
if (g_used_layers[C.layer]==0)
{ return; }
svgWriteCircle(C.x, C.y, C.radius, C.width, C.layer);
}
//------------------------------------------------------
// write drillsymbol
//------------------------------------------------------
void write_drill(int x, int y, int drill, int layer)
{
if (g_used_layers[layer]==0)
{ return; }
string style = svgLineStyle(mm2u(0.0254), CAP_ROUND);
int d = mm2u(1.02);
int r = mm2u(0.99);
svgWritePathStart(layer, style);
//TODO: Replace with rotations
switch (drill)
{
case 1:
svgWritePathLine(x-d, y, x+d, y);
svgWritePathLine(x, y-d, x, y+d);
break;
case 2:
svgWritePathLine(x-d, y-d, x+d, y+d);
svgWritePathLine(x-d, y+d, x+d, y-d);
break;
case 3:
svgWritePathLine(x-d, y-d, x-d, y+d);
svgWritePathLine(x+d, y-d, x+d, y+d);
svgWritePathLine(x-d, y-d, x+d, y-d);
svgWritePathLine(x-d, y+d, x+d, y+d);
svgWritePathLine(x, y, x, y+d);
break;
case 4:
svgWritePathLine(x-d, y, x, y-d);
svgWritePathLine(x+d, y, x, y+d);
svgWritePathLine(x, y-d, x+d, y);
svgWritePathLine(x, y+d, x-d, y);
svgWritePathLine(x, y, x, y+d);
break;
case 5:
svgWritePathLine(x-d, y-d, x+d, y+d);
svgWritePathLine(x-d, y+d, x+d, y-d);
svgWritePathLine(x-d, y-d, x+d, y-d);
svgWritePathLine(x-d, y+d, x+d, y+d);
break;
case 6:
svgWritePathLine(x-d, y-d, x+d, y+d);
svgWritePathLine(x-d, y+d, x+d, y-d);
svgWritePathLine(x-d, y-d, x-d, y+d);
svgWritePathLine(x+d, y-d, x+d, y+d);
break;
case 7:
svgWritePathLine(x-d, y, x+d, y);
svgWritePathLine(x, y-d, x, y+d);
svgWritePathLine(x-d, y, x, y-d);
svgWritePathLine(x+d, y, x, y+d);
break;
case 8:
svgWritePathLine(x-d, y, x+d, y);
svgWritePathLine(x, y-d, x, y+d);
svgWritePathLine(x, y-d, x+d, y);
svgWritePathLine(x, y+d, x-d, y);
break;
case 9:
svgWritePathLine(x-d, y-d, x+d, y+d);
svgWritePathLine(x-d, y+d, x+d, y-d);
svgWritePathLine(x, y+d, x, y-d);
break;
case 10:
svgWritePathLine(x-d, y-d, x+d, y+d);
svgWritePathLine(x-d, y+d, x+d, y-d);
svgWritePathLine(x-d, y, x+d, y);
break;
case 11:
svgWritePathLine(x-d, y+d, x+d, y+d);
svgWritePathLine(x+d, y+d, x, y);
svgWritePathLine(x-d, y+d, x, y);
svgWritePathLine(x, y, x, y-d);
break;
case 12:
svgWritePathLine(x-d, y-d, x+d, y-d);
svgWritePathLine(x+d, y-d, x, y);
svgWritePathLine(x-d, y-d, x, y);
svgWritePathLine(x, y, x, y+d);
break;
case 13:
svgWritePathLine(x+d, y+d, x+d, y-d);
svgWritePathLine(x+d, y+d, x, y);
svgWritePathLine(x+d, y-d, x, y);
svgWritePathLine(x-d, y, x, y);
break;
case 14:
svgWritePathLine(x-d, y+d, x-d, y-d);
svgWritePathLine(x-d, y+d, x, y);
svgWritePathLine(x-d, y-d, x, y);
svgWritePathLine(x, y, x+d, y);
break;
case 15:
svgWritePathLine(x-d, y, x+d, y);
svgWritePathLine(x, y-d, x, y+d);
svgWritePathArc(x-d, y-1, x-d, y+1, r, '1');
break;
case 16:
svgWritePathLine(x-d, y, x+d, y);
svgWritePathLine(x, y-d, x, y+d);
svgWritePathArc(x-d, y-1, x-d, y+1, r, '1');
svgWritePathArc(x-d/2, y-1, x-d/2, y+1, r/2, '1');
break;
case 0:
svgWritePathLine(x-d, y-d, x+d, y+d);
svgWritePathArc(x-d, y-1, x-d, y+1, r, '1');
break;
}
svgWritePathEnd();
}
//------------------------------------------------------
// write restring
//------------------------------------------------------
void write_restring(int x, int y, int diameter, int shape, int long, real angle, int layer)
{
switch(shape)
{
case PAD_SHAPE_SQUARE:
svgWriteRectCenter(x, y, diameter, diameter, angle, layer);
break;
case PAD_SHAPE_OCTAGON:
svgWriteOctCenter(x, y, diameter, diameter, angle, layer);
break;
case PAD_SHAPE_LONG:
svgWriteRoundRectCenter(x, y, (diameter*long)/100, diameter, 100, angle, layer);
break;
case PAD_SHAPE_OFFSET:
case PAD_SHAPE_ANNULUS:
case PAD_SHAPE_THERMAL:
case PAD_SHAPE_ROUND:
default:
svgWriteDot(x, y, diameter, layer);
}
}
//------------------------------------------------------
// write UL pad
//------------------------------------------------------
void write_pad(UL_PAD P)
{
int layer;
if (P.flags&PAD_FLAG_STOP)
{
if (g_used_layers[LAYER_TSTOP])
{ write_restring(P.x, P.y, P.diameter[LAYER_TSTOP], P.shape[LAYER_TSTOP], 100+P.elongation, P.angle, LAYER_TSTOP); }
if (g_used_layers[LAYER_BSTOP])
{ write_restring(P.x, P.y, P.diameter[LAYER_BSTOP], P.shape[LAYER_BSTOP], 100+P.elongation, P.angle, LAYER_BSTOP); }
}
for (layer=LAYER_TOP; layer<=LAYER_BOTTOM ; ++layer)
{
if (g_used_layers[layer])
{
write_restring(P.x, P.y, P.diameter[layer], P.shape[layer], 100+P.elongation, P.angle, layer);
}
}
if (g_used_layers[LAYER_PADS])
{
int diameter = P.diameter[LAYER_PADS];
//Hack for pads layer
if (diameter == 0)
{ diameter = P.diameter[LAYER_TOP]; }
write_restring(P.x, P.y, diameter, P.shape[layer], 100+P.elongation, P.angle, layer);
svgWriteDot(P.x, P.y, P.drill, 0);
}
write_drill(P.x, P.y, P.drillsymbol, LAYER_DRILLS);
}
//------------------------------------------------------
// write UL smd
//------------------------------------------------------
void write_smd(UL_SMD S)
{
if (S.layer==LAYER_TOP)
{
if (g_used_layers[LAYER_TOP])
{ svgWriteRoundRectCenter(S.x, S.y, S.dx[LAYER_TOP], S.dy[LAYER_TOP], S.roundness, S.angle, LAYER_TOP); }
if (g_used_layers[LAYER_TSTOP])
{ svgWriteRoundRectCenter(S.x, S.y, S.dx[LAYER_TSTOP], S.dy[LAYER_TSTOP], S.roundness, S.angle, LAYER_TSTOP); }
if (g_used_layers[LAYER_TCREAM])
{ svgWriteRoundRectCenter(S.x, S.y, S.dx[LAYER_TCREAM], S.dy[LAYER_TCREAM], S.roundness, S.angle, LAYER_TCREAM); }
}
else if (S.layer==LAYER_BOTTOM)
{
if (g_used_layers[LAYER_BCREAM])
{ svgWriteRoundRectCenter(S.x, S.y, S.dx[LAYER_BCREAM], S.dy[LAYER_BCREAM], S.roundness, S.angle, LAYER_BCREAM); }
if (g_used_layers[LAYER_BSTOP])
{ svgWriteRoundRectCenter(S.x, S.y, S.dx[LAYER_BSTOP], S.dy[LAYER_BSTOP], S.roundness, S.angle, LAYER_BSTOP); }
if (g_used_layers[LAYER_BOTTOM])
{ svgWriteRoundRectCenter(S.x, S.y, S.dx[LAYER_BOTTOM], S.dy[LAYER_BOTTOM], S.roundness, S.angle, LAYER_BOTTOM); }
}
}
//------------------------------------------------------
// write UL via
//------------------------------------------------------
void write_via(UL_VIA V)
{
int layer;
if (V.flags&VIA_FLAG_STOP)
{
if (g_used_layers[LAYER_TSTOP])
{ write_restring(V.x, V.y, V.diameter[LAYER_TSTOP], V.shape[LAYER_TSTOP], 100, 0.0, LAYER_TSTOP); }
if (g_used_layers[LAYER_BSTOP])
{ write_restring(V.x, V.y, V.diameter[LAYER_BSTOP], V.shape[LAYER_BSTOP], 100, 0.0, LAYER_BSTOP); }
}
for (layer=V.start; layer<=V.end; ++layer)
{
if (g_used_layers[layer])
{
write_restring(V.x, V.y, V.diameter[layer], V.shape[layer], 100, 0.0, layer);
}
}
if (g_used_layers[LAYER_VIAS])
{ svgWriteDot(V.x, V.y, V.drill, 0); }
write_drill(V.x, V.y, V.drillsymbol, LAYER_DRILLS);
}
//------------------------------------------------------
// write UL hole
//------------------------------------------------------
void write_hole(UL_HOLE H)
{
svgWriteCircle(H.x, H.y, H.drill/2, zero_width, LAYER_DIMENSION);
write_drill(H.x, H.y, H.drillsymbol, LAYER_HOLES);
}
//------------------------------------------------------
// write UL segment
//------------------------------------------------------
void write_segment(UL_SEGMENT SEG)
{
int layer = 0;
SEG.wires(W)
{
layer = W.layer;
write_wire(W);
}
SEG.junctions(J)
{
svgWriteDot(J.x, J.y, J.diameter, layer);
}
SEG.texts(T)
{
write_text(T);
}
}
//------------------------------------------------------
// write UL polygon
//------------------------------------------------------
void write_polygon(UL_POLYGON P)
{
if (g_used_layers[P.layer]==0)
{
return;
}
int count = 0;
printf( "<polygon class='l%d' points='", P.layer);
P.wires(W)
{
if (count == 0)
{
printf( "%f %f", u2mm(W.x1), u2mm(-W.y1));
}
else
{
printf( ", %f %f", u2mm(W.x1), u2mm(-W.y1));
}
++count;
}
printf( "'/>\n" );
}
//------------------------------------------------------
// write filled UL polygon
//------------------------------------------------------
void write_filled_polygon(UL_POLYGON P)
{
if (g_used_layers[P.layer]==0)
{ return; }
string style;
int first=1;
P.contours(W)
{
if (first)
{
string style = svgLineStyle(W.width, W.cap);
svgWritePathStart(P.layer, style);
first=0;
}
svgWritePathLine(W.x1, W.y1, W.x2, W.y2);
}
P.fillings(W)
{
svgWritePathLine(W.x1, W.y1, W.x2, W.y2);
}
svgWritePathEnd();
}
//------------------------------------------------------
// write UL bus
//------------------------------------------------------
void write_bus(UL_BUS B)
{
printf("<g><title>BUS %s</title>\n", encodeText(B.name));
B.segments(SEG) { write_segment(SEG); }
printf("</g>\n");
}
//------------------------------------------------------
// write UL net
//------------------------------------------------------
void write_net(UL_NET N)
{
printf("<g><title>NET %s</title>\n", encodeText(N.name));
N.segments(SEG) { write_segment(SEG); }
printf("</g>\n");
}
//------------------------------------------------------
//write UL signal
//------------------------------------------------------
void write_signal(UL_SIGNAL S)
{
S.polygons(P) {write_filled_polygon(P);}
S.wires(W) {write_wire(W);}
S.vias(V) {write_via(V);}
}
//------------------------------------------------------
//write UL pin
//------------------------------------------------------
void write_pin(UL_PIN P)
{
P.wires(W) {write_wire(W);}
P.circles(C) {write_circle(C);}
P.texts(T) {write_text(T);}
}
//------------------------------------------------------
//write UL symbol
//------------------------------------------------------
void write_symbol(UL_SYMBOL S)
{
S.polygons(P) {write_polygon(P);}
S.circles(C) {write_circle(C);}
S.rectangles(R) {write_rectangle(R);}
S.pins(P) {write_pin(P);}
S.wires(W) {write_wire(W);}
S.texts(T) {write_text(T);}
}
//------------------------------------------------------
//write UL gate
//------------------------------------------------------
void write_gate(UL_GATE G)
{
write_symbol(G.symbol);
}
//------------------------------------------------------
//write UL instance
//------------------------------------------------------
void write_instance(UL_INSTANCE I)
{
printf("<g><title>PART %s</title>\n", encodeText(I.name));
write_gate(I.gate);
I.texts(T) {write_text(T);}
printf("</g>\n");
}
//------------------------------------------------------
//write UL part
//------------------------------------------------------
void write_part(UL_PART P)
{
P.instances(I)
{
write_instance(I);
}
}
//------------------------------------------------------
//write UL contact
//------------------------------------------------------
void write_contact(UL_CONTACT C)
{
if (C.pad)
write_pad(C.pad);
else if (C.smd)
write_smd(C.smd);
}
//------------------------------------------------------
//write UL package
//------------------------------------------------------
void write_package(UL_PACKAGE PKG)
{
PKG.polygons(P) {write_polygon(P);}
PKG.rectangles(R) {write_rectangle(R);}
PKG.wires(W) {write_wire(W);}
PKG.circles(C) {write_circle(C);}
PKG.texts(T) {write_text(T);}
PKG.contacts(C) {write_contact(C);}
PKG.holes(H) {write_hole(H);}
}
//------------------------------------------------------
//write UL element
//------------------------------------------------------
void write_element(UL_ELEMENT E)
{
printf("<g><title>PART %s</title>\n", encodeText(E.name));
E.texts(T) {write_text(T);}
write_package(E.package);
printf("</g>\n");
}
//------------------------------------------------------
//write UL dimension
//------------------------------------------------------
void write_dimension(UL_DIMENSION D)
{
if (g_used_layers[D.layer] == 0)// && D.layer != layer)
{ return; }
printf("<g><title>DIMENSION</title>\n");
D.texts(T)
{
write_text(T);
}
int cnt = 0;
D.wires(W)