build.gradle

plugins {
	id 'fabric-loom' version '1.3-SNAPSHOT'
	id 'com.matthewprenger.cursegradle' version '1.4.0'
	id "com.modrinth.minotaur" version "2.+"
	id 'maven-publish'
}


sourceCompatibility = JavaVersion.VERSION_17
targetCompatibility = JavaVersion.VERSION_17

archivesBaseName = project.archives_base_name
version = project.mod_version
group = project.maven_group


repositories {
	mavenLocal()
	mavenCentral()
	maven { url 'https://maven.fabricmc.net/' }
	maven { url "https://maven.shedaniel.me/" }
	maven { url "https://maven.terraformersmc.com/releases/" }
}

runClient.doFirst {
	args = ['--username', "couturey${new Random().nextInt(1000)}"]
}

loom {
    runs {
		// This adds a new gradle task that runs the datagen API: "gradlew runDatagen"
		datagen {
			inherit server
			name "Data Generation"
			vmArg "-Dfabric-api.datagen"
			vmArg "-Dfabric-api.datagen.output-dir=${file("src/main/generated")}"
			vmArg "-Dfabric-api.datagen.modid=f3c"
 
			runDir "build/datagen"
		}
	}
}

// Add the generated resources to the main source set
sourceSets {
	main {
		resources {
			srcDirs += [
					'src/main/generated'
			]
		}
	}
}
dependencies {
	minecraft "com.mojang:minecraft:${project.minecraft_version}"
	mappings "net.fabricmc:yarn:${project.yarn_mappings}:v2"
	modImplementation "net.fabricmc:fabric-loader:${project.loader_version}"

	modImplementation "net.fabricmc.fabric-api:fabric-api:${project.fabric_version}"

	modApi("me.shedaniel.cloth:cloth-config-fabric:${project.cloth_config_version}")
	modApi "com.terraformersmc:modmenu:${project.modmenu_version}"

	implementation 'com.moandjiezana.toml:toml4j:0.7.2'
}

processResources {
	filesMatching('fabric.mod.json') {
		expand 'version': version,
				'minecraft_version': minecraft_version,
				'minecraft_dependency': minecraft_version,
				'loader_version': loader_version
	}
}

tasks.withType(JavaCompile).configureEach {
	it.options.encoding = 'UTF-8'
	it.options.release = 17
}

java {
	withSourcesJar()
}

jar {
	from("LICENSE") {
		rename { "${it}_${archivesBaseName}" }
	}
}

tasks.modrinth.configure({
	group = 'upload'
})
tasks.modrinthSyncBody.configure({
	group = 'upload'
})

modrinth {
	token = file("${rootDir}/modrinth_token.txt").exists() ? file("${rootDir}/modrinth_token.txt").text : ''
	projectId = modrinth_id
	versionNumber = "fabric-${mod_version}"
	versionName = "[FABRIC][${minecraft_version}] ${mod_name} ${mod_version}"
	uploadFile = jar
	versionType = release_type.toUpperCase()
	changelog = file('changelog.md').text
	gameVersions = [minecraft_version]
	loaders = ['fabric']
	dependencies {
//		optional.project 'mOgUt4GM' // ModMenu
//		optional.project '9s6osm5g' // ClothConfig
	}
	syncBodyFrom = file("${rootDir}/readme.md").text
}
tasks.modrinth.dependsOn(build)