4 Channels WAV File with independant Volume control

[bbaldach]

Hi everybody , I try to play a 4 channels WAV File with independant Volume Control. My idea was :

AudioSourceSDMMC -> EncodedAudioOutput -> ChannelsSelectOutput -> VolumeStream 1 -> I2S_1 
                                                              |-> VolumeStream 2 -> I2S_2

WAV file played correctly but Volume has no effect. Any idea ?

/**
 * @file streams-sd_wav4-i2s.ino
 * @author Phil Schatzmann
 * @brief decode WAV file with 4 channels and output it on 2 I2S ports
 * @version 0.1
 * @date 2021-96-25
 *
 * @copyright Copyright (c) 2021
 */

#include <FS.h>
#include <SD_MMC.h>
#include "AudioTools.h"
#include "AudioCodecs/CodecMP3Helix.h"



AudioInfo info(44100, 2, 16);
AudioInfo info4(44100, 4, 16);
I2SStream i2s_1;  // final output port 0
I2SStream i2s_2;  // final output port 1
VolumeStream volume_1(i2s_1);
VolumeStream volume_2(i2s_2);
ChannelsSelectOutput out;
WAVDecoder wav;
EncodedAudioOutput decoder(&out, &wav);  // Decoding stream
StreamCopy copier;
File audioFile;

//SD MMC
int clk = 14;
int cmd = 15;
int d0 = 2;

void setup() {
    /////////////activer le MUX vers la carte SD (SD/USB) ////////
  pinMode(4, OUTPUT);
  digitalWrite(4,HIGH);
  /////////////////////////////////////////////////////////////
  Serial.begin(115200);

Serial.println("Delays 2S");
delay(2000);

  // setup file
  if (!SD_MMC.setPins(clk, cmd, d0)) {
    Serial.println("Pin change failed!");
    return;
  }

  // open sdmmc in 1 bit mode
  
  if (!SD_MMC.begin("/sdcard", true, false, 40000, 5)) {
    Serial.println("SD_MMC Error");
    stop();
  }


  AudioLogger::instance().begin(Serial, AudioLogger::Warning);

  // setup i2s
  auto config1 = i2s_1.defaultConfig(TX_MODE);
  config1.copyFrom(info);
  // config1.port_no = 0;  // 0 is default port  
  config1.port_no = 0;
  config1.pin_bck = 26;
  config1.pin_ws = 25;
  config1.pin_data = 23;
  i2s_1.begin(config1);
  
  auto config2 = i2s_2.defaultConfig(TX_MODE);
  config2.copyFrom(info);
  // use separate pins
  config2.port_no = 1;
  config2.pin_bck = 27;
  config2.pin_ws = 32;
  config2.pin_data = 33;
  i2s_2.begin(config2);


  audioFile = SD_MMC.open("/13/4.wav");

  // set initial volume
  volume_1.begin(config1); // we need to provide the bits_per_sample and channels
  volume_1.setVolume(0.0);
  volume_2.begin(config2); // we need to provide the bits_per_sample and channels
  volume_2.setVolume(0.3);

  // split channels to different i2s ports
  out.addOutput(i2s_1, 0, 1);
  out.addOutput(i2s_2, 2, 3);

  // 4 channels
  out.begin(info4);

  // setup decoder
  decoder.begin();

  // begin copy
  copier.begin(decoder, audioFile);
}

void loop() {
  if (!copier.copy()) {
    stop();
  }
}

[pschatzmann]

You don't use the volume control:
The following lines are wrong

// split channels to different i2s ports
out.addOutput(i2s_1, 0, 1);
out.addOutput(i2s_2, 2, 3);

[bbaldach]

My bad .....

[bbaldach]

// split channels to different i2s ports
out.addOutput(volume_1, 0, 1);
out.addOutput(volume_2, 2, 3);

It works now. Thank you.