A2DP->I2S -> I2S->webserver_wav, plays to fast

[andreaswatch]

Hi pschatzmann, Hi all,
I am trying to route the audio from a Android device to my multiroom audio system (LMS/Squeezelite).
Thanks to the great examples I can run basic-a2dp-audioi2s.ino on the first ESP32 and streams-i2s-webserver_wav.ino on the second ESP32.
It seems to work great so far, with the exception that it seems to play to fast. This causes short pauses in the stream and other playback errors.
I suspect that I have set the I2S settings incorrectly and ask you to take a quick look, I can't seem to get anywhere on my own and any advice would be very appreciated.

A2DP->I2S:

/**
 * @file basic-a2dp-audioi2s.ino
 * @brief A2DP Sink with output to I2SStream. This example is of small value
 * since my Bluetooth Library already provides I2S output out of the box.
 *
 * @author Phil Schatzmann
 * @copyright GPLv3
 */

#include "BluetoothA2DPSink.h"
#include "AudioConfigLocal.h"
#include "AudioTools.h"

BluetoothA2DPSink a2dp_sink;
I2SStream i2s;

// Write data to SPDIF in callback
void read_data_stream(const uint8_t *data, uint32_t length) {
  i2s.write(data, length);
}

void setup() {
  Serial.begin(115200);
  AudioLogger::instance().begin(Serial, AudioLogger::Warning);

  // register callback
  a2dp_sink.set_stream_reader(read_data_stream, false);
  
  // Start Bluetooth Audio Receiver
  a2dp_sink.set_auto_reconnect(true);
  a2dp_sink.start("a2dp-i2s");

  // setup output
  auto config = i2s.defaultConfig();
  config.pin_data = 22;
  config.pin_bck = 23;
  config.pin_ws = 27;
  config.channels = 2;
  config.is_master = true;
  config.fixed_mclk = false;

  config.i2s_format = I2S_LSB_FORMAT; // if quality is bad change to I2S_LSB_FORMAT https://github.com/pschatzmann/arduino-audio-tools/issues/23

  Serial.println(a2dp_sink.sample_rate());
  config.sample_rate = a2dp_sink.sample_rate();// 32000 ;//44100;// a2dp_sink.sample_rate();


  config.bits_per_sample = I2S_BITS_PER_SAMPLE_16BIT;
  //cfg.i2s_format = i2s_comm_format_t(I2S_COMM_FORMAT_I2S | I2S_COMM_FORMAT_I2S_MSB);
  //cfg.buffer_count = 10;
  //cfg.buffer_size = 512;

  i2s.begin(config);
}

void loop() { delay(100); }

I2S->webserver_wav

/**
 * @file streams-i2s-webserver_wav.ino
 *
 *  This sketch reads sound data from I2S. The result is provided as WAV stream which can be listened to in a Web Browser
 *
 * @author Phil Schatzmann
 * @copyright GPLv3
 */

#include "AudioTools.h"

//AudioEncodedServer server(new WAVEncoder(),"ssid","password");  
AudioWAVServer server("wifi","pass"); // the same a above

I2SStream i2sStream;    // Access I2S as stream
ConverterFillLeftAndRight<int16_t> filler(RightIsEmpty); // fill both channels - or change to RightIsEmpty

void setup(){
  Serial.begin(115200);
  //AudioLogger::instance().begin(Serial, AudioLogger::Info);

  // start i2s input with default configuration
  Serial.println("starting I2S...");
  auto config = i2sStream.defaultConfig(RX_MODE);
  config.pin_data = 22;
  config.pin_bck = 23;
  config.pin_ws = 27;
  config.channels = 2;
  config.is_master = false;
  config.fixed_mclk = false;

  config.i2s_format = I2S_LSB_FORMAT; // if quality is bad change to I2S_LSB_FORMAT https://github.com/pschatzmann/arduino-audio-tools/issues/23
  config.sample_rate = 44100;//32000 ;//44100;

  config.bits_per_sample = I2S_BITS_PER_SAMPLE_16BIT;
  //config.i2s_format = i2s_comm_format_t(I2S_COMM_FORMAT_I2S | I2S_COMM_FORMAT_I2S_MSB);
  //config.buffer_count = 10;
  //config.buffer_size = 512;

  i2sStream.begin(config);
  Serial.println("I2S started");

  // start data sink
  server.begin(i2sStream, config, &filler);
  //server.begin(i2sStream, config);
}

// Arduino loop  
void loop() {
  // Handle new connections
  server.doLoop();  
}

[pschatzmann]

I never tried to connect 2 ESP32 via I2S, but others seem to have the same issues as well:
#149

I would suggest to try to set use_apll = true and play around with the buffer settings but my assumption is that the issue comes because the master clock between the 2 devices are not synchronised. Unfortunately, to my knowledge it is not possible to use the master clock as input...

If you have an oscilloscope you could define pin_mck on both devices and compare the frequency.

[andreaswatch]

Thank you, I did not recognize that the same issue is already discussed in #149.
Unfortunately use_apll = true did not improve the behavior.
I have no osscilloscope available and yes, looks like we can not use the mclk as input.

Other question: Is there a good alternative way to connect two ESP's for audio processing (e.g. I2C or others)?
Any suggestions for a alternative SBC with BT and WIFI?

[pschatzmann]

I suggest to look into ESP-Now as a wireless transmission protocol. But any connection (even serial) should be feasable.

You would just use a CODEC to reduce the amount of data which is transmitted and reduce the sampling rate and/or number of channels if necessary.