Jenkinsfile

@Library('visenze-lib')_

pipeline {
  // choose a suitable agent to build
  agent {
    label "${params.AGENT_LABEL ?: 'build-arm64'}"
  }

  options {
    timestamps()
  }

  parameters {
    string(name: 'DOCKER_REGISTRY', defaultValue: '', description: 'leave empty to use dockerhub as registry')
    string(name: 'DOCKER_REGISTRY_CREDENTIAL', defaultValue: 'docker-hub-credential',
        description: 'The credential ID stored in Jenkins to pull/push to docker registry')
    string(name: 'AGENT_LABEL', defaultValue: '', description: 'The label of the agent to run the build')
  }

  stages {
    stage('Checkout') {
      steps {
        // checkout the code from scm (github)
        checkout scm
      }
    }

    stage('Package') {
      steps {
        script {
          sh("docker run --rm -v ${WORKSPACE}:${WORKSPACE} -v ${HOME}/.m2:/root/.m2 -w ${WORKSPACE} maven:3.9-amazoncorretto-11 mvn clean compile package install") 
        }
      }
    }

    stage('Docker Build and Push') {
      when {
        expression {
          return doBuildAndTest(env.BRANCH_NAME)
        }
      }
      steps {
        script {
          // assume the Dockerfile is directly under WORKSPACE
          def commitHash = getCommit()
          def version = getVersion()
          // push all the tags
          def tags = genDockerTags(env.BRANCH_NAME, commitHash, version, env.BUILD_NUMBER)
          // keep the last tag as a global variable used by later stages
          TAG = tags[-1]

          def tagsString = tags.collect{"-t visenze/dubbo-admin:${it}"}.join(" ")
          docker.withRegistry(params.DOCKER_REGISTRY, params.DOCKER_REGISTRY_CREDENTIAL) {
            sh "docker buildx create --use"
            sh "docker buildx build ${tagsString} -f docker/Dockerfile --push --platform linux/arm64,linux/amd64 ."
          }
        }
      }
    }


    stage('Archive') {
      when {
        expression {
          return doBuildAndTest(env.BRANCH_NAME) || isProdRelease(env.BRANCH_NAME)
        }
      }
      steps {
        script {
          def archive = [
            docker_tag: TAG,
            version: getVersion(),
            docker_repos: ['visenze/dubbo-admin']
          ]
          writeFile(file: "${WORKSPACE}/version.json", text: groovy.json.JsonOutput.toJson(archive))
          archiveArtifacts(artifacts: "version.json", allowEmptyArchive: true)
        }
      }
    }
  }

}

// Get commit sha
def getCommit() {
  return sh(
    script: "(cd '${WORKSPACE}'; git rev-parse HEAD)", returnStdout: true
  ).trim()
}

def getVersion() {
  // read version from pom
  return readMavenPom(file: 'pom.xml').properties.revision
}

def genDockerTags(branch, commit, version=null, buildNumber=null) {
  def tags = []
  def shortCommit = commit.substring(0, 9)
  tags.add(branch.replaceAll("/", "_"))
  tags.add("${branch.replaceAll("/", "_")}-${shortCommit}")
  //if(branch == 'production') {
  //  assert version !=null
  //  tags.add("${version}")
  //} else {
  //  assert version != null && buildNumber != null
  //  tags.add("${version}.${buildNumber}-${shortCommit}")
  //}
  return tags
}

def doBuildAndTest(branch) {
  return branch.startsWith('feature') || branch == 'staging' || branch == 'production'
}

def isProdRelease(branch) {
  return env.BRANCH_NAME == "production"
}