build.gradle

buildscript {
    ext {
        kotlinVersion = '1.6.10' // https://github.com/JetBrains/kotlin/releases/latest
        junit5Version = "5.8.2" // https://junit.org/junit5/
        jacksonVersion = "2.13.1"
        okhttpVersion = "4.9.3" // https://mvnrepository.com/artifact/com.squareup.okhttp3/okhttp
    }

    repositories {
        mavenLocal()
        mavenCentral()
        maven { url "https://plugins.gradle.org/m2/" }
        maven { url "https://oss.sonatype.org/content/repositories/snapshots/" }
        google()
    }
    dependencies {
        classpath "org.jetbrains.kotlin:kotlin-gradle-plugin:$kotlinVersion"
    }
}
plugins {
    id "org.jetbrains.kotlin.jvm" version "$kotlinVersion"
}

allprojects {
    version = '1.0'

    repositories {
        mavenLocal()
        mavenCentral()
        jcenter()
        google()
        maven { url "https://oss.sonatype.org/content/repositories/snapshots/" }
        maven { url "https://oss.sonatype.org/content/repositories/releases/" }
//        maven { url "https://jitpack.io" }
    }

}

subprojects {
    apply plugin: "kotlin"
    dependencies {
        implementation "org.jetbrains.kotlin:kotlin-stdlib:$kotlinVersion"
        testImplementation "org.junit.jupiter:junit-jupiter-engine:$junit5Version"
        testImplementation "org.junit.jupiter:junit-jupiter-api:$junit5Version"
    }
    repositories {
        maven { url 'https://www.jitpack.io' }
    }
    test {
        useJUnitPlatform()
    }
    compileKotlin {
        kotlinOptions {
            languageVersion = "1.5"
            jvmTarget = "11"
            // jsr305 gives nullable/nonnull support for Java code annotated with javax stuff
            freeCompilerArgs += ["-Xjsr305=strict"]
        }
    }
    [compileJava, compileTestJava]*.options*.encoding = 'UTF-8'
}

project(":app"){}

wrapper {
    // https://gradle.org/releases/
    gradleVersion = '7.3.3'
    distributionType = Wrapper.DistributionType.ALL
}