build.gradle

import java.text.SimpleDateFormat

import com.github.spotbugs.snom.Effort

import org.apache.commons.configuration.Configuration;
import org.apache.commons.configuration.PropertiesConfiguration

buildscript {
    repositories {
        mavenCentral()
        maven {
            url "https://plugins.gradle.org/m2/"
        }
    }
    dependencies {
        classpath 'gradle.plugin.com.github.johnrengelman:shadow:8.0.0'
        classpath 'commons-configuration:commons-configuration:1.10'
        classpath 'com.guardsquare:proguard-gradle:7.6.1'
        classpath 'com.github.spotbugs.snom:spotbugs-gradle-plugin:6.1.3'
        classpath 'org.sonarsource.scanner.gradle:sonarqube-gradle-plugin:6.0.1.5171'
    }
}

subprojects {
    apply plugin: 'java-library'
    apply plugin: 'checkstyle'
    apply plugin: 'pmd'
    apply plugin: 'idea'
    apply plugin: 'com.github.spotbugs'
    apply plugin: 'jacoco'
    apply plugin: 'org.sonarqube'

    tasks.withType(JavaCompile) {
        options.release = 9
    }

    ext {
        privkeyid = '99'
        privkeyfile = "$rootDir/config/priv_key"
        pubkeyfile = "$rootDir/config/pub_key"
        mxtfile = project.layout.buildDirectory.dir("${rootProject.name}-v${getConfigValueForKey("module_build")}.mxt")
        outjar = project.layout.buildDirectory.dir("proguard-${rootProject.name}-v${getConfigValueForKey("module_build")}.jar")
    }

    repositories {
        mavenCentral()
        flatDir dirs: "$rootDir/lib"
    }

    spotbugs {
        effort = Effort.valueOf('MAX')
        excludeFilter = file("$rootDir/config/spotbugs-exclude.xml")
    }

    spotbugsMain {
        reports {
            html {
                required = true
            }
        }
    }

    jacoco {
        toolVersion = "0.8.12"
    }

    tasks.withType(Checkstyle) {
        reports {
            xml.required = false
            html.required = true
            html.stylesheet resources.text.fromFile("$rootDir/config/checkstyle/checkstyle-noframes-sorted.xsl")
        }
    }

    checkstyle {
        toolVersion = "10.21.2"
    }

    pmd {
        toolVersion = "7.4.0"
        sourceSets = [sourceSets.main]
        ruleSets = []
        ruleSetFiles = files("$rootDir/config/pmd-ruleSet.xml")
    }

    sonar {
        properties {
            property "sonar.host.url", "https://sonarcloud.io"
            property "sonar.organization", "my-flow"
        }
    }
}

task createLibs(type: Exec) {
    description 'Generates patched libraries from trusted source'
    executable "sh"
    args "-c", "scripts/create_libs.sh"
}

String getCurrentTimestamp() {
    Date today = new Date()
    SimpleDateFormat df = new SimpleDateFormat('yyyy-MM-dd HH:mm:ss')
    return df.format(today)
}

String getConfigValueForKey(String key) {
    file("${project(':core').projectDir}/src/main/resources/com/moneydance/modules/features/paypalimporter/meta_info.dict").withInputStream {
        final Configuration config = new PropertiesConfiguration();
        config.load(it);
        return config.getString("\"" + key + "\"").replaceAll("^\"|\"\$", "");
    }
}