build.gradle

/*
 * Licensed under the Apache License, Version 2.0 (the "License");
 * you may not use this file except in compliance with the License.
 * You may obtain a copy of the License at
 *
 *     http://www.apache.org/licenses/LICENSE-2.0
 *
 * Unless required by applicable law or agreed to in writing, software
 * distributed under the License is distributed on an "AS IS" BASIS,
 * WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
 * See the License for the specific language governing permissions and
 * limitations under the License.
 */

buildscript {
    repositories {
        maven {
            url 'https://plugins.gradle.org/m2/'
        }
    }
    dependencies {
        classpath 'com.adarshr:gradle-test-logger-plugin:3.1.0'
        classpath 'gradle.plugin.com.github.johnrengelman:shadow:7.1.2'
        classpath 'com.diffplug.spotless:spotless-plugin-gradle:6.2.0'
    }
}

allprojects {
    repositories {
        mavenLocal()
        mavenCentral()
        maven {
            url = 'https://datakin.jfrog.io/artifactory/maven-public-libs-snapshot'
        }
    }
}

subprojects {
    apply plugin: 'jacoco'
    apply plugin: 'java'
    apply plugin: 'com.adarshr.test-logger'
    apply plugin: 'com.github.johnrengelman.shadow'
    apply plugin: "com.diffplug.spotless"

    project(':api') {
        apply plugin: 'application'
        archivesBaseName = 'marquez-api'
    }

    project(':clients:java') {
        apply plugin: 'java-library'
        archivesBaseName = 'marquez-java'
    }

    ext {
        assertjVersion = '3.22.0'
        dropwizardVersion = '2.0.28'
        jacocoVersion = '0.8.7'
        junit5Version = '5.8.2'
        lombokVersion = '1.18.22'
        mockitoVersion = '4.2.0'
        openlineageVersion = '0.5.1'
        slf4jVersion = '1.7.33'
        postgresqlVersion = '42.3.1'
        isReleaseVersion = !version.endsWith('SNAPSHOT')
    }

    dependencies {
        implementation "org.projectlombok:lombok:${lombokVersion}"
        annotationProcessor "org.projectlombok:lombok:${lombokVersion}"

        testImplementation "org.assertj:assertj-core:${assertjVersion}"
        testImplementation "org.junit.jupiter:junit-jupiter:${junit5Version}"
        testImplementation "org.mockito:mockito-core:${mockitoVersion}"
        testImplementation "org.mockito:mockito-junit-jupiter:${mockitoVersion}"
        testImplementation "org.projectlombok:lombok:${lombokVersion}"
        testAnnotationProcessor "org.projectlombok:lombok:${lombokVersion}"
    }

    compileJava {
        options.incremental = true
        options.compilerArgs << '-parameters'
        options.encoding = "UTF-8"
        sourceCompatibility = JavaVersion.VERSION_17
        targetCompatibility = JavaVersion.VERSION_17
    }

    compileTestJava {
        options.incremental = true
        options.compilerArgs << '-parameters'
        options.encoding = "UTF-8"
        sourceCompatibility = JavaVersion.VERSION_17
        targetCompatibility = JavaVersion.VERSION_17
    }

    task sourceJar(type: Jar) {
        classifier 'sources'
        from sourceSets.main.allJava
    }

    task javadocJar(type: Jar, dependsOn: javadoc) {
        classifier 'javadoc'
        from javadoc.destinationDir
    }

    spotless {
        def disallowWildcardImports = {
            String text = it
            def regex = ~/import .*\.\*;/
            def m = regex.matcher(text)
            if (m.find()) {
                throw new AssertionError("Wildcard imports disallowed - ${m.findAll()}")
            }
        }
        java {
            googleJavaFormat()
            removeUnusedImports()
            custom 'disallowWildcardImports', disallowWildcardImports
        }
    }

    def reportsDir = "${buildDir}/reports";
    def coverageDir = "${reportsDir}/coverage";

    jacoco {
        toolVersion = "${jacocoVersion}"
        reportsDir = file(coverageDir)
    }

    jacocoTestReport {
        reports {
            xml.enabled = true
            html.enabled = true
            html.destination = file(coverageDir)
        }
    }
}