build.gradle

plugins {
    id "com.github.ben-manes.versions" version "0.51.0"
    id "build-dashboard"
    id 'idea'
}

allprojects {
    group = 'io.github.stewartbryson'

    repositories {
        mavenCentral()
        gradlePluginPortal()
    }
}

if (hasProperty('buildScan')) {
    buildScan {
        termsOfServiceUrl = 'https://gradle.com/terms-of-service'
        termsOfServiceAgree = 'yes'
    }
}

import org.apache.tools.ant.filters.ReplaceTokens
tasks.register('copyReadme', Copy) {
    group 'documentation'
    description 'Update README.md file with current version.'
    from('src/markdown') {
        include 'README.md'
        filter(ReplaceTokens, tokens: [version: version])
    }
    into '.'
}

tasks.register('copyExamples', Copy) {
    group 'documentation'
    description 'Token replacement of current version in examples.'
    from('src/examples') {
        include '*/build.gradle'
        filter(ReplaceTokens, tokens: [version: version])
    }
    into 'examples'
    mustRunAfter copyReadme
}

tasks.register('examples') {
    group 'documentation'
    description 'Update README and example build.gradle files with current version.'
    dependsOn copyReadme, copyExamples
}