build.gradle

import com.github.jk1.license.render.*

buildscript {
    repositories {
        mavenCentral()
        maven {
            url "http://repository.activeeon.com/content/groups/proactive/"
        }
        maven {
              url "https://plugins.gradle.org/m2/"
        }
    }

    dependencies {
        classpath 'org.springframework.boot:spring-boot-gradle-plugin:1.5.22.RELEASE'
        classpath "com.diffplug.gradle.spotless:spotless:2.4.0"
        classpath "org.ow2.proactive:coding-rules:1.0.0"
        classpath "org.sonarsource.scanner.gradle:sonarqube-gradle-plugin:2.6.1"
        classpath "io.spring.gradle:dependency-management-plugin:1.0.15.RELEASE"
        classpath 'org.jsonschema2pojo:jsonschema2pojo-gradle-plugin:0.4.27'
        classpath 'com.github.jk1:gradle-license-report:1.7'
    }
    dependencies {
        delete "gradle/ext"
        ant.unjar src: configurations.classpath.find { it.name.startsWith("coding-rules") }, dest: 'gradle/ext'
    }
}

apply plugin: 'org.springframework.boot'
apply plugin: 'org.sonarqube'
apply plugin: 'com.github.jk1.dependency-license-report'

apply from: "$rootDir/gradle/ext/coding-format.gradle"

bootRepackage {
    enabled = false
}

springBoot {
    mainClass = 'org.ow2.proactive.scheduling.api.Application'
}

licenseReport {
    configurations = ['runtime']
    renderers = [new InventoryHtmlReportRenderer()]
}

allprojects {
    apply plugin: "io.spring.dependency-management"
    apply plugin: 'eclipse'
    apply plugin: 'idea'
    apply plugin: 'java'
    apply plugin: 'maven'
    apply plugin: 'project-report'

    group = 'org.ow2.proactive'

    sourceCompatibility = JavaVersion.VERSION_1_8
    targetCompatibility = JavaVersion.VERSION_1_8

    defaultTasks 'clean', 'build', 'check'

    dependencyManagement {
        imports {
            mavenBom "org.ow2.proactive:parent-bom:${version}"

            dependencies {
                dependency "com.graphql-java:graphql-java:17.6"
                dependency "com.graphql-java:graphql-java-extended-scalars:17.1"
            }
        }
        resolutionStrategy {
            cacheChangingModulesFor 0, 'seconds'
        }
    }

    dependencies {
        testCompile 'com.google.truth:truth'
        testCompile 'junit:junit'
        testCompile 'org.mockito:mockito-core'
    }

    repositories {
        if (project.hasProperty('local')) {
            mavenLocal()
        }
        mavenCentral()

        maven { url 'http://repository.activeeon.com/content/groups/proactive/' }
        maven { url "https://repo.jenkins-ci.org/releases/" }
    }

    uploadArchives {
        repositories {
            mavenDeployer {
                snapshotRepository(url: "http://repository.activeeon.com/content/repositories/snapshots/") {
                    authentication(userName: "${System.getProperty('nexusUsername')}",
                            password: "${System.getProperty('nexusPassword')}")
                }
                repository(url: "http://repository.activeeon.com/content/repositories/releases/") {
                    authentication(userName: "${System.getProperty('nexusUsername')}",
                            password: "${System.getProperty('nexusPassword')}")
                }
            }
        }
    }

    sonarqube {
        properties {
            property "sonar.projectKey", "$project.group:scheduling-api"
            property "sonar.projectName", "scheduling-api"
            property "sonar.jdbc.driverClassName", "org.postgresql.Driver"
            property "sonar.language", "java"
            property "sonar.sources", "src/main"
            property 'sonar.jacoco.reportPath', "${buildDir}/jacoco/testDebug.exec"
            property 'sonar.junit.reportsPath', "${buildDir}/test-results"
        }
    }

    sourceSets {
        integrationTest {
            java.srcDir file('src/integration-test/java')
            resources.srcDir file('src/integration-test/resources')

            compileClasspath = sourceSets.main.output + configurations.integrationTestCompile
            runtimeClasspath = output + compileClasspath + configurations.integrationTestRuntime
        }
    }

    task integrationTest(type: Test) {
        testClassesDir = sourceSets.integrationTest.output.classesDir
        classpath = sourceSets.integrationTest.runtimeClasspath
        classpath += sourceSets.test.runtimeClasspath

        testLogging {
            events "passed", "skipped", "failed"
        }
    }

    check.dependsOn integrationTest

    configurations {
        // The following module is excluded to avoid clashes when embedded inside the ProActive Scheduler
        all*.exclude module: 'spring-boot-starter-logging'

        integrationTestCompile.extendsFrom testCompile
        integrationTestRuntime.extendsFrom testRuntime
    }

    idea {
        module {
            testSourceDirs += file('src/integration-test/java')
            testSourceDirs += file('src/integration-test/resources')

            scopes.TEST.plus += [
                    configurations.integrationTestCompile,
                    configurations.integrationTestRuntime
            ]
        }
    }
}