Adding Direct Vehicle Move waypoint

addons/waypoint/$PBOPREFIX$

@@ -0,0 +1 @@
+z\afmf\addons\waypoint

addons/waypoint/CfgWaypoints.cfg

@@ -0,0 +1,11 @@
+class CfgWaypoints {
+    class ADDON {
+        displayName = "ArmaForces";
+        class Move_vehicle {
+            displayName = CSTRING(Vehicle_Move_Name);
+            file = QPATHTOF(functions\fnc_moveVehicleWp.sqf);
+            icon = "\a3\3DEN\Data\CfgWaypoints\Move_ca.paa";
+            tooltip = CSTRING(Vehicle_Move_Description);
+        };
+    };
+};

addons/waypoint/README.md

@@ -0,0 +1,8 @@
+## Waypoint
+
+Waypoints:
+- Vehicle Move - Order vehicle to move in strain line to target ignoring AI orders and situation. waypoint create pool of vehicles where group units are driver and create new group per vehicle
+
+### Authors
+
+- Command DDOS

addons/waypoint/XEH_PREP.hpp

@@ -0,0 +1 @@
+PREP(moveVehicleWp);

addons/waypoint/XEH_postInit.sqf

@@ -0,0 +1 @@
+#include "script_component.hpp"

addons/waypoint/XEH_preInit.sqf

@@ -0,0 +1,8 @@
+#include "script_component.hpp"
+ADDON = false;
+
+PREP_RECOMPILE_START;
+#include "XEH_PREP.hpp"
+PREP_RECOMPILE_END;
+
+ADDON = true;

addons/waypoint/XEH_preStart.sqf

@@ -0,0 +1,2 @@
+#include "script_component.hpp"
+#include "XEH_PREP.hpp"

addons/waypoint/ZEN_CfgWaypointTypes.hpp

@@ -0,0 +1,7 @@
+ class ZEN_WaypointTypes {
+    class GVAR(VehicleMove) {
+            displayName = CSTRING(Vehicle_Move_Name);
+            type = "SCRIPTED";
+            script = QPATHTOF(functions\fnc_moveVehicleWP.sqf);
+        };
+};

addons/waypoint/config.cpp

@@ -0,0 +1,19 @@
+#include "script_component.hpp"
+
+class CfgPatches {
+    class ADDON {
+        name = COMPONENT_NAME;
+        units[] = {};
+        weapons[] = {};
+        requiredVersion = REQUIRED_VERSION;
+        requiredAddons[] = {
+            "afmf_main"
+        };
+        author = "ArmaForces";
+        authors[] = {"Command DDOS"};
+        VERSION_CONFIG;
+    };
+};
+
+#include "CfgWaypoints.cfg"
+#include "ZEN_CfgWaypointTypes.hpp"

addons/waypoint/functions/fnc_moveVehicleWp.sqf

@@ -0,0 +1,135 @@
+#include "script_component.hpp"
+/*
+ * Author: Command DDOS
+ *
+ *
+ * Arguments:
+ * 0: group
+ * 1: pos
+ *
+ * Return Value:
+ * none
+ *
+*/
+
+params ["_group", "_pos"];
+
+if !(local _group) exitwith {false};
+
+//vehicle list
+private _vehicles = [];
+{
+    _vehicles pushBackUnique (vehicle _x);
+} forEach (units _group);
+
+_vehicles = _vehicles select {assignedDriver _x in (units _group)};
+
+if (count _vehicles == 0) exitwith {true};
+
+
+private _leaderVehicle = vehicle leader _group;
+
+// create groups with waypoint for vehicles without leader vehicle
+{
+    private _vehicle = _X;
+    private _newgroup = createGroup (side _group);
+    private _UnitsInVehicle = (units _group select {_x in (Crew _vehicle)});
+    _UnitsInVehicle joinSilent _newGroup;
+    _group leaveVehicle  _vehicle;
+    _newgroup addVehicle _vehicle;
+    private _nearPos = _pos vectorAdd [random 5,random 5,0];
+    private _waypoint = _newGroup addWaypoint [_nearPos,0];
+    _waypoint setWaypointType "SCRIPTED";
+    _waypoint setWaypointScript QPATHTOF(functions\fnc_moveVehicleWP.sqf);
+} foreach (_vehicles - [_LeaderVehicle]);
+
+if !(driver _LeaderVehicle in (units _group)) exitwith {true};
+
+// at this point there should be always 1 vehicle to process with leader inside
+ private _driver = driver _LeaderVehicle;
+
+    //prevent when driver is not avaible
+if !(alive _driver) exitwith {true};
+if (lifestate _driver == "INCAPACITATED") exitwith {true};
+
+    //calculate positions
+    private _posVehicleATL = getposATL _LeaderVehicle;
+    private _vectorDir = _posVehicleATL vectorDiff _pos;
+    private _vectorDirNormalized = vectorNormalized _vectorDir ;
+    private _pos1 = _pos vectorAdd (_vectorDirNormalized vectorMultiply 1);
+    private _pos2 = _pos;
+    private _pos3 = _pos vectorAdd (_vectorDirNormalized vectorMultiply -1);
+    //update pos used in WUAE
+    _LeaderVehicle setvariable [QGVAR(TargetArrayMovePosition),[_pos1,_pos2,_pos3]];
+
+   //create WUAE only when needed
+if !(_LeaderVehicle getvariable [QGVAR(ActiveVehicleMove),false]) then {
+
+        _LeaderVehicle setvariable [QGVAR(ActiveVehicleMove),true];
+
+        //making group/unit easier to command
+        _driver setVariable ["lambs_danger_disableAI", true];
+        (group _driver) setVariable ["lambs_danger_disablegroupAI", true];
+
+        _driver enableAI "PATH";
+        _driver domove _pos2;
+        _driver disableAI "AUTOTARGET";
+        _driver disableAI "AUTOCOMBAT";
+        _driver disableAI "TARGET";
+        _driver disableAI "COVER";
+        _driver disableAI "FSM";
+        _driver setBehaviour "AWARE";
+
+        _LeaderVehicle setvariable [QGVAR(DriverWaitTime),(time + 1)];
+        _LeaderVehicle setDriveOnPath (_LeaderVehicle getvariable QGVAR(TargetArrayMovePosition));
+
+        [{
+        //condition
+            params ["_vehicle","_group"];
+            if !(waypointScript [_group,currentWaypoint _group] == QPATHTOF(functions\fnc_moveVehicleWP.sqf)) exitwith {true};
+            if !(alive (driver _vehicle)) exitwith {true};
+            if (lifestate (driver _vehicle) == "INCAPACITATED") exitwith {true};
+            if (_vehicle distance2d (_vehicle getvariable (QGVAR(TargetArrayMovePosition)) select 1) < 8 ) exitwith {true};
+            //refresh AI from "stuck" or move to updated position
+
+            if (_vehicle getvariable QGVAR(DriverWaitTime) < time) then {
+                    _vehicle setvariable [QGVAR(DriverWaitTime),(time + 2)];
+                    if (speed _vehicle < 4) then {
+                        (driver _vehicle) disableAI "PATH";
+                        (driver _vehicle) enableAI "PATH";
+                    };
+                    if !(isFormationLeader (driver _vehicle)) then {
+                        (driver _vehicle) doFollow leader (driver _vehicle);
+                        dostop (driver _vehicle);
+                };
+                (driver _vehicle) domove ( _vehicle getvariable QGVAR(TargetArrayMovePosition) select 1);
+                _vehicle setDriveOnPath ( _vehicle getvariable QGVAR(TargetArrayMovePosition));
+                false;
+            }
+            },{
+        //code when true
+            params ["_vehicle"];
+
+            //fixing driver behaviour where he can ignore all move orders if vehicle don't achive setDriveOnPath destinations before doFollow.
+            private _point1 = _vehicle getrelpos [2,0];
+            private _point2 = _vehicle getrelpos [3,0];
+            _vehicle setDriveOnPath [_point1,_point2];
+
+            [{
+                params ["_vehicle"];
+                (driver _vehicle) doFollow (leader (driver _vehicle));
+                (driver _vehicle) domove (getposATL _vehicle);
+                (driver _vehicle) enableAI "all";
+                (driver _vehicle) setVariable ["lambs_danger_disableAI", false];
+                (group (driver _vehicle)) setVariable ["lambs_danger_disablegroupAI", false];
+                _vehicle setvariable [QGVAR(ActiveVehicleMove),false];
+            },[_vehicle],0.2] call cba_fnc_waitAndExecute;
+
+            },[_LeaderVehicle,_group]
+    ] call CBA_fnc_waitUntilAndExecute;
+};
+
+waitUntil {sleep 0.4; !(_LeaderVehicle getvariable [QGVAR(ActiveVehicleMove),false])};
+
+// end
+true

addons/waypoint/functions/script_component.hpp

@@ -0,0 +1 @@
+#include "\z\afmf\addons\waypoint\script_component.hpp"

addons/waypoint/script_component.hpp

@@ -0,0 +1,15 @@
+#define COMPONENT waypoint
+#include "\z\afmf\addons\main\script_mod.hpp"
+
+// #define DEBUG_MODE_FULL
+// #define DISABLE_COMPILE_CACHE
+
+#ifdef DEBUG_ENABLED_WAYPOINT
+    #define DEBUG_MODE_FULL
+#endif
+    #ifdef DEBUG_ENABLED_WAYPOINT
+    #define DEBUG_SETTINGS DEBUG_SETTINGS_DEBUG_ENABLED_WAYPOINT
+#endif
+
+#include "\z\afmf\addons\main\script_macros.hpp"
+

addons/waypoint/stringtable.xml

@@ -0,0 +1,13 @@
+<?xml version="1.0" encoding="utf-8"?>
+<Project name="AFMF">
+    <Package name="Waypoint">
+        <Key ID="STR_AFMF_Waypoint_Vehicle_Move_Name">
+            <English>Direct Vehicle Move</English>
+            <Polish>Bezpośredni ruch pojazdu</Polish>
+        </Key>
+         <Key ID="STR_AFMF_Waypoint_Vehicle_Move_Description">
+            <English>Direct Vehicle Move. Waypoint create new groups for all drivers in original group and assign new waypoint for them. Waypoint is complete after reaching destination or after losing life by driver</English>
+            <Polish>Bezpośredni ruch pojazdu. Waypoint tworzy nowe grupy na każdego kierowce który znajduję się w grupie i przypisuje im również waypoint. Zalicza się po dotarciu lub straceniu życia przez kierowce</Polish>
+        </Key>
+    </Package>
+</Project>