Switching between sources

[AlexandrosEmvoliadis]

So, my task is to build a backend for a webradio with several automations. I have a front-end (html) and a back-end (flask) that communicate with each other and the back-end also communicates with the liquidsoap via telnet. I have a button that switches between 2 sources: a fallback_playlist and a microphone. I have observed that, when i switch from speech back to music, the source continues from the segment i have pushed the button. Why is that? Why doesn't the "silent" source continue in silence? Is there another workaround?

Below you can find my snippet

set("server.telnet", true)
set("server.telnet.port", 1234)

dynamic_queue = request.queue(id="music_queue")

initial_playlist = playlist("music_pool_playlist.m3u")

fallback_playlist = fallback([dynamic_queue, initial_playlist])

mic = sine()

b = interactive.bool("button", true)
shutdown_requested = interactive.bool("shutdown_requested", false)

radio_stream = switch(track_sensitive=false, [
(shutdown_requested, blank()),
(b, fallback_playlist),
({true}, mic)
])

radio_stream = crossfade(duration=2.0, fade_in=2.0, fade_out=2.0, radio_stream)

def shutdown_blank_handler() =
log("Stream has been blank for too long! Performing custom action.")
shutdown()
end

radio_stream = blank.detect(shutdown_blank_handler, radio_stream)

output.ao(radio_stream, fallible=true)
output.file(%mp3, "out.wav", radio_stream, fallible=true)
output.icecast(%mp3,
host="localhost", port=8000, password="password", mount="stream",
radio_stream, fallible=true)

[Mikulskii]

If I understood correctly, then you just need to set track_sensitive=true in the switch statement. Then the switching will take place at the end of the track, therefore, when returning to the playlist there will be a new track. Or add a skip() function call as a workaround in some way. Silence I believe is endless source

[AlexandrosEmvoliadis]

Yes that's true, but what if i would like to talk in between the songs?

[AlexandrosEmvoliadis]

To put this straight:
switch pauses (b is false) the music source (fallback_playlist) and when b is true again, the fallback continues from the pause, which i would like to avoid

[Mikulskii]

Um, why is track_sensitive=true not suitable for you?
Press the button->the current track finishes playing->your speech->press the button->a new track is playing from the beginning

[AlexandrosEmvoliadis]

I would like to talk in between the songs and not interrupt the continuous of the playlist.

If this is impossible (i'm trying to figure it out about a week now), i will follow either this way, or the one gAlleb suggested below

[AlexandrosEmvoliadis]

Another workaround would be to gradually increase and decrease the levels when b is true/false, but i do not know how can this be implemented.

[AlexandrosEmvoliadis]

Thank you for your time. Won't this result into a new track each time i open the mic?

[gAlleb]

it would. Track will be skipped.
Also the scheme without interruption proposed by @Mikulskii is fine too.
Moreover you can use add or smooth_add to play mic over the playing source (without interruption).

[AlexandrosEmvoliadis]

Can you provide an example regarding the add or smooth add, please?
Thanks

[gAlleb]

You can find smooth_add here https://www.liquidsoap.info/book/book.pdf Page 122.
add is described on page 102.

However it has some downsides:

radio = add(normalize=false, [mic, bed])
but beware that this might result into some clipping if the two sources are loud,
which is never nice to hear, see also section 6.5.
As a side note, the operator add only adds the sources which are ready. This
means that if mic is taken from a harbor input such as
mic = input.harbor("mic")
and the client did not connect or was disconnected, we will hear only the bed,
as expected.

Reading that you want I would like to talk in between the songs and not interrupt the continuous of the playlist. the track_sensitive=true option by @Mikulskii seems most suitable.

But I think if you'll give some more pondering into the issue you can come up with a bit more complex but more sophisticated logic to meet all of your needs. You can look at the azuracast livedj panel and the code which accompanies it (https://github.com/AzuraCast/AzuraCast/)

[AlexandrosEmvoliadis]

Thanks, man!

[AlexandrosEmvoliadis]

To anyone interested in this task, trying to solving it directly through liquidsoap is not feasible (at least me 1-2 weeks experimentation has showed me so). Thanks for the advice and the time!

[gAlleb]

Hi @AlexandrosEmvoliadis,

And what's not working?

Here's simple script. Didn't put much thought into it, just to show:

settings.harbor.bind_addrs := ["0.0.0.0"]
interactive.harbor(port=8007, uri="/djpanel")
volume_playlist = interactive.float("volume_playlist", min=0., max=1., 1.)
volume_overall = interactive.float("volume_overall", min=0., max=1., 1.)
volume_mic = interactive.float("volume_mic_add", min=0., max=1., 1.)
pause_playlist = interactive.bool("pause_playlist",false)

radio =	playlist(mode="randomize", reload_mode="watch", "/music.m3u8")
radio = amplify(volume_playlist, radio)

def skipper(_)
radio.skip()
http.response(data="The song from the playlist was skipped!")
end
harbor.http.register.simple(port=8007, "/skip", skipper)

blank = blank()

radio = switch(track_sensitive=false, [
  ({pause_playlist() == true}, blank),
  ({true}, radio)
])

mic_add = input.harbor("mic_add", port=8006, password="hackme")
mic_add = amplify(volume_mic, mic_add)

radio = add(normalize=false,[mic_add,radio])

radio = amplify(volume_overall, radio)

output(radio)

We got input.harbor.
If you connect to mic_add mountpoint - it would be available instantly. You talk, playlist plays in a background. And if you go to localhost:8007/djpanel you can control volume of your playlist and of your mic_add with volume_playlist and volume_mic_add.
With volume_overall you control overall volume.
You can connect, check pause_playlist box and playlist will stop, uncheck - it will resume. You can fade the volume of playlist, pause it and skip it (localhost:8007/skip), and talk, then you can resume playlist from the next song.

Now you have all the options whether you wanna talk between tracks or at the same time, resume from where you've paused or start from new track. Then add transitions, crossfade, all other stuff...

[AlexandrosEmvoliadis]

At first, it seems that switch completely pauses the primary source. Then, source.skip skips to the next second. I might have set some things wrong. To be more specific, i would like to fade in & out between music and speech even in the middle of the current song, but continue to play the song in the background. I have tried a numerous ways to achieve this behavior (fun fact, i have found a way of achieving that by generating ~100 sources that crossfade between them, but it was resource intense), but nothing seem to be efficient.

[AlexandrosEmvoliadis]

As i read my comments now, i have put my requirements in a very misleading way, apologies for that. Of course, the suggested methods have been tested and worked towards the "false" requirements! Again, thank you very much for your time!

[gAlleb]

To be more specific, i would like to fade in & out between music and speech even in the middle of the current song, but continue to play the song in the background.

That is exactly what radio = smooth_add(duration=3., p=0.3, normal=radio, special=mic_add) would do apart from fading out mic_add at the end 'cause it just can't calculate that. It can be done manually. But it will fade out the playlist to 30%, fade in mic, then in the end fade in playlist again from 30% to 100%.

[AlexandrosEmvoliadis]

That didn't work either, have you tried the suggested solution with smooth_add?

[gAlleb]

Of course. Here is the script. Try connecting to input.harbor. Volume sliders won't work as expecteed cause smooth_add has it's inner controls.

settings.harbor.bind_addrs := ["0.0.0.0"]
interactive.harbor(port=8007, uri="/djpanel")
volume_playlist = interactive.float("volume_playlist", min=0., max=1., 1.)
volume_overall = interactive.float("volume_overall", min=0., max=1., 1.)
volume_mic = interactive.float("volume_mic_add", min=0., max=1., 1.)
pause_playlist = interactive.bool("pause_playlist",false)

radio =	playlist(mode="randomize", reload_mode="watch", "/music.m3u8")
radio = amplify(volume_playlist, radio)

def skipper(_)
radio.skip()
http.response(data="The song from the playlist was skipped!")
end
harbor.http.register.simple(port=8007, "/skip", skipper)

blank = blank()

radio = switch(track_sensitive=false, [
  ({pause_playlist() == true}, blank),
  ({true}, radio)
])

mic_add = input.harbor("mic_add", port=8006, password="hackme")
mic_add = amplify(volume_mic, mic_add)

#radio = add(normalize=false,[mic_add,radio])
radio = smooth_add(duration=3., p=0.3, normal=radio, special=mic_add)

radio = amplify(volume_overall, radio)

output(radio)