amazon-cloudwatch-agent: let users specify configuration file paths

NixOS · Nov 24, 2024 · 612721a · 612721a
1 parent 5bc0af1
commit 612721a
Show file tree

Hide file tree

Showing 2 changed files with 85 additions and 31 deletions.
diff --git a/nixos/modules/services/monitoring/amazon-cloudwatch-agent.nix b/nixos/modules/services/monitoring/amazon-cloudwatch-agent.nix
@@ -10,8 +10,16 @@ let
   tomlFormat = pkgs.formats.toml { };
   jsonFormat = pkgs.formats.json { };
 
-  commonConfigurationFile = tomlFormat.generate "common-config.toml" cfg.commonConfiguration;
-  configurationFile = jsonFormat.generate "amazon-cloudwatch-agent.json" cfg.configuration;
+  commonConfigurationFile =
+    if (cfg.commonConfigurationFile == null) then
+      (tomlFormat.generate "common-config.toml" cfg.commonConfiguration)
+    else
+      cfg.commonConfigurationFile;
+  configurationFile =
+    if (cfg.configurationFile == null) then
+      (jsonFormat.generate "amazon-cloudwatch-agent.json" cfg.configuration)
+    else
+      cfg.configurationFile;
   # See https://docs.aws.amazon.com/prescriptive-guidance/latest/implementing-logging-monitoring-cloudwatch/create-store-cloudwatch-configurations.html#store-cloudwatch-configuration-s3.
   #
   # We don't use the multiple JSON configuration files feature,
@@ -24,13 +32,27 @@ in
   options.services.amazon-cloudwatch-agent = {
     enable = lib.mkEnableOption "Amazon CloudWatch Agent";
     package = lib.mkPackageOption pkgs "amazon-cloudwatch-agent" { };
+    commonConfigurationFile = lib.mkOption {
+      type = lib.types.nullOr lib.types.path;
+      default = null;
+      description = ''
+        Amazon CloudWatch Agent common configuration. See
+        <https://docs.aws.amazon.com/AmazonCloudWatch/latest/monitoring/install-CloudWatch-Agent-commandline-fleet.html#CloudWatch-Agent-profile-instance-first>
+        for supported values.
+
+        {option}`commonConfigurationFile` takes precedence over {option}`commonConfiguration`.
+      '';
+      example = /etc/amazon-cloudwatch-agent/amazon-cloudwatch-agent.json;
+    };
     commonConfiguration = lib.mkOption {
       type = tomlFormat.type;
       default = { };
       description = ''
         Amazon CloudWatch Agent common configuration. See
         <https://docs.aws.amazon.com/AmazonCloudWatch/latest/monitoring/install-CloudWatch-Agent-commandline-fleet.html#CloudWatch-Agent-profile-instance-first>
         for supported values.
+
+        {option}`commonConfigurationFile` takes precedence over {option}`commonConfiguration`.
       '';
       example = {
         credentials = {
@@ -44,13 +66,35 @@ in
         };
       };
     };
+    configurationFile = lib.mkOption {
+      type = lib.types.nullOr lib.types.path;
+      default = null;
+      description = ''
+        Amazon CloudWatch Agent configuration file. See
+        <https://docs.aws.amazon.com/AmazonCloudWatch/latest/monitoring/CloudWatch-Agent-Configuration-File-Details.html>
+        for supported values.
+
+        The following options aren't supported:
+        * `agent.run_as_user`
+          * Use {option}`user` instead.
+
+        {option}`configurationFile` takes precedence over {option}`configuration`.
+      '';
+      example = /etc/amazon-cloudwatch-agent/amazon-cloudwatch-agent.json;
+    };
     configuration = lib.mkOption {
       type = jsonFormat.type;
       default = { };
       description = ''
         Amazon CloudWatch Agent configuration. See
         <https://docs.aws.amazon.com/AmazonCloudWatch/latest/monitoring/CloudWatch-Agent-Configuration-File-Details.html>
         for supported values.
+
+        The following options aren't supported:
+        * `agent.run_as_user`
+          * Use {option}`user` instead.
+
+        {option}`configurationFile` takes precedence over {option}`configuration`.
       '';
       # Subset of "CloudWatch agent configuration file: Complete examples" and "CloudWatch agent configuration file: Traces section" in the description link.
       #
@@ -110,6 +154,15 @@ in
         };
       };
     };
+    # Replaces "agent.run_as_user" from the configuration file.
+    user = lib.mkOption {
+      type = lib.types.str;
+      default = "root";
+      description = ''
+        The user that runs the Amazon CloudWatch Agent.
+      '';
+      example = "amazon-cloudwatch-agent";
+    };
     mode = lib.mkOption {
       type = lib.types.str;
       default = "auto";
@@ -122,7 +175,7 @@ in
   };
 
   config = lib.mkIf cfg.enable {
-    # See https://github.com/aws/amazon-cloudwatch-agent/blob/v1.300048.1/packaging/dependencies/amazon-cloudwatch-agent.service.
+    # See https://github.com/aws/amazon-cloudwatch-agent/blob/v1.300049.1/packaging/dependencies/amazon-cloudwatch-agent.service.
     systemd.services.amazon-cloudwatch-agent = {
       description = "Amazon CloudWatch Agent";
       after = [ "network.target" ];
@@ -140,38 +193,39 @@ in
         # 3. Runs "amazon-cloudwatch-agent" with the paths to these generated files.
         #
         # Re-implementing with systemd options.
-        User = lib.attrByPath [
-          "agent"
-          "run_as_user"
-        ] "root" cfg.configuration;
+        User = cfg.user;
         RuntimeDirectory = "amazon-cloudwatch-agent";
         LogsDirectory = "amazon-cloudwatch-agent";
-        ExecStartPre = ''
-          ${cfg.package}/bin/config-translator \
-            -config ${commonConfigurationFile} \
-            -input ${configurationFile} \
-            -input-dir ${configurationDirectory} \
-            -mode ${cfg.mode} \
-            -output ''${RUNTIME_DIRECTORY}/amazon-cloudwatch-agent.toml
-        '';
-        ExecStart = ''
-          ${cfg.package}/bin/amazon-cloudwatch-agent \
-            -config ''${RUNTIME_DIRECTORY}/amazon-cloudwatch-agent.toml \
-            -envconfig ''${RUNTIME_DIRECTORY}/env-config.json \
-            -otelconfig ''${RUNTIME_DIRECTORY}/amazon-cloudwatch-agent.yaml \
-            -pidfile ''${RUNTIME_DIRECTORY}/amazon-cloudwatch-agent.pid
-        '';
+        ExecStartPre = builtins.concatStringsSep " " [
+          "${cfg.package}/bin/config-translator"
+          "-config ${commonConfigurationFile}"
+          "-input ${configurationFile}"
+          "-input-dir ${configurationDirectory}"
+          "-mode ${cfg.mode}"
+          "-output \${RUNTIME_DIRECTORY}/amazon-cloudwatch-agent.toml"
+        ];
+        ExecStart = builtins.concatStringsSep " " [
+          "${cfg.package}/bin/amazon-cloudwatch-agent"
+          "-config \${RUNTIME_DIRECTORY}/amazon-cloudwatch-agent.toml"
+          "-envconfig \${RUNTIME_DIRECTORY}/env-config.json"
+          "-otelconfig \${RUNTIME_DIRECTORY}/amazon-cloudwatch-agent.yaml"
+          "-pidfile \${RUNTIME_DIRECTORY}/amazon-cloudwatch-agent.pid"
+        ];
         KillMode = "process";
         Restart = "on-failure";
         RestartSec = 60;
       };
-      restartTriggers = [
-        cfg.package
-        commonConfigurationFile
-        configurationFile
-        configurationDirectory
-        cfg.mode
-      ];
+      restartTriggers =
+        [
+          cfg.package
+          cfg.mode
+          configurationDirectory
+        ]
+        # If the file exists, use hashes instead of contents since contents may be long.
+        ++ (map (file: if (builtins.pathExists file) then (builtins.hashFile "sha256" file) else file) [
+          commonConfigurationFile
+          configurationFile
+        ]);
     };
   };
 

diff --git a/pkgs/by-name/am/amazon-cloudwatch-agent/package.nix b/pkgs/by-name/am/amazon-cloudwatch-agent/package.nix
@@ -22,7 +22,7 @@ buildGoModule rec {
 
   vendorHash = "sha256-zsASHuTXL3brRlgLPNb4wFPHkYpUWbOdRDCXQUwZjIY=";
 
-  # See the list in https://github.com/aws/amazon-cloudwatch-agent/blob/v1.300048.1/Makefile#L68-L77.
+  # See the list in https://github.com/aws/amazon-cloudwatch-agent/blob/v1.300049.1/Makefile#L68-L77.
   subPackages = [
     "cmd/config-downloader"
     "cmd/config-translator"
@@ -32,7 +32,7 @@ buildGoModule rec {
     "cmd/amazon-cloudwatch-agent-config-wizard"
   ];
 
-  # See https://github.com/aws/amazon-cloudwatch-agent/blob/v1.300048.1/Makefile#L57-L64.
+  # See https://github.com/aws/amazon-cloudwatch-agent/blob/v1.300049.1/Makefile#L57-L64.
   #
   # Needed for "amazon-cloudwatch-agent -version" to not show "Unknown".
   postInstall = ''