Merge pull request #330286 from bwkam/init-zotify

zotify: init at 0.6.13

maintainers/maintainer-list.nix

@@ -3044,6 +3044,12 @@
     githubId = 25644444;
     name = "Ben C";
   };
+  bwkam = {
+    email = "[email protected]";
+    github = "bwkam";
+    githubId = 91009118;
+    name = "Beshoy Kamel";
+  };
   bwlang = {
     email = "[email protected]";
     github = "bwlang";

pkgs/by-name/zo/zotify/package.nix

@@ -0,0 +1,47 @@
+{
+  fetchFromGitHub,
+  python3Packages,
+  lib,
+}:
+python3Packages.buildPythonApplication rec {
+  pname = "zotify";
+  version = "0.6.13";
+
+  pyproject = true;
+
+  src = fetchFromGitHub {
+    owner = "zotify-dev";
+    repo = "zotify";
+    # repository has no version tags
+    # https://github.com/zotify-dev/zotify/issues/124
+    rev = "5da27d32a1f522e80a3129c61f939b1934a0824a";
+    hash = "sha256-KA+Q4sk+riaFTybRQ3aO5lgPg4ECZE6G+By+x2uP/VM=";
+  };
+
+  build-system = [ python3Packages.setuptools ];
+
+  nativeBuildInputs = [ python3Packages.pythonRelaxDepsHook ];
+
+  pythonRelaxDeps = [ "protobuf" ];
+
+  dependencies = with python3Packages; [
+    ffmpy
+    music-tag
+    pillow
+    tabulate
+    tqdm
+    librespot
+    pwinput
+    protobuf
+  ];
+
+  pythonImportsCheck = [ "zotify" ];
+
+  meta = {
+    description = "Fast and customizable music and podcast downloader";
+    homepage = "https://github.com/zotify-dev/zotify";
+    license = lib.licenses.zlib;
+    mainProgram = "zotify";
+    maintainers = with lib.maintainers; [ bwkam ];
+  };
+}

pkgs/development/python-modules/pwinput/default.nix

@@ -0,0 +1,35 @@
+{
+  buildPythonPackage,
+  fetchPypi,
+  setuptools,
+  lib,
+  pythonOlder,
+}:
+buildPythonPackage rec {
+  pname = "pwinput";
+  version = "1.0.3";
+
+  pyproject = true;
+
+  disabled = pythonOlder "3.7";
+
+  src = fetchPypi {
+    inherit version;
+    pname = "pwinput";
+    hash = "sha256-yhqL0G4ohy11Hb1BMthjcSfCW0COo6NJN3MUpUkUJvM=";
+  };
+
+  build-system = [ setuptools ];
+
+  pythonImportsCheck = [ "pwinput" ];
+
+  # Requires graphical environment to use pyautogui
+  doCheck = false;
+
+  meta = {
+    description = "Python module that masks password input";
+    homepage = "https://github.com/asweigart/pwinput";
+    license = lib.licenses.mit;
+    maintainers = with lib.maintainers; [ bwkam ];
+  };
+}

pkgs/top-level/python-packages.nix

@@ -10035,6 +10035,8 @@ self: super: with self; {
 
   pyaprilaire = callPackage ../development/python-modules/pyaprilaire { };
 
+  pwinput = callPackage ../development/python-modules/pwinput { };
+
   pybars3 = callPackage ../development/python-modules/pybars3 { };
 
   pymeta3 = callPackage ../development/python-modules/pymeta3 { };