Trouble getting a PCM5102 I2S DAC to work with Raspberry Pi Pico

[madskjeldgaard]

Hi Friends

I have tried to connect a PCM5102 DAC via I2S to a Raspberry Pi Pico board but I get no sound coming out.

Does anyone have any idea ?

The same sketch seems to output audio fine when modified to use a PWMOutput.

With my oscilloscope I can see data coming into the three pins on the DAC.

Connections

CONNECTIONS:
DAC  -  board
BCK -> GPIO26
DIN -> GPIO27
LCK->GPIO28

Sketch

And here is my patch

#include "AudioTools.h"
#include "alice.h"
// #include "knghtsng.h"
#include <Arduino.h>

MemoryStream wavfileMemory(alice_wav, alice_wav_len);
// MemoryStream wav(knghtsng_wav, knghtsng_wav_len);

constexpr auto sample_rate = 8000;
constexpr auto channels = 2;
constexpr auto bits_per_sample = 16;
constexpr auto baudrate = 115200;

// constexpr auto i2s_bck_pin = 26;
// constexpr auto i2s_ws_pin = 28;
// constexpr auto i2s_data_out_pin = 27;

AudioInfo info(sample_rate, channels, bits_per_sample);
I2SStream i2sOutput;
EncodedAudioStream sig(&i2sOutput, new WAVDecoder()); // Decoder stream
StreamCopy copier(sig, wavfileMemory);                // copy in to out

void setup() {
  Serial.begin(baudrate);
  AudioLogger::instance().begin(Serial, AudioLogger::Info);

  // setup I2S output
  auto config = i2sOutput.defaultConfig(TX_MODE);
  config.copyFrom(info);
  // config.pin_ws = i2s_ws_pin;
  // config.pin_bck = i2s_bck_pin;
  // config.pin_data = i2s_data_out_pin;

  auto result = i2sOutput.begin(config);

  if (!result) {
    LOGE("Failed to start I2S output");
    while (1)
      ;
  }

  // Setup audio file
  // wavfileMemory.setLoop(true);
  wavfileMemory.begin();
  sig.begin();
}

void loop() {
  if (wavfileMemory) {
    copier.copy();
  } else {
    // after we are done we just print some info from the wav file
    auto info = sig.audioInfo();
    LOGI("The audio rate from the wav file is %d", info.sample_rate);
    LOGI("The channels from the wav file is %d", info.channels);
    Serial.println("Restarting...");

    // Reset file
    wavfileMemory.end();
    wavfileMemory.begin();
  }
}

[madskjeldgaard]

The pins for I2S defaults on RP2040 are defined here. It seems that DIN and LCK are switched around compared to what I expected.
What's the correct way to go?

https://github.com/pschatzmann/arduino-audio-tools/blob/main/src/AudioConfig.h#L478

[pschatzmann]

If you don't want to use the default mapping you can define your custom pins in your sketch!

Please note that for the RP2040 the ws pin can not be defined as it is the bck + 1!

ps. Don't ignore the logging messages !

[madskjeldgaard]

Okay, I figured it out now.

These are the correct default pins to use:

CORRECT PINS:
PCM5102 - PICO
SCK → GND
BCK → GPIO26
LCK → GPIO27
DIN → GPIO28
VIN → 5V

And also MAKE SURE XSMT IS PULLED LOGIC HIGH (3.3v). This is a mute, which on my cheap board was set to ON (low) by default.

[pschatzmann]

I guess you forgot to check the solder bridges

[madskjeldgaard]

@pschatzmann this means that the pins here are incorrect:

https://github.com/pschatzmann/arduino-audio-tools/wiki/External-DAC#hiletgo-pcm5102-i2s-iis-lossless-digital-audio-dac-decoder

[madskjeldgaard]

At least for my board