nextflow.config

/*
 * -------------------------------------------------
 *  peterk87/nf-asfv-ont Nextflow config file
 * -------------------------------------------------
 * Default config options for all environments.
 * Cluster-specific config options should be saved
 * in the conf folder and imported under a profile
 * name here.
 */

// Global default params, used in configs
params {
  container = 'peterk87/nf-villumina:2.0.0'

  // Workflow flags
  reads = "reads/*R{1,2}*.fastq.gz"
  outdir = 'results'
  centrifuge_db = checkParentExists(getEnvValue("CENTRIFUGE_DB", "/opt/DB/centrifuge/nt-2018-03-03/nt"))
  kraken2_db = checkPathExists(getEnvValue("KRAKEN2_DB", "/opt/DB/kraken2/standard2"))
  unicycler_mode = "bold"
  taxids = 10239 // Viruses
  blastn_db = checkParentExists(getEnvValue('BLASTDB', '/opt/DB/blast') + '/nt')
  blastn_taxids = "$baseDir/data/Viruses-10239.taxidlist"
  fastp_min_base_quality = 15
  fastp_max_percent_low_qual_base = 40
  shovill_trim = false
  megahit_preset = 'meta-sensitive'
  exclude_unclassified_reads = false

  skip_fastp = false

  // SLURM cluster options
  slurm_queue = null
  slurm_queue_size = 100

  // Boilerplate options
  name = false
  multiqc_config = "$baseDir/conf/multiqc_config.yaml"
  monochrome_logs = false
  email = false
  plaintext_email = false
  help = false
  tracedir = "${params.outdir}/pipeline_info"
  clusterOptions = false
  awsqueue = false
  awsregion = 'eu-west-1'
  custom_config_version = 'master'
}

// Load base.config by default for all pipelines
includeConfig 'conf/base.config'
process.container = params.container

profiles {
  conda { 
    process.conda = "$baseDir/environment.yml"
    conda.useMamba = true
  }
  debug { process.beforeScript = 'echo $HOSTNAME' }
  docker {
    docker.enabled = true
  }
  singularity {
    singularity.enabled = true
    singularity.autoMounts = true
    // provide full container url to Singularity-Hub.org
    process.container = "shub://${params.container}"
  }
  slurm { includeConfig 'conf/slurm.config' }
  test { includeConfig 'conf/test.config' }
}

// Capture exit codes from upstream processes when piping
process.shell = ['/bin/bash', '-euo', 'pipefail']

timeline {
  enabled = true
  file = "${params.tracedir}/execution_timeline.html"
}
report {
  enabled = true
  file = "${params.tracedir}/execution_report.html"
}
trace {
  enabled = true
  file = "${params.tracedir}/execution_trace.txt"
}
dag {
  enabled = true
  file = "${params.tracedir}/execution_dag.svg"
}

manifest {
  name = 'peterk87/nf-villumina'
  author = 'Peter Kruczkiewicz'
  homePage = 'https://github.com/peterk87/nf-villumina'
  description = 'Generic viral Illumina paired-end sequencing reads analysis pipeline'
  mainScript = 'main.nf'
  nextflowVersion = '>=21.10.0'
  version = '2.0.1'
}

// If parent path exists, then return `p`, else return null
def checkParentExists(p) {
  f = new File(p)
  if ((new File(f.parent)).exists()) {
    p
  } else {
    null
  }
}

// If path exists, return `p`, else return null
def checkPathExists(p) {
  f = new File(p)
  if (f.exists()) {
    p
  } else {
    null
  }
}

// Try to get a system environment variable value with some key. If the key
// doesn't exist, then return a default value
def getEnvValue(envKey, defaultValue = null) {
  envMap = new HashMap(System.getenv())
  if (envMap.containsKey(envKey)) {
    envMap[envKey]
  } else {
    defaultValue
  }
}


// Function to ensure that resource requirements don't go beyond
// a maximum limit
def check_max(obj, type) {
  if(type == 'memory'){
    try {
      if(obj.compareTo(params.max_memory as nextflow.util.MemoryUnit) == 1)
        return params.max_memory as nextflow.util.MemoryUnit
      else
        return obj
    } catch (all) {
      println "   ### ERROR ###   Max memory '${params.max_memory}' is not valid! Using default value: $obj"
      return obj
    }
  } else if(type == 'time'){
    try {
      if(obj.compareTo(params.max_time as nextflow.util.Duration) == 1)
        return params.max_time as nextflow.util.Duration
      else
        return obj
    } catch (all) {
      println "   ### ERROR ###   Max time '${params.max_time}' is not valid! Using default value: $obj"
      return obj
    }
  } else if(type == 'cpus'){
    try {
      return Math.min( obj, params.max_cpus as int )
    } catch (all) {
      println "   ### ERROR ###   Max cpus '${params.max_cpus}' is not valid! Using default value: $obj"
      return obj
    }
  }
}