Make a random selection from a playlist

[TomKranenburg]

So I've been going through the documentation. How can I change the below single track, to a random single selection from a playlist?:

time_queue = request.queue()

def queue_track(url) = 
  time_queue.push(request.create(url))
end

thread.when(predicate.activates({17h00m}), {list.iter(queue_track, ["\\\\CITADEL\\Archive\\Music\\Music Archive\\Vangelis - Blade Runner Blues (Leviathan Radio Edit).mp3"])})

radio = fallback(track_sensitive=false, [time_queue, radio])

I've been going through the documentation and the book and there's not much to go on.

[gAlleb]

Hi @TomKranenburg.

I think it's not a usual use case, that's why it's not in a book (actually you can see something similar on pages 85-86). Some thinking should be made, which I've tried to do)) Should work.
Came up with this:

radio = playlist("default_playlist)

# Define playlist_1 as a path to `playlist file`
playlist_1 = "path/to/playlist_1.m3u"
 
# Good old `time_queue`
time_queue = request.queue()

# Here we are loading a random track from playlist_1
def queue_music_from_playlist() =
  # Reading lines from the playlist
  playlist_lines = process.read.lines("cat #{playlist_1}")
  # Getting random track from the lines
  random_track = list.nth(playlist_lines, random.int(min=0, max=list.length(playlist_lines)))  
  # Pushing a random track
  time_queue.push(request.create(random_track))
end

# At 11:47:20 we push a random track from playlist to request.queue()
thread.when(predicate.activates({11h47m20s}), queue_music_from_playlist)

radio = fallback(track_sensitive=false, [time_queue, radio])
radio = mksafe(radio)
output.dummy(radio)

[TomKranenburg]

@gAlleb you legend. I think you came up with the original method. Thanks again for this. You have my word I've been going through the manual.

I'll give it a try tonight.

[gAlleb]

Actually you can see something similar on pages 85-86 and more stuff. So eventually it's possible to build whatever you need

For example you don't have to make a playlist file. Instead you can use a directory.

playlist_1_dir = "/path/to/music"

# and then 

playlist_lines = process.read.lines("find  #{playlist_1_dir} -type f")
...

Or you can make a playlist file but shuffle it every time and pick the first entry instead of picking random:

  playlist_lines = process.read.lines("cat #{playlist_1}")
  playlist_lines = list.shuffle(playlist_lines)
  random_track = list.hd(playlist_lines)  

[gAlleb]

Ah, almost forgot. You have a very strange file path;) If you’re using OS witch doesn’t have cat command (I’m not sure if it’s everywhere) - you should change process.read.line and use this instead:

playlist_lines = playlist.files("#{playlist_1}")
it’s straight from a playlist function so should work everywhere.

radio = playlist("default_playlist)

# Define playlist_1 as a path to `playlist file`
playlist_1 = "path/to/playlist_1.m3u"
 
# Good old `time_queue`
time_queue = request.queue()

# Here we are loading a random track from playlist_1
def queue_music_from_playlist() =
  # Reading lines from the playlist
  playlist_lines = playlist.files("#{playlist_1}")
  # Getting random track from the lines
  random_track = list.nth(playlist_lines, random.int(min=0, max=list.length(playlist_lines)))  
  # Pushing a random track
  time_queue.push(request.create(random_track))
end

# At 11:47:20 we push a random track from playlist to request.queue()
thread.when(predicate.activates({11h47m20s}), queue_music_from_playlist)

radio = fallback(track_sensitive=false, [time_queue, radio])
radio = mksafe(radio)
output.dummy(radio)

And as an option. So there wouldn't be any repeats (because of randomization) - function which returns a request made from the first element of the shuffled list and then this first element is removed from the list until there is no more - then list is reloaded:

radio = playlist("playlist.m3u")
playlist_1 = "path/to/playlist.m3u"

time_queue = request.queue()

# Get the lines from the playlist and shuffle it
playlist_lines = ref(list.shuffle(playlist.files("#{playlist_1}")))

# Function 
def dynamic_queue_music_request() =

     # If list is not empty - push random track to queue, exclude it from the list so it won't play again
	if not (list.is_empty(playlist_lines())) then
          
	  random_track = list.hd(playlist_lines())
	  playlist_lines := list.tl(playlist_lines())
	  time_queue.push(request.create(random_track))

	else

      # If all tracks have played and list is empty - reload playlist, shuffle it, push random track to queue exclude it from the list so it won't play again :)

          try
	    playlist_lines := playlist.files(("#{playlist_1}")) 
	    playlist_lines := list.shuffle(playlist_lines())
	    random_track = list.hd(playlist_lines())
	    playlist_lines := list.tl(playlist_lines())
	    time_queue.push(request.create(random_track))
	  catch err do
	    log(level=3, label="time_queue", "#{error.kind(err)} - #{error.message(err)}")
	  end

        end

end

thread.when(predicate.activates({11h47m20s}), dynamic_queue_music_request)

[Moonbase59]

Wild workarounds appearing here! ;-)

My heretic 2 cents: Couldn’t this be achieved much easier using the builtin functions?

# The radio playlist
radio = playlist("/home/matthias/Musik/Playlists/Radio/Classic Rock.m3u")

# The "timed" playlist, or folder
timed_tracks = playlist("/home/matthias/Musik/Other/Jingles/Programm")

radio = fallback(
    track_sensitive=false,
    [
        switch([(predicate.once({17h00m}), timed_tracks)]),
        radio
    ]
)

# This is only test output stuff
radio = amplify(override="replaygain_track_gain", 1.0, radio)
radio = mksafe(radio)
output.ao(radio)

You can test this using a time predicate of {0s} instead of {17h00m}. It will then play a new jingle every full minute.

You can even specify nice transitions with fallback or switch, but I left these out for a simpler example. Same for reload_mode="watch" with the playlist.

[gAlleb]

💯
It's actually awesome. After struggling to make it work with

radio = switch(track_sensitive=false,[
    (predicate.once({17h00}), playlist_1),
    ({true}, radio)
])

Because it doesn't work (track_sensitive=false and predicate don't work together in switch alone), I've completely forgotten that we can use switch and fallback together to achieve this.
Ha! Why can't I keep things simple? :))

[Moonbase59]

It misleads, right? Your code shown here was exactly my first idea! And I wondered why the log showed the switching (and immediately switching back)—without apparently anything happening. Then I remembered my TOTH overlay code, and thought "HA!"—leading to above. :-)

@smimram, @toots: Maybe one for the cookbook?