Frontend,Backend: option to print BTC transactions

Added --print-transactions option that for given Bitcoin
address prints all incoming transactions in reverse
chronological order.

Data printed: BTC amount, USD amount, date.

Author: webwarrior-ws

src/GWallet.Backend/GWallet.Backend-legacy.fsproj

@@ -70,6 +70,7 @@
     <Compile Include="UtxoCoin\UtxoCoinMinerFee.fs" />
     <Compile Include="UtxoCoin\TransactionTypes.fs" />
     <Compile Include="UtxoCoin\UtxoCoinAccount.fs" />
+    <Compile Include="UtxoCoin\BtcTransactionPrinting.fs" />
     <Compile Include="Ether\EtherExceptions.fs" />
     <Compile Include="Ether\EtherMinerFee.fs" />
     <Compile Include="Ether\TransactionMetadata.fs" />

src/GWallet.Backend/GWallet.Backend.fsproj

@@ -39,6 +39,7 @@
     <Compile Include="UtxoCoin\UtxoCoinMinerFee.fs" />
     <Compile Include="UtxoCoin\TransactionTypes.fs" />
     <Compile Include="UtxoCoin\UtxoCoinAccount.fs" />
+    <Compile Include="UtxoCoin\BtcTransactionPrinting.fs" />
     <Compile Include="Ether\EtherExceptions.fs" />
     <Compile Include="Ether\EtherMinerFee.fs" />
     <Compile Include="Ether\TransactionMetadata.fs" />

src/GWallet.Backend/UtxoCoin/BtcTransactionPrinting.fs

@@ -0,0 +1,84 @@
+namespace GWallet.Backend.UtxoCoin
+
+open System
+open System.Net
+
+open GWallet.Backend
+open GWallet.Backend.FSharpUtil
+open GWallet.Backend.FSharpUtil.UwpHacks
+
+
+module BtcTransactionPrinting =
+    let GetBitcoinPriceForDate (date: DateTime) : Async<Result<decimal, Exception>> =
+        async {
+            try
+                let baseUrl = 
+                    let dateFormated = date.ToString("dd-MM-yyyy")
+                    SPrintF1 "https://api.coingecko.com/api/v3/coins/bitcoin/history?date=%s&localization=false" dateFormated
+                let uri = Uri baseUrl
+                use webClient = new WebClient()
+                let task = webClient.DownloadStringTaskAsync uri
+                let! result = Async.AwaitTask task
+                let json = Newtonsoft.Json.Linq.JObject.Parse result
+                return Ok(json.["market_data"].["current_price"].["usd"].ToObject<decimal>())
+            with
+            | ex ->
+                return Error ex
+        }
+
+    let PrintTransactions (maxTransactionsCount: uint32) (btcAddress: string) =
+        let address = NBitcoin.BitcoinAddress.Create(btcAddress, NBitcoin.Network.Main)
+        async { 
+            let scriptHash = Account.GetElectrumScriptHashFromPublicAddress Currency.BTC btcAddress
+            let! history =
+                Server.Query
+                    Currency.BTC
+                    (QuerySettings.Default ServerSelectionMode.Fast)
+                    (ElectrumClient.GetBlockchainScriptHashHistory scriptHash)
+                    None
+
+            let sortedHistory = history |> List.sortByDescending (fun entry -> entry.Height)
+            
+            let rec processHistory history (maxTransactionsToPrint: uint32) =
+                match history with
+                | nextEntry :: rest when maxTransactionsToPrint > 0u ->
+                    async {
+                        let! transaction = 
+                            Server.Query
+                                Currency.BTC
+                                (QuerySettings.Default ServerSelectionMode.Fast)
+                                (ElectrumClient.GetBlockchainTransactionVerbose nextEntry.TxHash)
+                                None
+                        let transactionInfo = NBitcoin.Transaction.Parse(transaction.Hex, NBitcoin.Network.Main)
+
+                        let incomingOutputs =
+                            transactionInfo.Outputs 
+                            |> Seq.filter (fun output -> output.IsTo address)
+
+                        if not (Seq.isEmpty incomingOutputs) then
+                            let amount = incomingOutputs |> Seq.sumBy (fun txOut -> txOut.Value)
+                            let dateTime = 
+                                let startOfUnixEpoch = DateTime(1970, 1, 1)
+                                startOfUnixEpoch + TimeSpan.FromSeconds(float transaction.Time)
+                            let! bitcoinPrice = GetBitcoinPriceForDate dateTime
+                            Console.WriteLine(SPrintF1 "BTC amount: %A" amount)
+                            match bitcoinPrice with
+                            | Ok price -> 
+                                let bitcoinAmount = amount.ToDecimal(NBitcoin.MoneyUnit.BTC) 
+                                Console.WriteLine(SPrintF1 "~USD amount: %s" ((bitcoinAmount * price).ToString("F2")))
+                            | Error exn -> 
+                                Console.WriteLine("Could not get bitcoin price for the date. An error has occured:\n" + exn.ToString())
+                            Console.WriteLine(SPrintF1 "date: %A UTC" dateTime)
+                            Console.WriteLine()
+                            return! processHistory rest (maxTransactionsToPrint - 1u)
+                        else
+                            return! processHistory rest maxTransactionsToPrint
+                    }
+                | _ -> async { return () }
+            
+            do! processHistory sortedHistory maxTransactionsCount
+            Console.WriteLine("End of results")
+            Console.ReadKey() |> ignore
+            return 0
+        }
+        |> Async.RunSynchronously

src/GWallet.Backend/UtxoCoin/ElectrumClient.fs

@@ -100,6 +100,12 @@ module ElectrumClient =
         return unspentListResult.Result
     }
 
+    let GetBlockchainScriptHashHistory scriptHash (stratumServer: Async<StratumClient>) = async {
+        let! stratumClient = stratumServer
+        let! history = stratumClient.BlockchainScriptHashHistory scriptHash
+        return history.Result
+    }
+
     let GetBlockchainTransaction txHash (stratumServer: Async<StratumClient>) = async {
         let! stratumClient = stratumServer
         let! blockchainTransactionResult = stratumClient.BlockchainTransactionGet txHash
@@ -113,6 +119,12 @@ module ElectrumClient =
         return blockchainTransactionResult.Result
     }
 
+    let GetBlockchainTransactionVerbose (txHash: string) (stratumServer: Async<StratumClient>) = async {
+        let! stratumClient = stratumServer
+        let! blockchainTransactionResult = stratumClient.BlockchainTransactionGetVerbose txHash
+        return blockchainTransactionResult.Result
+    }
+
     let EstimateFee (numBlocksTarget: int) (stratumServer: Async<StratumClient>): Async<decimal> = async {
         let! stratumClient = stratumServer
         let! estimateFeeResult = stratumClient.BlockchainEstimateFee numBlocksTarget

src/GWallet.Backend/UtxoCoin/StratumClient.fs

@@ -46,6 +46,18 @@ type BlockchainScriptHashListUnspentResult =
         Result: array<BlockchainScriptHashListUnspentInnerResult>
     }
 
+type BlockchainScriptHashHistoryInnerResult =
+    {
+        TxHash: string
+        Height: uint32
+    }
+
+type BlockchainScriptHashHistoryResult =
+    {
+        Id: int
+        Result: List<BlockchainScriptHashHistoryInnerResult>
+    }
+
 type BlockchainTransactionGetResult =
     {
         Id: int;
@@ -59,6 +71,20 @@ type BlockchainTransactionIdFromPosResult =
         Result: string
     }
 
+type BlockchainTransactionGetVerboseInnerResult =
+    {
+        Locktime: uint32
+        Confirmations: uint32
+        Hex: string
+        Time: uint32
+    }
+
+type BlockchainTransactionGetVerboseResult =
+    {
+        Id: int
+        Result: BlockchainTransactionGetVerboseInnerResult
+    }
+
 type BlockchainEstimateFeeResult =
     {
         Id: int;
@@ -277,6 +303,18 @@ type StratumClient (jsonRpcClient: JsonRpcTcpClient) =
             return resObj
         }
 
+    member self.BlockchainScriptHashHistory scriptHash: Async<BlockchainScriptHashHistoryResult> =
+        let obj = {
+            Id = 0
+            Method = "blockchain.scripthash.get_history"
+            Params = scriptHash :: List.Empty
+        }
+        let json = Serialize obj
+        async {
+            let! resObj,_ = self.Request<BlockchainScriptHashHistoryResult> json
+            return resObj
+        }
+
     member self.BlockchainTransactionGet txHash: Async<BlockchainTransactionGetResult> =
         let obj = {
             Id = 0;
@@ -302,6 +340,18 @@ type StratumClient (jsonRpcClient: JsonRpcTcpClient) =
             return resObj
         }
 
+    member self.BlockchainTransactionGetVerbose (txHash: string): Async<BlockchainTransactionGetVerboseResult> =
+        let obj = {
+            Id = 0
+            Method = "blockchain.transaction.get"
+            Params = [txHash :> obj; true :> obj]
+        }
+        let json = Serialize obj
+        async {
+            let! resObj,_ = self.Request<BlockchainTransactionGetVerboseResult> json
+            return resObj
+        }
+
     // NOTE: despite Electrum-X official docs claiming that this method is deprecated... it's not! go read the official
     //       non-shitcoin forked version of the docs: https://electrumx-spesmilo.readthedocs.io/en/latest/protocol-methods.html#blockchain-estimatefee
     member self.BlockchainEstimateFee (numBlocksTarget: int): Async<BlockchainEstimateFeeResult> =

src/GWallet.Frontend.Console/Program.fs

@@ -535,5 +535,11 @@ module Program =
             UpdateServersFile()
         | 1 when argv.[0] = "--update-servers-stats" ->
             UpdateServersStats()
+        | 2 | 3 when argv.[0] = "--print-transactions" ->
+            // --print-transactions <btcAddress> [maxTransactionsCount]
+            if argv.Length = 2 then 
+                UtxoCoin.BtcTransactionPrinting.PrintTransactions UInt32.MaxValue argv.[1]
+            else
+                UtxoCoin.BtcTransactionPrinting.PrintTransactions (uint32 argv.[2]) argv.[1]
         | _ ->
             failwith "Arguments not recognized"