[Backport release-24.05] slskd: 0.21.3 -> 0.21.4

pkgs/by-name/sl/slskd/package.nix

@@ -1,70 +1,82 @@
 {
   lib,
-  buildNpmPackage,
-  fetchFromGitHub,
-  dotnetCorePackages,
   buildDotnetModule,
+  buildPackages,
+  dotnetCorePackages,
+  fetchFromGitHub,
+  fetchNpmDeps,
   mono,
   nodejs_18,
+  slskd,
+  testers,
 }:
+
 let
+  nodejs = nodejs_18;
+  # https://github.com/NixOS/nixpkgs/blob/d88947e91716390bdbefccdf16f7bebcc41436eb/pkgs/build-support/node/build-npm-package/default.nix#L62
+  npmHooks = buildPackages.npmHooks.override { inherit nodejs; };
+in
+buildDotnetModule rec {
   pname = "slskd";
-  version = "0.21.3";
+  version = "0.21.4";
 
   src = fetchFromGitHub {
     owner = "slskd";
     repo = "slskd";
-    rev = version;
-    sha256 = "sha256-qAS8uiXAG0JTOCW/bIVYhv6McUSBihAHFjJu3b5Ttoc=";
+    rev = "refs/tags/${version}";
+    hash = "sha256-9EKlCmc+zdiuEPa8YNjoQ3QLTy8vt2qcZ+6D0sWgwEU=";
   };
 
-  meta = with lib; {
-    description = "A modern client-server application for the Soulseek file sharing network";
-    homepage = "https://github.com/slskd/slskd";
-    license = licenses.agpl3Plus;
-    maintainers = with maintainers; [
-      ppom
-      melvyn2
-    ];
-    platforms = platforms.linux;
-  };
+  nativeBuildInputs = [
+    nodejs
+    npmHooks.npmConfigHook
+  ];
 
-  wwwroot = buildNpmPackage {
-    inherit meta version;
+  runtimeDeps = [ mono ];
 
-    pname = "slskd-web";
-    src = "${src}/src/web";
-    npmFlags = [ "--legacy-peer-deps" ];
-    nodejs = nodejs_18;
-    npmDepsHash = "sha256-06qQ1y870TrkXhkHYADjnWVhdyiLWEqdDt3qrJ1BBFo=";
-    installPhase = ''
-      cp -r build $out
-    '';
+  npmRoot = "src/web";
+  npmDeps = fetchNpmDeps {
+    name = "${pname}-${version}-npm-deps";
+    inherit src;
+    sourceRoot = "${src.name}/${npmRoot}";
+    hash = "sha256-WANoxgPbBoMx6o8fjhSTsKBRZadO2QaeErMMMXk0tgE=";
   };
 
-in
-buildDotnetModule {
-  inherit
-    pname
-    version
-    src
-    meta
-    ;
-
-  runtimeDeps = [ mono ];
+  projectFile = "slskd.sln";
+  nugetDeps = ./deps.nix;
 
   dotnet-sdk = dotnetCorePackages.sdk_8_0;
   dotnet-runtime = dotnetCorePackages.aspnetcore_8_0;
 
-  projectFile = "slskd.sln";
-
   testProjectFile = "tests/slskd.Tests.Unit/slskd.Tests.Unit.csproj";
   doCheck = true;
 
-  nugetDeps = ./deps.nix;
+  postBuild = ''
+    pushd "$npmRoot"
+    npm run build --legacy-peer-deps
+    popd
+  '';
 
   postInstall = ''
     rm -r $out/lib/slskd/wwwroot
-    ln -s ${wwwroot} $out/lib/slskd/wwwroot
+    mv "$npmRoot"/build $out/lib/slskd/wwwroot
   '';
+
+  passthru = {
+    tests.version = testers.testVersion { package = slskd; };
+  };
+
+  meta = {
+    description = "Modern client-server application for the Soulseek file sharing network";
+    homepage = "https://github.com/slskd/slskd";
+    changelog = "https://github.com/slskd/slskd/releases/tag/${version}";
+    license = lib.licenses.agpl3Plus;
+    maintainers = with lib.maintainers; [
+      ppom
+      melvyn2
+      getchoo
+    ];
+    mainProgram = "slskd";
+    platforms = lib.platforms.linux;
+  };
 }