Number.pen

# This module provides common number operations.

import foreign "c" _pen_core_absolute \(number) number
import foreign "c" _pen_core_ceil \(number) number
import foreign "c" _pen_core_convert_number_to_string \(number) string
import foreign "c" _pen_core_epsilon \() number
import foreign "c" _pen_core_exponential \(number) number
import foreign "c" _pen_core_floor \(number) number
import foreign "c" _pen_core_fraction \(number) number
import foreign "c" _pen_core_infinity \() number
import foreign "c" _pen_core_is_nan \(number) boolean
import foreign "c" _pen_core_nan \() number
import foreign "c" _pen_core_parse_number \(string) number | error
import foreign "c" _pen_core_power \(number, number) number
import foreign "c" _pen_core_remainder \(number, number) number
import foreign "c" _pen_core_round \(number) number
import foreign "c" _pen_core_square_root \(number) number
import foreign "c" _pen_core_truncate \(number) number

# Calculate an absolute value.
Absolute = \(x number) number {
  _pen_core_absolute(x)
}

# Calculate a ceil value.
Ceil = \(x number) number {
  _pen_core_ceil(x)
}

# Machine epsilon
Epsilon = \() number {
  _pen_core_epsilon()
}

# Calculate an exponential of a number.
Exponential = \(x number) number {
  _pen_core_exponential(x)
}

# Calculate a floor value.
Floor = \(x number) number {
  _pen_core_floor(x)
}

# Calculate a fraction value of a number.
Fraction = \(x number) number {
  _pen_core_fraction(x)
}

# Infinity
Infinity = \() number {
  _pen_core_infinity()
}

# Check if a number is NaN.
IsNan = \(x number) boolean {
  _pen_core_is_nan(x)
}

# Calculate a maximum.
Maximum = \(x number, y number) number {
  if IsNan(x) | IsNan(y) {
    Nan()
  } else if x > y {
    x
  } else {
    y
  }
}

# Calculate a minimum.
Minimum = \(x number, y number) number {
  if IsNan(x) | IsNan(y) {
    Nan()
  } else if x < y {
    x
  } else {
    y
  }
}

# NaN
Nan = \() number {
  _pen_core_nan()
}

# Parse a number.
Parse = \(s string) number | error {
  _pen_core_parse_number(s)
}

# Calculate a power.
Power = \(base number, exponent number) number {
  _pen_core_power(base, exponent)
}

# Create a list of numbers from a minimum to a maximum.
Range = \(minimum number, maximum number) [number] {
  if minimum > maximum {
    [number]
  } else {
    [number minimum, ...Range(minimum + 1, maximum)]
  }
}

# Calculate a remainder.
Remainder = \(dividend number, divisor number) number {
  _pen_core_remainder(dividend, divisor)
}

# Round a number.
Round = \(x number) number {
  _pen_core_round(x)
}

# Create a list of numbers from 1 to a maximum value.
Sequence = \(maximum number) [number] {
  Range(1, maximum)
}

# Calculate a square root.
SquareRoot = \(x number) number {
  _pen_core_square_root(x)
}

# Convert a number into its string representation.
String = \(x number) string {
  _pen_core_convert_number_to_string(x)
}

# Sum up numbers.
Sum = \(xs [number]) number {
  sumRecursive(xs, 0)
}

sumRecursive = \(xs [number], sum number) number {
  if [x, ...xs] = xs {
    sumRecursive(xs, sum + x())
  } else {
    sum
  }
}

# Return an integer value of a number.
Truncate = \(x number) number {
  _pen_core_truncate(x)
}