CMakeLists.txt

# SPDX-License-Identifier: MulanPSL-2.0

cmake_minimum_required(VERSION 3.14)

project(syscare)

# Includes
include(GNUInstallDirs)
find_package(Git QUIET)

# Build type
if(NOT CMAKE_BUILD_TYPE)
    set(CMAKE_BUILD_TYPE RelWithDebInfo)
endif()

# Build version
if(NOT DEFINED BUILD_VERSION)
    execute_process(
        COMMAND sh -c "cat syscare/Cargo.toml | grep -F 'version' | head -n 1 | awk -F '\"' '{print $2}'"
        OUTPUT_VARIABLE BUILD_VERSION
        OUTPUT_STRIP_TRAILING_WHITESPACE
        ERROR_QUIET
        WORKING_DIRECTORY ${CMAKE_CURRENT_LIST_DIR}
    )
endif()

if(GIT_FOUND)
    execute_process(
        COMMAND ${GIT_EXECUTABLE} rev-parse --short HEAD
        OUTPUT_VARIABLE GIT_VERSION
        OUTPUT_STRIP_TRAILING_WHITESPACE
        ERROR_QUIET
        WORKING_DIRECTORY ${CMAKE_CURRENT_LIST_DIR}
    )
    set(PROJECT_BUILD_VERSION "${BUILD_VERSION}-g${GIT_VERSION}")
else()
    set(PROJECT_BUILD_VERSION "${BUILD_VERSION}")
endif()

# Build configurations
if(ENABLE_ASAN)
    set(PROJECT_BUILD_VERSION "${PROJECT_BUILD_VERSION}-asan")
    list(APPEND PROJECT_C_BUILD_FLAGS -fsanitize=address -fno-omit-frame-pointer)
    list(APPEND PROJECT_C_LIBRARIES asan)
endif()

if(ENABLE_GCOV)
    set(PROJECT_BUILD_VERSION "${PROJECT_BUILD_VERSION}-gcov")
    list(APPEND PROJECT_C_BUILD_FLAGS -ftest-coverage -fprofile-arcs)
    list(APPEND PROJECT_RUST_FLAGS -C instrument-coverage)
    list(APPEND PROJECT_C_LIBRARIES gcov)
endif()

# Build flags
list(APPEND PROJECT_C_BUILD_FLAGS
    -std=gnu99 -Wall -O2 -Werror -Wextra
    -DBUILD_VERSION="${PROJECT_BUILD_VERSION}" -D_FORTIFY_SOURCE=2
    -Wtrampolines -Wformat=2 -Wstrict-prototypes -Wdate-time
    -Wstack-usage=8192 -Wfloat-equal -Wswitch-default
    -Wshadow -Wconversion -Wcast-qual -Wcast-align -Wunused -Wundef
    -funsigned-char -fstack-protector-all -fpic -fpie -ftrapv
    -fstack-check -freg-struct-return -fno-canonical-system-headers
    -fno-common -pipe -fdebug-prefix-map=old=new
)
list(APPEND PROJECT_RUST_FLAGS
    --cfg unsound_local_offset
    -C relocation_model=pic
    -D warnings
    -C link-arg=-s
    -C overflow_checks
    -W rust_2021_incompatible_closure_captures
)

# Link flags
list(APPEND PROJECT_C_LINK_FLAGS
    -pie
    -Wl,-z,relro,-z,now
    -Wl,-z,noexecstack -rdynamic
    -Wl,-Bsymbolic
    -Wl,-no-undefined
)

if(CMAKE_BUILD_TYPE STREQUAL "Debug" OR CMAKE_BUILD_TYPE STREQUAL "RelWithDebInfo")
    list(APPEND PROJECT_C_BUILD_FLAGS -g)
elseif(CMAKE_BUILD_TYPE STREQUAL "Release")
    list(APPEND PROJECT_C_LINK_FLAGS -s)
endif()

# Install directories
set(SYSCARE_BINARY_DIR  "${CMAKE_INSTALL_FULL_BINDIR}")
set(SYSCARE_LIBEXEC_DIR "${CMAKE_INSTALL_FULL_LIBEXECDIR}/syscare")
set(SYSCARE_SERVICE_DIR "${CMAKE_INSTALL_PREFIX}/lib/systemd/system")

# Print build info
message("---------------------------------------------------------")
message("███████╗██╗   ██╗███████╗ ██████╗ █████╗ ██████╗ ███████╗")
message("██╔════╝╚██╗ ██╔╝██╔════╝██╔════╝██╔══██╗██╔══██╗██╔════╝")
message("███████╗ ╚████╔╝ ███████╗██║     ███████║██████╔╝█████╗  ")
message("╚════██║  ╚██╔╝  ╚════██║██║     ██╔══██║██╔══██╗██╔══╝  ")
message("███████║   ██║   ███████║╚██████╗██║  ██║██║  ██║███████╗")
message("╚══════╝   ╚═╝   ╚══════╝ ╚═════╝╚═╝  ╚═╝╚═╝  ╚═╝╚══════╝")
message("---------------------------------------------------------")
message("-- Build type: ${CMAKE_BUILD_TYPE}")
message("-- Build version: ${PROJECT_BUILD_VERSION}")
message("-- Rust flags: ${PROJECT_RUST_FLAGS}")
message("-- Build flags: ${PROJECT_C_BUILD_FLAGS}")
message("-- Link flags: ${PROJECT_C_LINK_FLAGS}")
message("-- Link libraries: ${PROJECT_C_LIBRARIES}")
message("-- Binary  directory: ${SYSCARE_BINARY_DIR}")
message("-- Libexec directory: ${SYSCARE_LIBEXEC_DIR}")
message("-- Service directory: ${SYSCARE_SERVICE_DIR}")
message("---------------------------------------------------------")

# Apply all flags
add_compile_options(${PROJECT_C_BUILD_FLAGS})
add_link_options(${PROJECT_C_LINK_FLAGS})
link_libraries(${PROJECT_C_LIBRARIES})

# Build rust executables
set(RUST_TARGET_DIR "${CMAKE_CURRENT_BINARY_DIR}/rust")
set(RUST_OUTPUT_DIR "${RUST_TARGET_DIR}/release")
foreach(FLAG IN LISTS PROJECT_RUST_FLAGS)
     set(RUST_FLAGS "${RUST_FLAGS} ${FLAG}")
endforeach()

add_custom_target(rust-build ALL
    COMMENT "Building rust executables..."
    COMMAND ${CMAKE_COMMAND} -E env
        "BUILD_VERSION=${PROJECT_BUILD_VERSION}"
        "RUSTFLAGS=${RUST_FLAGS}"
        cargo build --release --target-dir "${RUST_TARGET_DIR}"
    WORKING_DIRECTORY ${CMAKE_CURRENT_SOURCE_DIR}
)

# Generate upatch helpers
add_custom_target(generate-upatch-helpers ALL
    COMMENT "Generating upatch helpers..."
    COMMAND ln -sf upatch-helper upatch-cc
    COMMAND ln -sf upatch-helper upatch-c++
    DEPENDS
        rust-build
    WORKING_DIRECTORY ${RUST_OUTPUT_DIR}
)

# Install rust binaries
install(
    PROGRAMS
        ${RUST_OUTPUT_DIR}/syscare
    PERMISSIONS
        OWNER_READ OWNER_WRITE OWNER_EXECUTE
        GROUP_READ GROUP_EXECUTE
        WORLD_READ WORLD_EXECUTE
    DESTINATION
        ${SYSCARE_BINARY_DIR}
)

install(
    PROGRAMS
        ${RUST_OUTPUT_DIR}/syscared
    PERMISSIONS
        OWNER_READ OWNER_WRITE OWNER_EXECUTE
        GROUP_READ GROUP_EXECUTE
    DESTINATION
        ${SYSCARE_BINARY_DIR}
)

install(
    PROGRAMS
        ${RUST_OUTPUT_DIR}/syscare-build
        ${RUST_OUTPUT_DIR}/upatch-build
        ${RUST_OUTPUT_DIR}/upatch-helper
        ${RUST_OUTPUT_DIR}/upatch-cc
        ${RUST_OUTPUT_DIR}/upatch-c++
        ${RUST_OUTPUT_DIR}/metadata-viewer
        ${RUST_OUTPUT_DIR}/metadata-generator
    PERMISSIONS
        OWNER_READ OWNER_WRITE OWNER_EXECUTE
        GROUP_READ GROUP_EXECUTE
        WORLD_READ WORLD_EXECUTE
    DESTINATION
        ${SYSCARE_LIBEXEC_DIR}
)

# Build other components
add_subdirectory(upatch-diff)
add_subdirectory(upatch-manage)
add_subdirectory(misc)