build.gradle

plugins {
    id 'groovy'
    id 'idea'    
    id 'application'
    id "org.hidetake.swagger.generator" version "2.18.2"
}

repositories {
    mavenLocal()
    mavenCentral()
}

dependencies {
    implementation 'javax.validation:validation-api:2.0.1.Final'
    implementation 'javax.annotation:javax.annotation-api:1.3.2'

    implementation "org.codehaus.groovy:groovy:$groovyVersion"
    implementation "org.codehaus.groovy:groovy-json:$groovyVersion"

    implementation "com.fasterxml.jackson.core:jackson-databind:2.13.0"

    implementation "org.apache.commons:commons-text:1.9"
    implementation 'com.rabbitmq:amqp-client:5.13.1'

    implementation 'io.swagger.core.v3:swagger-annotations:2.0.7'
    implementation 'io.springfox:springfox-swagger2:2.9.2'

    swaggerCodegen 'org.openapitools:openapi-generator-cli:3.3.4'
}

application {
    mainClassName = 'dupla.underretning.klient.UnderretningTestClient'
}

swaggerSources {
    underretning {
        inputFile = file("$rootDir/src/main/resources/underretning-ekstern.yaml")
        code {
            language = 'spring'
            configFile = file("$rootDir/src/main/resources/codegen-underretning.json")
            components = ['models']
        }
    }
}

compileJava.dependsOn swaggerSources.underretning.code
sourceSets.main.java.srcDir "${swaggerSources.underretning.code.outputDir}/src/main/java"
sourceSets.main.resources.srcDir "${swaggerSources.underretning.code.outputDir}/src/main/resources"