Pull recent changes from main repository

.gitignore

@@ -1,3 +1,6 @@
 /tests-ga/
 /tests-wd/
 /tests2/
+AS/
+page2tei-output/
+

LICENSE

@@ -0,0 +1,21 @@
+MIT License
+
+Copyright (c) 2018 Dario Kampkaspar
+
+Permission is hereby granted, free of charge, to any person obtaining a copy
+of this software and associated documentation files (the "Software"), to deal
+in the Software without restriction, including without limitation the rights
+to use, copy, modify, merge, publish, distribute, sublicense, and/or sell
+copies of the Software, and to permit persons to whom the Software is
+furnished to do so, subject to the following conditions:
+
+The above copyright notice and this permission notice shall be included in all
+copies or substantial portions of the Software.
+
+THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS OR
+IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF MERCHANTABILITY,
+FITNESS FOR A PARTICULAR PURPOSE AND NONINFRINGEMENT. IN NO EVENT SHALL THE
+AUTHORS OR COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER
+LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE, ARISING FROM,
+OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE USE OR OTHER DEALINGS IN THE
+SOFTWARE.

README.md

@@ -1,7 +1,40 @@
 # page2tei
+PAGE2TEI was created and is maintained by Dario Kampkaspar and is licensed under the MIT license.
 
-Use the METS File for your transformation:
+## How to use
+Apply page2tei-0.xsl to the METS File:
 
 ```
 java -jar saxon9he.jar -xsl:page2tei-0.xsl -s:mets.xml -o:[your tei file].xml
 ```
+
+Additional stylesheets can be applied to the output created by the basic transformation:
+- `combine-continued.xsl` (or set parameter `combine=true()`) — try to combine entities that are split over a line break into one element
+- `simplify-coordinates.xsl` (parameter `bounding-rectangles=true()` by default) — convert polygons into bounding rectangles
+- `tokenize.xsl` (or set parameter `tokenize=true()`) — perform (very basic!) whitespace tokenization
+
+## Parameters
+You can set the following parameters when calling `page2tei-0.xsl` (via command line or via an oXygen scenario; in oXygen, the parameters should be marked as “XPath“):
+
+- rs (default: `true()`): create `rs type="..."` for person/place/org (default) or `persName` etc.
+- tokenize (default: `false()`): Whether to run white space tokenization
+- combine (default: `false()`): Whether to combine entities over line breaks
+- ab (default: `false()`): If false(), region types that correspond to valid TEI elements will be returned as 
+         this element; types that do not correspond to a TEI element will be returned as
+         tei:ab[@type]. If set to true(), all region types (except for paragraph, heading) will be
+         returned as tei:ab.
+- word-coordinates (default: `false()`): If true(), export the (estimated) word coordinates to the facsimile section.
+- bounding-rectangles (default: `true()`): Whether to create bounding rectangles from polygons (default: true())
+- withoutBaseline (default: `false()`): Whether to export lines without baseline or not
+- withoutTextline (default: `false()`): Whether to export regions without text lines
+
+
+## Contributors
+- @tboenig
+- @peterstadler
+- @tillgrallert
+
+---
+
+Some contributions to this software were created within the scope of a project funded by the German BMBF, project ID 16TOA015A.
+

combine-continued.xsl

@@ -0,0 +1,122 @@
+<?xml version="1.0" encoding="UTF-8"?>
+<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
+   xmlns:xs="http://www.w3.org/2001/XMLSchema"
+   xmlns:xd="http://www.oxygenxml.com/ns/doc/xsl"
+   xmlns:tei="http://www.tei-c.org/ns/1.0"
+   xmlns:local="local"
+   xmlns="http://www.tei-c.org/ns/1.0"
+   exclude-result-prefixes="#all"
+   version="3.0">
+   <xd:doc scope="stylesheet">
+      <xd:desc>
+         <xd:p><xd:b>Created on:</xd:b> 2022-08-03</xd:p>
+         <xd:p><xd:b>Author:</xd:b> [email protected]</xd:p>
+         <xd:p>combine neighbouring tei:rs[@continued] separated by a tei:lb</xd:p>
+      </xd:desc>
+   </xd:doc>
+
+   <!--<xsl:template match="/">
+      <xsl:apply-templates mode="continued" />
+   </xsl:template>-->
+
+   <xd:doc>
+      <xd:desc>
+         <xd:p>Combine continued elements (e.g. rs)</xd:p>
+         <xd:p>This works on an element that contains (more than one) continued element (there may be just one element
+            if the continuation happens across region borders).</xd:p>
+      </xd:desc>
+   </xd:doc>
+   <xsl:template match="tei:*[count(tei:*[@continued = 'true']) gt 1]" mode="continued">
+      <xsl:copy>
+         <xsl:apply-templates select="@*" mode="continued" />
+         <xsl:for-each-group select="node()"
+               group-starting-with="tei:*[
+                  @continued eq 'true'
+                  and normalize-space() != ''
+                  and (
+                        normalize-space(preceding::text()[1]) != ''
+                     or preceding::text()[1][not(preceding-sibling::*)]
+                     or preceding-sibling::*[1][not(@continued = 'true') and not(self::tei:lb)]
+                  )
+               ]">
+
+            <xsl:choose>
+               <xsl:when test="current-group()[1][@continued eq 'true' and tei:abbr]">
+                  <!-- we assume there is exactly 2 choice with one lb in between, so no multi-line abbreviations:
+                     1=choice, 2=text(), 3=lb, 4=text(), 5=choice -->
+                  <choice>
+                     <expan>
+                        <xsl:sequence select="current-group()[1]/tei:expan/node()" />
+                     </expan>
+                     <abbr>
+                        <xsl:sequence select="current-group()[1]/tei:abbr/node()" />
+                        <xsl:sequence select="current-group()[3]" />
+                        <xsl:sequence select="current-group()[4]/tei:abbr/node()" />
+                     </abbr>
+                  </choice>
+                  <xsl:apply-templates select="current-group()[position() gt 4]" mode="continued" />
+               </xsl:when>
+               <xsl:when test="current-group()[1][@continued eq 'true'] and count(current-group()[@continued = 'true']) gt 1">
+                  <xsl:variable
+                     name="final"
+                     select="
+                        (
+                           current-group()[
+                                 position() gt 1
+                                 and @continued = 'true'
+                                 and node()
+                              ][last()],
+                           current-group()[4]
+                        )[1]"
+                  />
+                  <xsl:try>
+                     <xsl:variable name="last" select="index-of(current-group(), $final)[1]"/>
+
+                  <xsl:element name="{local-name()}">
+                     <xsl:apply-templates select="@*" mode="continued" />
+                     <xsl:apply-templates select="current-group()[position() le $last]" mode="rs-continued" />
+                  </xsl:element>
+                  <xsl:apply-templates select="current-group()[position() gt $last]" mode="continued" />
+                     <xsl:catch>
+                        <xsl:message select="current-group()" />
+                     </xsl:catch>
+                  </xsl:try>
+               </xsl:when>
+               <xsl:otherwise>
+                  <xsl:apply-templates select="current-group()" mode="continued" />
+               </xsl:otherwise>
+            </xsl:choose>
+         </xsl:for-each-group>
+      </xsl:copy>
+   </xsl:template>
+
+   <xd:doc>
+      <xd:desc>lb will be returned unaltered</xd:desc>
+   </xd:doc>
+   <xsl:template match="tei:lb" mode="rs-continued">
+      <lb>
+         <xsl:sequence select="@*" />
+      </lb>
+   </xsl:template>
+
+   <xd:doc>
+      <xd:desc>For continued rs, only return the content</xd:desc>
+   </xd:doc>
+   <xsl:template match="*" mode="rs-continued">
+      <xsl:apply-templates select="node()" mode="continued" />
+   </xsl:template>
+
+   <xd:doc>
+      <xd:desc>Remove @continued</xd:desc>
+   </xd:doc>
+   <xsl:template match="@continued" mode="continued"/>
+
+   <xd:doc>
+      <xd:desc>Default</xd:desc>
+   </xd:doc>
+   <xsl:template match="@* | node()" mode="continued">
+      <xsl:copy>
+         <xsl:apply-templates select="@* | node()" mode="#current" />
+      </xsl:copy>
+   </xsl:template>
+</xsl:stylesheet>

combine-hi.xsl

@@ -0,0 +1,45 @@
+<?xml version="1.0" encoding="UTF-8"?>
+<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
+   xmlns:xs="http://www.w3.org/2001/XMLSchema"
+   xmlns:tei="http://www.tei-c.org/ns/1.0"
+   xmlns:math="http://www.w3.org/2005/xpath-functions/math"
+   xmlns="http://www.tei-c.org/ns/1.0"
+   exclude-result-prefixes="#all"
+   version="3.0">
+
+   <xsl:template match="*[tei:hi]" mode="combine-hi">
+      <xsl:copy>
+         <xsl:sequence select="@*" />
+         <xsl:for-each-group select="node()"
+               group-starting-with="tei:hi[
+                  @style != preceding-sibling::tei:hi[1]/@style
+                  or not(preceding-sibling::tei:hi)
+                  or normalize-space(string-join(preceding-sibling::tei:hi[1]/following-sibling::node() intersect preceding-sibling::node())) != ''
+               ]">
+            <xsl:choose>
+               <xsl:when test="not(current-group()[self::tei:hi])">
+                  <xsl:sequence select="current-group()" />
+               </xsl:when>
+               <xsl:otherwise>
+                  <xsl:variable name="lastHi" select="index-of(current-group(), current-group()[self::tei:hi][last()])"/>
+
+                  <hi style="{current-group()[1]/@style}">
+                     <xsl:apply-templates select="current-group()[position() le $lastHi]" mode="do-combine-hi" />
+                  </hi>
+                  <xsl:sequence select="current-group()[position() gt $lastHi]" />
+               </xsl:otherwise>
+            </xsl:choose>
+         </xsl:for-each-group>
+      </xsl:copy>
+   </xsl:template>
+
+   <xsl:template match="tei:hi" mode="do-combine-hi">
+      <xsl:apply-templates mode="combine-hi"/>
+   </xsl:template>
+
+   <xsl:template match="@* | node()" mode="combine-hi do-combine-hi">
+      <xsl:copy>
+         <xsl:apply-templates select="@* | node()" mode="#current"/>
+      </xsl:copy>
+   </xsl:template>
+</xsl:stylesheet>