build.gradle

buildscript {
    ext.kotlinVersion = "1.3.70"

    repositories {
        mavenCentral()
        jcenter()
    }

    dependencies {
        classpath("org.jetbrains.kotlin:kotlin-gradle-plugin:$kotlinVersion")
        classpath("org.jetbrains.dokka:dokka-gradle-plugin:0.9.17")
    }
}

plugins {
    id("com.github.ben-manes.versions") version "0.28.0"
}

project.apply from: './gradle/scripts/git.gradle'

subprojects {

    project.apply from: "$rootDir/dependencies.gradle"

    repositories {
        mavenCentral()
        jcenter()
    }

    afterEvaluate {
        dokka {
            outputDirectory = javadoc.destinationDir.absolutePath
            includeNonPublic = false
        }
        javadoc.dependsOn(dokka)

        if (project.hasProperty("java")) {
            java {
                targetCompatibility = JavaVersion.VERSION_1_8
            }
        }

        if (project.hasProperty("compileKotlin")) {
            compileKotlin {
                kotlinOptions {
                    jvmTarget = "1.8"
                }
            }
        }

        project.apply from: "$rootDir/publishing.gradle"
    }
}

println "${git.versionName()} (${git.commitCount()})"