EHBasic Programs and quirks

[Hyenadae]

I've been going through RosettaCode and trying out different mathematical or graphical functions that can run on the terminal output only, given EHBasic currently doesn't have any plotting/graphical functionality.

Current quirks I've found:

It's print (to grab input for a variable) prefers a ; over a , at the end of PRINT text.

ie, 20 PRINT "Enter an integer";
30 INPUT N
or 20 PRINT "Enter an integer"; N
seems to work fine.

CLS doesn't work. Can't clear a screen that doesn't exist.
LET can be removed when defining variable values, though multi-definitions on a single line is iffy?
TIME returns 0, as there doesn't seem to be defined, since there's no RTC code
Output past the decimal point is capped to six digits, same for Exponent based output

when I copy and paste a new program over the terminal, I usually run

NEW
CLEAR

to reset the environment. As usual, type RUN after pressing enter on the final line, should work to execute the below programs

Control C kills every BASIC code, UNLESS you've crashed the system which I managed to using a program that uses

DATA 1234,6325,2453 etc writes and reads?
Additionally, BASIC code that's too long on a single line will get cut off/not be entered, so you will need to split it up.

Iterative/Expanding Mandelbrot:

  100 REM A BASIC, ASCII MANDELBROT
  110 REM
  120 REM This implementation copyright (c) 2019, Gordon Henderson
  130 REM
  140 REM Permission to use/abuse anywhere for any purpose granted, but
  150 REM it comes with no warranty whatsoever. Good luck!
  160 REM
  170 C$ = ".,'~=+:;[/<&?oxOX# " : REM 'Pallet' Lightest to darkest...
  180 SO = 1 : REM Set to 0 if your MID$() indexes from 0.
  190 MI = LEN(C$)
  200 MX = 4
  210 LS = -2.0
  220 TP = 1.25
  230 XS = 2.5
  240 YS = -2.5
  250 W = 12
  260 H = 8
  270 SX = XS / W
  280 SY = YS / H
  290 Q = TIME
  300 FOR Y = 0 TO H
  310   CY = Y * SY + TP
  320   FOR X = 0 TO W
  330     CX = X * SX + LS
  340     ZX = 0
  350     ZY = 0
  360     CC = SO
  370     X2 = ZX * ZX
  380     Y2 = ZY * ZY
  390     IF CC > MI THEN GOTO 460
  400     IF (X2 + Y2) > MX THEN GOTO 460
  410     T = X2 - Y2 + CX
  420     ZY = 2 * ZX * ZY + CY
  430     ZX = T
  440     CC = CC + 1
  450     GOTO 370
  460     PRINT MID$(C$, CC - SO, 1);
  470   NEXT
  480   PRINT
  490 NEXT
  500 PRINT W " Width" H " Height"
  510 IF W > 74 THEN GOTO 580
  520 W = W + 8
  530 H = H + 6
  540 PRINT 
  570 GOTO 270
  580 END

PI CALCULATOR : TRS 80 VERS,  https://rosettacode.org/wiki/Pi#TRS-80_Model_4_BASIC 

10 REM ADOPTED FROM COMMODORE BASIC
15 CR=0
20 N = 50: REM N MAY BE INCREASED, BUT WILL SLOW EXECUTION
30 LN = INT(10*N/3)+16
40 ND = 1
50 DIM A(LN)
60 N9 = 0
70 PD = 0:REM FIRST PRE-DIGIT IS A 0
80 REM
90 FOR J = 1 TO LN
100    A(J-1) = 2:REM START WITH 2S
110 NEXT J
120 REM
130 FOR J = 1 TO N
140     Q = 0
150     FOR I = LN TO 1 STEP -1:REM WORK BACKWARDS
160         X = 10*A(I-1) + Q*I
170         A(I-1) = X - (2*I-1)*INT(X/(2*I-1)):REM X - INT ( X / Y) * Y
180         Q = INT(X/(2*I - 1))
190     NEXT I
200     A(0) = Q-10*INT(Q/10)
210     Q = INT(Q/10)
220     IF Q=9 THEN N9 = N9 + 1: GOTO 450
240     IF Q<>10 THEN GOTO 350
250     REM Q == 10
260        D = PD+1: GOSUB 500
270        IF N9 <= 0 THEN GOTO 320
280           FOR K = 1 TO N9
290              D = 0: GOSUB 500
300           NEXT K
310        REM END IF
320        PD = 0
330        N9 = 0
335        GOTO 450
340     REM Q <> 10
350        D = PD: GOSUB 500
360        PD = Q
370        IF N9 = 0 THEN GOTO 450
380           FOR K = 1 TO N9
390              D = 9: GOSUB 500
400           NEXT K
410           N9 = 0
450 NEXT J
460 PRINT STR$(PD)
470 END
480 REM
490 REM OUTPUT DIGITS
500 IF ND=0 AND CR<22 THEN PRINT STR$(D);:CR=CR+1: RETURN
502 IF ND=0 AND CR=22 THEN PRINT STR$(D):CR=0: RETURN
510 IF D=0 THEN RETURN
520 PRINT STR$(D);".";
530 ND = 0
550 RETURN

Mobius Series: (Minimal Basic)

10 REM Moebius function
20 FOR T = 0 TO 9
30 FOR U = 1 TO 10
40 LET N = 10*T+U
50 GOSUB 110
60 PRINT M;" ";
70 NEXT U
80 PRINT
90 NEXT T
100 END
110 LET M = 1
120 IF N = 1 THEN 230
130 LET F = 2
140 LET F2 = F*F
150 IF INT(N/F2)*F2 <> N THEN 180
160 LET M = 0
170 GOTO 230
180 IF INT(N/F)*F <> N THEN 210
190 LET M = -M
200 LET N = N/F
210 LET F = F+1
220 IF F <= N THEN 140
230 RETURN

Harmonic Numbers calculation:
(Applesoft? Modified code. Remove CLS, replace with REM)

100 REM Haromic Series
110 PRINT "The first twenty harmonic numbers are:"
120 FOR n = 1 TO 20
130   h = h+(1/n)
140   PRINT n,h
150 NEXT n
160 PRINT
170 h = 1
180 n = 2
190 FOR i = 2 TO 10
200   IF NOT(h < i) THEN GOTO 240
210     h = h+(1/n)
220     n = n+1
230   GOTO 200
240   PRINT "The first harmonic number greater than " i" is " h" at position " n-1
250 NEXT i
260 END

GOLDEN RATIO (GW Basic, modified to remove CLS)

100 REM Golden Ratio
110 LET I = 0
120 LET P0 = 1
130 LET P1 = 1+(1/P0)
140 LET D = ABS(P1-P0)
150 LET P0 = P1
160 LET I = I+1
170 IF .000001 < D THEN 130
180 PRINT "Result: ";P1;" after ";I;" iterations"
190 PRINT "The error is approximately ";P1-(.5*(1+SQR(5)))
200 END

COMPUTE E VIA INVERSE FACTORIAL (Commodore BASIC)

100 REM COMPUTE E VIA INVERSE FACTORIAL SUM
110 N = 11 : REM NUMBER OF ITERATIONS
120 E =  1 : REM APPROXIMATE E HERE
130 F =  1 : REM BUILD FACTORIAL HERE
140 FOR I = 1 TO N
150 : F = F*I
160 : E = E + 1/F
170 NEXT I
180 PRINT "AFTER" N " ITERATIONS, E =" E

Iterative Fibonnaci sequence: (MSX Basic ver, remove CLS)

100 PRINT
110 FOR N = 0 TO 35: GOSUB 130: PRINT FIBOI; : NEXT N
120 END
130 REM Iterative Fibonacci sequence
140 N1 = 0
150 N2 = 1
160 FOR K = 1 TO ABS(N)
170   SUM = N1 + N2
180   N1 = N2
190   N2 = SUM
200 NEXT K
210 IF N < 0 THEN FIBOI = N1 * ((-1) ^ ((-N) + 1)) ELSE FIBOI = N1
220 RETURN

Factors of an Integer (Minimal BASIC)

10 REM Factors of an integer
20 PRINT "Enter an integer";
30 INPUT N
40 IF N = 0 THEN 30
50 N1 = ABS(N)
60 FOR I = 1 TO N1/2
70 IF INT(N1/I)*I <> N1 THEN 90
80 PRINT I;
90 NEXT I
100 PRINT N1
110 END

ARITHMETIC Geometric Mean: (Commodore BASIC)

10 A = 1
20 G = 1/SQR(2)
30 GOSUB 100
40 PRINT A
50 END
100 TA = A
110 A = (A+G)/2
120 G = SQR(TA*G)
130 IF A<TA THEN 100
140 RETURN

[Hyenadae]

Of course, any games or other programs that can work in EHBasic with modifications posted would be appreciated!
Trying to build up a list here, and find more things that need to be known if conversions need to be done if they're not too difficult.

[netzerohero]

Nice! - well captured EhBASIC quirk examples on record above.

From above code examples, it appears you've found SQR() to work?

Input lines currently limited to 80 chars; see lang.s source file; search for "Ibuffe".

For CLS - as a suggestion, I understand RP6502-VGA-pico's console supports ANSI-escape-codes; unclear if VGA-console supports a clear-entire-screen: ( ESC[2J == erase entire screen) - may be worth a try...
e.g., PRINT CHR$(27)"[2J";

Have you seen these RFCs related to your tests and observations?:
RTC - #39
Enhance EhBASIC - #59

[Hyenadae]

Hi, I've seen the RFCs, sadly my programming knowledge isn't very good and I've got weeks of learning probably before I understand how things mostly work... given it's a bit more of an unusual setup than doing VASM 'compiling' -> eeprom ROM programs (I keep looking over the videos from Rumble!)

I will have to try the character print command later. I saw that we have a codeplug / table for symbols and characters, but I don't yet quite get both where it is stored, and if or how BASIC on the 6502 side can directly access or address it. I think the videos have it, but the documentation pages don't have the current memory map, or the one that ehbasic uses?

I know it's loaded into the RAM as a part of EHBasic's ROM, but I haven't tried to directly print the special characters defined character from there. The Mandelbrot is as fancy as I've seen for the non-alphanumeric print, kind of wish the documentation for UART terminal characters (and what minicom supports) was more obvious incase you can do fancy 8x8 pixel custom defined characters like the commodore has, but I assume it's not possible because there's no way to tell minicom that the weird data it's getting is 'text' data.

[Hyenadae]

I might also need to consider making a table for myself of the translated addresses from hex to bytes for PEEKS and POKES, ie for interacting with the VIA chip or getting more obvious data from RAM without BASIC putting it 'Somewhere' while executing

[netzerohero]

Agree with your comments on the memory map. I've wanted to understand that memory map better, so I just uploaded a spreadsheet with one I've put together under a separate thread. It also includes some block-diagrams captured from Rumble's videos. Take a look, maybe you'll find it helpful.

[James-HoneyBadger]

PRINT CHR$(12) works for clearing the screen

[WojciechGw]

BTW problem was solved by adding ";" after CHR$(12)
10 PRINT CHR$(12);

[netzerohero]

Just a hunch: Looks like a race-condition between the 6502 and VGA-pico. Or with the RIA-pico. (There are 3 active CPU-units running concurrently.)
My guess is the CHR$(12) to clear the screen is being carried-out by the VGA-pico; yet the 6502 of course is carrying out the BASIC print via the RIA. Rumble may need to comment.

Try adding a delay for/next loop on line 15 and see if behavior improves. Or try reducing the 6502-speed with the PHI2 setting.

[WojciechGw]

Thank You :)
Adding ";" was simplest anyway :)
But why this one solve the problem ?
Referring to your suggestions - it gave the needed little delay ?

[netzerohero]

Admittedly, I am not intimately familiar with the HW timing nuances. My guess is: VGA-clear running on VGA-pico is running open-loop while 6502+RIA-pico are together executing BASIC. You adding the " ; " to the line-10 print statement added enough delay on the 6502-side so VGA-clear on the VGA-pico can complete nicely.

If my hunch is correct, a HW-signal indicating "I am done clearing screen" would signal back to the 6502-side to say it is "OK to continue outputting the print-out chars".

Or: simply do the delay as you found with the " ; " (which prints-out additional unseen white-space characters). :)

Neat problem to think about.

[rumbledethumps]

It's a buffer overrun. Clearing the screen takes too long. It can be fixed and remain open loop.