build.gradle

buildscript {
    repositories {
        google()
        jcenter()
    }
    dependencies {
        classpath "com.android.tools.build:gradle:3.3.2"
    }
}

plugins {
    id "maven-publish"
    id "com.github.technoir42.aar-publish" version "1.0.0"
    id "com.jfrog.bintray" version "1.8.4"
}

apply plugin: "com.android.library"

group = "com.sch.stetho"
version = "1.0.0"

android {
    compileSdkVersion 28

    defaultConfig {
        minSdkVersion 16
        targetSdkVersion 28
    }

    lintOptions {
        warningsAsErrors true
        informational "GradleDependency"
    }

    libraryVariants.all {
        it.generateBuildConfigProvider.configure { it.enabled = false }
    }
}

repositories {
    google()
    jcenter()
}

dependencies {
    implementation "net.zetetic:android-database-sqlcipher:3.5.9"
    implementation "com.facebook.stetho:stetho:1.5.0"
}

publishing {
    publications {
        maven(MavenPublication) {
            from components.android
        }
    }
}

bintray {
    user = findProperty("BINTRAY_USER")
    key = findProperty("BINTRAY_KEY")
    publish = true
    pkg {
        repo = "maven"
        name = "stetho-sqlcipher"
        licenses = ["Apache-2.0"]
        vcsUrl = "https://github.com/technoir42/stetho-sqlcipher.git"
        version {
            name = project.version
        }
        publications = ["maven"]
    }
}