Deploy Remix app in AWS Lambda using Terraform

[zlberto]

Could you provide documentation on how to deploy a Remix app in AWS Lambda using Terraform?

[dhstevev]

@zlberto Were you able to figure out a good approach here?

[pmlk]

This guide helped me mostly with remix (vite) on AWS lambda: https://dev.to/gautierblandin/deploying-remix-vite-on-lambda-using-pulumi-41oj

I only followed it until the node build.cjs part. That takes care of creating a ./build/lambda/index.cjs file with a handler function, which is the entry point for lambda. Then I used the following terraform code to deploy it that way rather than with Pulumi which is what they used.

Note that the file is located in ./deployment/ which is mostly relevant for the relative path in the data "archive_file" .... Adjust according to your needs.

# ./deployment/lambda.tf

resource "aws_lambda_function" "http" {
  filename      = "lambda_function.zip"
  function_name = "http"
  role          = aws_iam_role.iam_for_remix_vite_lambda.arn
  handler       = "index.handler"
  architectures = ["arm64"]

  source_code_hash = data.archive_file.lambda.output_base64sha256

  runtime = "nodejs20.x"

  environment {
    variables = {
      foo = "bar"
    }
  }
}

resource "aws_lambda_function_url" "furl" {
  authorization_type = "NONE"
  function_name = aws_lambda_function.http.function_name
}

data "aws_iam_policy_document" "assume_role" {
  statement {
    effect = "Allow"

    principals {
      type        = "Service"
      identifiers = ["lambda.amazonaws.com"]
    }

    actions = ["sts:AssumeRole"]
  }
}

resource "aws_iam_role" "iam_for_remix_vite_lambda" {
  name               = "iam_for_remix_vite_lambda"
  path               = "/service-role/"
  assume_role_policy = data.aws_iam_policy_document.assume_role.json
}

data "archive_file" "lambda" {
  type        = "zip"
  source_file = "${path.module}/../build/lambda/index.cjs"
  output_path = "lambda_function.zip"
}

output "lambda_url" {
  value = aws_lambda_function_url.furl.function_url
}