feat: add spago derivation

build.nix

@@ -0,0 +1,84 @@
+{ system
+, nixpkgs
+, purescript-overlay
+, slimlock
+, nix-filter
+}:
+let
+  pkgs = import nixpkgs {
+    inherit system;
+    overlays = [
+      purescript-overlay.overlays.default
+      (self: super: { purescript = self.purs-unstable; nodejs = super.nodejs_18; })
+      slimlock.overlays.default
+    ];
+  };
+  spagoDependencies = pkgs.purix.buildSpagoLock { src = ./.; };
+  nodeDependencies = pkgs.slimlock.buildPackageLock { src = ./.; };
+in
+pkgs.stdenv.mkDerivation {
+  name = "spago";
+
+  phases = [ "buildPhase" "installPhase" ];
+
+  nativeBuildInputs = [
+    pkgs.purs-unstable
+    pkgs.spago-unstable
+    pkgs.nodejs_18
+    pkgs.python3
+    pkgs.git
+    pkgs.installShellFiles
+  ];
+
+  src = nix-filter.lib {
+    root = ./.;
+    include = [
+      "src"
+      "bin"
+      "core"
+      "test"
+      "test-fixtures"
+      "test-fixtures"
+      "LICENSE"
+      "package-lock.json"
+      "package.json"
+      "README.md"
+      "spago.lock"
+      "spago.yaml"
+    ];
+  };
+
+  buildPhase = ''
+    cd $src
+          
+    chmod +w -R .
+
+    cp -r ${nodeDependencies}/js/node_modules .
+    cp -r ${spagoDependencies.spago-bin}/output .
+
+    spago bundle --offline -p spago-bin
+
+    mkdir -p $out/package
+    cp bin/bundle.js package.json README.md LICENSE $out/package
+  '';
+
+  installPhase = ''
+    PACKAGE=$out/node_modules/spago
+    mkdir -p $PACKAGE
+    mv $out/package/* $PACKAGE/
+
+    BIN=$PACKAGE/bundle.js
+    chmod +x $BIN
+    patchShebangs $BIN
+
+    SPAGO=$out/bin/spago
+
+    mkdir -p $out/bin
+    ln -s $BIN $SPAGO
+
+    BASH_COMPLETIONS=$out/share/bash-completion/completions/
+    mkdir -p $BASH_COMPLETIONS
+    $SPAGO --bash-completion-script $SPAGO > $BASH_COMPLETIONS/spago
+  '';
+}
+

flake.nix

@@ -3,6 +3,9 @@
     nixpkgs.url = "github:NixOS/nixpkgs/nixos-23.05";
     purescript-overlay.url = "github:thomashoneyman/purescript-overlay";
     purescript-overlay.inputs.nixpkgs.follows = "nixpkgs";
+    flake-utils.url = "github:numtide/flake-utils";
+    slimlock.url = "github:thomashoneyman/slimlock";
+    nix-filter.url = "github:numtide/nix-filter";
   };
 
   outputs = { self, nixpkgs, ... }@inputs:
@@ -22,7 +25,8 @@
       };
 
       devShells = forAllSystems (system:
-        let pkgs = nixpkgsFor.${system}; in {
+        let pkgs = nixpkgsFor.${system}; in
+        {
           default = pkgs.mkShell {
             name = "spago";
             buildInputs = with pkgs; [
@@ -36,5 +40,11 @@
             ];
           };
         });
+
+      packages = forAllSystems (system: {
+        default = import ./build.nix {
+          inherit system nixpkgs; inherit (inputs) slimlock purescript-overlay nix-filter;
+        };
+      });
     };
 }