build.gradle

apply plugin: 'scala'

buildscript {
    repositories {
        mavenCentral()
        maven {
            name = "forge"
            url = "http://files.minecraftforge.net/maven"
        }
        maven {
            name = "sonatype"
            url = "https://oss.sonatype.org/content/repositories/snapshots/"
        }
    }
    dependencies {
        classpath 'net.minecraftforge.gradle:ForgeGradle:1.2-SNAPSHOT'
    }
}

apply plugin: 'forge'


version = "bash get_mod_version.bash".execute().text
group= "tk.monnef.jaffas"
archivesBaseName = "jaffas"

minecraft {
    version = "1.7.10-10.13.0.1180"
    assetDir = "eclipse/assets"
}

processResources
{
    // this will ensure that this task is redone when the versions change.
    inputs.property "version", project.version
    inputs.property "mcversion", project.minecraft.version

    // replace stuff in mcmod.info, nothing else
    from(sourceSets.main.resources.srcDirs) {
        include 'mcmod.info'
                
        // replace version and mcversion
        expand 'version':project.version, 'mcversion':project.minecraft.version
    }
        
    // copy everything else, thats not the mcmod.info
    from(sourceSets.main.resources.srcDirs) {
        exclude 'mcmod.info'
    }
}

// joint compilation
sourceSets.main.scala.srcDir "src/main/java"
sourceSets.main.java.srcDirs = []

dependencies {
    compile "junit:junit:4.11"
    testCompile "junit:junit:4.11"
    compile files('lib/NotEnoughItems-1.7.10-1.0.2.15-dev.jar')
}

jar {
    // just pack everything. Forge Gradle's support sucks so we will repack this later on
    archiveName = "combined.jar"
}

task pack(type:Exec) {
    commandLine 'bash', 'pack.bash'
}