Extraneous "sio:UncertaintyValue" linked to import of DegreeOfCrystallization?

[mdeagen]

Scroll to bottom for relevant SPARQL queries.

Query A returns a list of DOIs that have nanocomposite attributes linked to some uncertainty value (rdf:type sio:UncertaintyValue). A few of the DOIs seem to have nonsensical uncertainty values for attributes such as DOI, ISBN, ISSN, Issue, Keyword, Language, Publication Year, Publisher, Author, Date of Citation, Date of Measurement, etc.

Query B returns the attribute type and uncertainty value for one of these DOIs. The results seem to indicate that a "correct" uncertainty value for a particular attribute is being propagated across other attributes.

Inspection of one of the XML files (L212_S3_Ghanbari_2012.xml) suggests that the problem lies in the SETLr conversion. The nonsensical uncertainty values for this sample returned by the SPARQL query all have the value "0.1"^{^^xsd:double}. The DegreeOfCrystallization attribute in the XML is linked to 0.1 uncertainty, but does NOT get returned by the SPARQL query, indicating that the issue probably lies with how Degree of Crystallization values are imported into the KG.

---

Query A

# DOIs with reported uncertainty values from curation
PREFIX rdfs: <http://www.w3.org/2000/01/rdf-schema#>
PREFIX dct: <http://purl.org/dc/terms/>
PREFIX sio: <http://semanticscience.org/resource/>
PREFIX nm: <http://nanomine.org/ns/>
SELECT DISTINCT ?doi (COUNT(DISTINCT ?PropertyType) AS ?PropertyCount) (GROUP_CONCAT(DISTINCT ?PropertyType; SEPARATOR=", ") AS ?ListOfProperties) WHERE {
  ?doi a dct:BibliographicResource ;
       sio:hasPart ?sample .
  ?sample a nm:PolymerNanocomposite ;
          sio:hasAttribute ?attr ;
          sio:hasComponentPart [ sio:hasRole [ a nm:Matrix ] ;
                                 a [ rdfs:label ?Matrix ] ] ,
                               [ sio:hasRole [ a nm:Filler ] ;
                                 a [ rdfs:label ?Filler ] ;
                                 sio:hasAttribute [ a nm:MassFraction ;
                                 sio:hasValue ?MassFraction ] ] .
  ?attr a [ rdfs:label ?PropertyType ] ; 
        sio:hasAttribute [ a sio:UncertaintyValue ; 
                           sio:hasValue ?uncertainty ] 
}
GROUP BY ?doi
ORDER BY DESC (?PropertyCount)

Query B

PREFIX rdfs: <http://www.w3.org/2000/01/rdf-schema#>
PREFIX dct: <http://purl.org/dc/terms/>
PREFIX sio: <http://semanticscience.org/resource/>
PREFIX nm: <http://nanomine.org/ns/>
SELECT DISTINCT ?sample ?PropertyType ?uncertainty WHERE {
  <http://dx.doi.org/10.1016/j.polymer.2012.12.066> a dct:BibliographicResource ;
       sio:hasPart ?sample .
  ?sample a nm:PolymerNanocomposite ;
          sio:hasAttribute ?attr ;
          sio:hasComponentPart [ sio:hasRole [ a nm:Matrix ] ;
                                 a [ rdfs:label ?Matrix ] ] ,
                               [ sio:hasRole [ a nm:Filler ] ;
                                 a [ rdfs:label ?Filler ] ;
                                 sio:hasAttribute [ a nm:MassFraction ;
                                 sio:hasValue ?MassFraction ] ] .
  ?attr a [ rdfs:label ?PropertyType ] ; 
        sio:hasAttribute [ a sio:UncertaintyValue ; 
                           sio:hasValue ?uncertainty ]
  FILTER(?sample = <http://nanomine.org/sample/l212-s3-ghanbari-2012>)
}