current_user.md

subcategory
Security

databricks_current_user Data Source

-> Note If you have a fully automated setup with workspaces created by databricks_mws_workspaces or azurerm_databricks_workspace, please make sure to add depends_on attribute in order to prevent authentication is not configured for provider errors.

Retrieves information about databricks_user or databricks_service_principal, that is calling Databricks REST API. Might be useful in applying the same Terraform by different users in the shared workspace for testing purposes.

Example Usage

Create personalized databricks_job and databricks_notebook:

data "databricks_current_user" "me" {}
data "databricks_spark_version" "latest" {}
data "databricks_node_type" "smallest" {
  local_disk = true
}

resource "databricks_notebook" "this" {
  path     = "${data.databricks_current_user.me.home}/Terraform"
  language = "PYTHON"
  content_base64 = base64encode(<<-EOT
    # created from ${abspath(path.module)}
    display(spark.range(10))
    EOT
  )
}

resource "databricks_job" "this" {
  name = "Terraform Demo (${data.databricks_current_user.me.alphanumeric})"

  new_cluster {
    num_workers   = 1
    spark_version = data.databricks_spark_version.latest.id
    node_type_id  = data.databricks_node_type.smallest.id
  }

  notebook_task {
    notebook_path = databricks_notebook.this.path
  }
}

output "notebook_url" {
  value = databricks_notebook.this.url
}

output "job_url" {
  value = databricks_job.this.url
}

Exported attributes

Data source exposes the following attributes:

• id - The id of the calling user.
• external_id - ID of the user in an external identity provider.
• user_name - Name of the user, e.g. [email protected].
• home - Home folder of the user, e.g. /Users/[email protected].
• repos - Personal Repos location of the user, e.g. /Repos/[email protected].
• alphanumeric - Alphanumeric representation of user local name. e.g. mr_foo.
• workspace_url - URL of the current Databricks workspace.

Related Resources

The following resources are used in the same context:

• End to end workspace management guide
• databricks_directory to manage directories in Databricks Workpace.
• databricks_notebook to manage Databricks Notebooks.
• databricks_repo to manage Databricks Repos.