How to override parts of the kernel package?

[jwillikers]

I'm using raspberry-pi-nix as part of a flake and would like to override the kernel to apply the realtime kernel patches and enable PREEMPT_RT-related config options. I've tried a bunch of different ways of applying overlays to accomplish this, but nothing seems to be working. Here's a snippet of an overlay applied to nixpkgs.

nixpkgs.overlays = [
  (final: prev: {
    rpi-kernels.v6_6_54.bcm2712 = prev.rpi-kernels.v6_6_54.bcm2712.override (prevKernel: {
      structuredExtraConfig = with prev.lib.kernel; {
        SND_HDA_GENERIC = yes;
        SND_HDA_INTEL = yes;
        SND_HDA_PREALLOC_SIZE = 2048;

        # realtime
        # PREEMPT_RT was merged in to kernel 6.12.
        # https://github.com/NixOS/nixpkgs/blob/master/pkgs/os-specific/linux/kernel/linux-rt-6.1.nix
        PREEMPT_RT = yes;
        EXPERT = yes; # PREEMPT_RT depends on it (in kernel/Kconfig.preempt)
        # Fix error: option not set correctly: PREEMPT_VOLUNTARY (wanted 'y', got 'n').
        PREEMPT_VOLUNTARY = prev.lib.mkForce no; # PREEMPT_RT deselects it.
        # Fix error: unused option: RT_GROUP_SCHED.
        RT_GROUP_SCHED = prev.lib.mkForce (option no); # Removed by sched-disable-rt-group-sched-on-rt.patch.
        VIRTUALIZATION = no;
      };
      kernelPatches = let rt-patch = {
        name = "rt";
        patch = prev.fetchurl {
          url = "mirror://kernel/linux/kernel/projects/rt/${prevKernel.branch}/older/patch-${prevKernel.version}.patch.xz";
          sha256 = prev.lib.fakeHash;
        };
      }; in [ rt-patch ] ++ prevKernel.kernelPatches;
    });
  })
];

[tstat]

Ah, you will be prevented from doing so by this heavy-handed way of pinning the inputs:

raspberry-pi-nix/rpi/default.nix

Lines 293 to 312 in f872d77

	let
	rpi-overlays = [ core-overlay ]
	++ (if config.raspberry-pi-nix.libcamera-overlay.enable
	then [ libcamera-overlay ] else [ ]);
	rpi-overlay = lib.composeManyExtensions rpi-overlays;
	pin-prev-overlay = overlay: pinned-prev: final: prev:
	let
	# apply the overlay to pinned-prev and fix that so no references to the actual final
	# and prev appear in applied-overlay
	applied-overlay =
	lib.fix (final: pinned-prev // overlay final pinned-prev);
	# We only want to set keys that appear in the overlay, so restrict applied-overlay to
	# these keys
	restricted-overlay = lib.getAttrs (builtins.attrNames (overlay { } { })) applied-overlay;
	in
	prev // restricted-overlay;
	in
	if cfg.pin-inputs.enable
	then [ (pin-prev-overlay rpi-overlay pinned) ]
	else [ rpi-overlay ];

So, if you disable the pin-inputs option, then I expect your override to work.