qwhitesurgtkdecorations init at 0.1.0

maintainers/maintainer-list.nix

@@ -20995,6 +20995,12 @@
     githubId = 216167;
     name = "Steve Jones";
   };
+  sjhaleprogrammer = {
+    email = "[email protected]";
+    github = "sjhaleprogrammer";
+    githubId = 60676867;
+    name = "Samuel Hale";
+  };
   sjmackenzie = {
     email = "[email protected]";
     github = "sjmackenzie";

nixos/modules/config/qt.nix

@@ -30,6 +30,10 @@ let
       libsForQt5.qt5ct
       qt6Packages.qt6ct
     ];
+    whitesur = [
+      qwhitesurgtkdecorations
+      qwhitesurgtkdecorations-qt6
+    ];
   };
 
   stylePackages = with pkgs; {
@@ -131,6 +135,10 @@ in
             "qt6Packages"
             "qt6gtk2"
           ]
+          [
+            "qwhitesurgtkdecorations"
+            "qwhitesurgtkdecorations-qt6"
+          ]
         ];
         description = ''
           Selects the platform theme to use for Qt applications.
@@ -143,6 +151,7 @@ in
              application.
           - `qt5ct`: Use Qt style set using the [qt5ct](https://sourceforge.net/projects/qt5ct/)
              and [qt6ct](https://github.com/trialuser02/qt6ct) applications.
+          - 'whitesur': Use WhitesurGTK theme with [qwhitesurgtkdecorations](https://github.com/FengZhongShaoNian/QWhiteSurGtkDecorations)
         '';
       };
 

pkgs/by-name/qw/qwhitesurgtkdecorations/package.nix

@@ -0,0 +1,62 @@
+{
+  lib,
+  stdenv,
+  fetchFromGitHub,
+  cmake,
+  qt5,
+  qt6,
+  wayland,
+  nix-update-script,
+  useQt6 ? false,
+
+  # Shadows support on Qt5 requires the feature backported from Qt6:
+  # https://src.fedoraproject.org/rpms/qt5-qtwayland/blob/rawhide/f/qtwayland-decoration-support-backports-from-qt6.patch
+  qt5ShadowsSupport ? false,
+}:
+
+let
+  qt = if useQt6 then qt6 else qt5;
+  qtVersion = if useQt6 then "6" else "5";
+
+in
+stdenv.mkDerivation (finalAttrs: {
+  pname = "qwhitesurgtkdecorations";
+  version = "0.1.0";
+
+  src = fetchFromGitHub {
+    owner = "FengZhongShaoNian";
+    repo = "QWhiteSurGtkDecorations";
+    rev = finalAttrs.version;
+    hash = "sha256-dMwaLHAbpTBP8UvUvrW+CRBzgr11o+OAbsTW7AcnZsI=";
+  };
+
+  nativeBuildInputs = [
+    cmake
+  ];
+
+  buildInputs = with qt; [
+    qtbase
+    qtsvg
+    qtwayland
+    wayland
+  ];
+
+  dontWrapQtApps = true;
+
+  cmakeFlags =
+    [
+      "-DQT_PLUGINS_DIR=${placeholder "out"}/${qt.qtbase.qtPluginPrefix}"
+    ]
+    ++ lib.optional useQt6 "-DUSE_QT6=true"
+    ++ lib.optional qt5ShadowsSupport "-DHAS_QT6_SUPPORT=true";
+
+  passthru.updateScript = nix-update-script { };
+
+  meta = {
+    description = "Qt${qtVersion} decoration plugin implementing WhiteSurGTK-like client-side decorations. This project is modified based on the QAdwaitaDecorations project. Some of the icon resources used in this project come from WhiteSur-gtk-theme.";
+    homepage = "https://github.com/FengZhongShaoNian/QWhiteSurGtkDecorations";
+    license = lib.licenses.lgpl21Plus;
+    maintainers = with lib.maintainers; [ sjhaleprogrammer ];
+    platforms = lib.platforms.linux;
+  };
+})

pkgs/top-level/all-packages.nix

@@ -10639,6 +10639,10 @@ with pkgs;
     useQt6 = true;
   };
 
+  qwhitesurgtkdecorations-qt6 = callPackage ../by-name/qw/qwhitesurgtkdecorations/package.nix {
+    useQt6 = true;
+  };
+
   randomx = darwin.apple_sdk_11_0.callPackage ../development/libraries/randomx { };
 
   remodel = callPackage ../development/tools/remodel {