Added undead, skeletons and zombies.

code/modules/mob/living/human/death.dm

@@ -1,6 +1,8 @@
 /mob/living/carbon/human/gib(do_gibs = TRUE)
 	var/turf/my_turf = get_turf(src)
-	. = ..()
+	if(do_gibs && HasTrait(/decl/trait/undead, TRAIT_LEVEL_MODERATE))
+		do_gibs = FALSE
+	. = ..(do_gibs)
 	if(.)
 		for(var/obj/item/organ/I in get_internal_organs())
 			remove_organ(I)
@@ -16,10 +18,15 @@
 				E.throw_at(get_edge_target_turf(E, pick(global.alldirs)), rand(1,3), THROWFORCE_GIBS)
 
 /mob/living/carbon/human/get_death_message(gibbed)
+	if(HasTrait(/decl/trait/undead, TRAIT_LEVEL_MODERATE))
+		return "crumbles and falls apart!"
 	if(get_config_value(/decl/config/toggle/health_show_human_death_message))
 		return species.get_species_death_message(src) || "seizes up and falls limp..."
 	return ..()
 
+/mob/living/carbon/human/get_self_death_message(gibbed)
+	return HasTrait(/decl/trait/undead, TRAIT_LEVEL_MODERATE) ? "You have crumbled." : ..()
+
 /mob/living/carbon/human/death(gibbed)
 	if(!(. = ..()))
 		return
@@ -40,6 +47,12 @@
 		SSticker.mode.check_win()
 	species.handle_death(src)
 
+	if(!QDELETED(src) && !gibbed && HasTrait(/decl/trait/undead, TRAIT_LEVEL_MODERATE))
+		gib()
+
+/mob/living/carbon/human/get_gibber_type()
+	return HasTrait(/decl/trait/undead, TRAIT_LEVEL_MODERATE) ? null : ..()
+
 /mob/living/carbon/human/proc/is_husked()
 	return (MUTATION_HUSK in mutations)
 

code/modules/mob/living/human/human.dm

@@ -1206,6 +1206,16 @@
 	var/temp_inc = max(min(BODYTEMP_HEATING_MAX*(1-get_heat_protection()), exposed_temperature - bodytemperature), 0)
 	bodytemperature += temp_inc
 
+/mob/living/carbon/human/need_breathe()
+	return HasTrait(/decl/trait/undead) ? FALSE : ..()
+
+// Undead don't get hungry/thirsty (except for brains)
+/mob/living/carbon/human/get_nutrition()
+	return HasTrait(/decl/trait/undead) ? get_max_nutrition() : ..()
+
+/mob/living/carbon/human/get_hydration()
+	return HasTrait(/decl/trait/undead) ? get_max_hydration() : ..()
+
 /mob/living/carbon/human/currently_has_skin()
 	return currently_has_meat()
 
@@ -1217,3 +1227,13 @@
 		if(istype(limb.material, /decl/material/solid/organic/meat))
 			return TRUE
 	return FALSE
+
+/mob/living/carbon/human/set_status(condition, amount)
+	if(HasTrait(/decl/trait/undead, TRAIT_LEVEL_MODERATE))
+		var/static/list/ignore_status_conditions = list(
+			STAT_BLIND,
+			STAT_DEAF
+		)
+		if(condition in ignore_status_conditions)
+			return
+	. = ..()

code/modules/mob/living/human/human_appearance_head.dm

@@ -3,6 +3,9 @@
 
 // Eyes! TODO, make these a marking.
 /mob/living/carbon/human/get_eye_colour()
+	// Force an evil red glow for undead mobs.
+	if(HasTrait(/decl/trait/undead))
+		return COLOR_RED
 	return _eye_colour
 
 /mob/living/carbon/human/set_eye_colour(var/new_color, var/skip_update = FALSE)

code/modules/mob/living/human/human_damage.dm

@@ -1,4 +1,11 @@
 /mob/living/carbon/human/get_life_damage_types()
+	if(HasTrait(/decl/trait/undead))
+		// Undead human mobs use brute and burn damage instead of brain damage, a la simplemobs.
+		var/static/list/life_damage_types = list(
+			BURN,
+			BRUTE
+		)
+		return life_damage_types
 	var/static/list/brain_life_damage_types = list(
 		BRAIN
 	)
@@ -137,9 +144,13 @@
 	return 0
 
 /mob/living/carbon/human/setOxyLoss(var/amount)
+	if(HasTrait(/decl/trait/undead))
+		return
 	take_damage(amount - get_damage(OXY), OXY)
 
 /mob/living/carbon/human/adjustOxyLoss(var/damage, var/do_update_health = TRUE)
+	if(HasTrait(/decl/trait/undead))
+		return
 	. = FALSE
 	if(need_breathe())
 		var/obj/item/organ/internal/lungs/breathe_organ = get_organ(get_bodytype().breathing_organ, /obj/item/organ/internal/lungs)
@@ -150,21 +161,21 @@
 	..(do_update_health = FALSE) // Oxyloss cannot directly kill humans
 
 /mob/living/carbon/human/getToxLoss()
-	if((species.species_flags & SPECIES_FLAG_NO_POISON) || isSynthetic())
+	if((species.species_flags & SPECIES_FLAG_NO_POISON) || isSynthetic() || HasTrait(/decl/trait/undead))
 		return 0
 	var/amount = 0
 	for(var/obj/item/organ/internal/I in get_internal_organs())
 		amount += I.getToxLoss()
 	return amount
 
 /mob/living/carbon/human/setToxLoss(var/amount)
-	if(!(species.species_flags & SPECIES_FLAG_NO_POISON) && !isSynthetic())
+	if(!(species.species_flags & SPECIES_FLAG_NO_POISON) && !isSynthetic() || HasTrait(/decl/trait/undead))
 		take_damage(get_damage(TOX)-amount, TOX)
 
 // TODO: better internal organ damage procs.
 /mob/living/carbon/human/adjustToxLoss(var/amount, var/do_update_health = TRUE)
 
-	if((species.species_flags & SPECIES_FLAG_NO_POISON) || isSynthetic())
+	if((species.species_flags & SPECIES_FLAG_NO_POISON) || isSynthetic() || HasTrait(/decl/trait/undead))
 		return
 
 	var/heal = amount < 0

code/modules/mob/living/human/human_organs.dm

@@ -152,12 +152,25 @@
 			LAZYDISTINCTADD(bad_external_organs, E)
 
 /mob/living/carbon/human/proc/check_vital_organ_missing()
+	// Undead don't care about missing internal organs.
+	if(HasTrait(/decl/trait/undead))
+		return FALSE
 	return get_bodytype()?.check_vital_organ_missing(src)
 
+/mob/living/carbon/human/should_have_organ(organ_to_check)
+	// It might be nice to have eyes etc. matter for zombies, but as all organs are dead it won't work currently.
+	return HasTrait(/decl/trait/undead) ? FALSE : ..()
+
 /mob/living/carbon/human/proc/process_internal_organs()
+	if(HasTrait(/decl/trait/undead))
+		return
 	for(var/obj/item/organ/I in internal_organs)
 		I.Process()
 
+/mob/living/carbon/human/get_vision_organ_tag()
+	 // Where we're going, we don't need eyes.
+	return HasTrait(/decl/trait/undead) ? null : ..()
+
 // Takes care of organ related updates, such as broken and missing limbs
 /mob/living/carbon/human/proc/handle_organs()
 

code/modules/mob/living/human/undead.dm

@@ -0,0 +1,62 @@
+/decl/trait/undead
+	name = "Undead"
+	description = "Your body is dead, but remains animated through some supernatural force."
+	levels = list(TRAIT_LEVEL_MINOR, TRAIT_LEVEL_MODERATE) // Moderate means skeleton, minor means zombie.
+
+/mob/living/carbon/human/proc/make_zombie()
+	SetTrait(/decl/trait/metabolically_inert, TRAIT_LEVEL_EXISTS)
+	SetTrait(/decl/trait/undead, TRAIT_LEVEL_MINOR)
+
+	for(var/obj/item/organ/organ in get_organs())
+		organ.die()
+		organ.damage = 0 // die() sets to max damage
+		organ.germ_level = INFECTION_LEVEL_THREE
+
+	// Set this so nonhumans look appropriately gross.
+	reset_hair()
+	if(get_bodytype()?.appearance_flags & HAS_SKIN_COLOR)
+		_skin_colour = pick(COLOR_GRAY, COLOR_GRAY15, COLOR_GRAY20, COLOR_GRAY40, COLOR_GRAY80, COLOR_WHITE)
+		SET_HAIR_COLOUR(src, _skin_colour, TRUE)
+		SET_FACIAL_HAIR_COLOUR(src, _skin_colour, TRUE)
+
+	for(var/obj/item/organ/external/limb in get_external_organs())
+		if(!BP_IS_PROSTHETIC(limb))
+			limb.sync_colour_to_human(src)
+			if(prob(10))
+				limb.skeletonize()
+			else if(prob(15))
+				if(prob(75))
+					limb.createwound(CUT, rand(limb.max_damage * 0.25, limb.max_damage * 0.5))
+				else
+					limb.createwound(BURN, rand(limb.max_damage * 0.25, limb.max_damage * 0.5))
+
+	vessel.remove_any(vessel.total_volume * rand(0.2, 0.5))
+	update_body()
+
+/mob/living/carbon/human/proc/make_skeleton()
+	SetTrait(/decl/trait/metabolically_inert, TRAIT_LEVEL_EXISTS)
+	SetTrait(/decl/trait/undead, TRAIT_LEVEL_MODERATE)
+
+	for(var/obj/item/organ/external/limb in get_external_organs())
+		if(!BP_IS_PROSTHETIC(limb))
+			limb.skeletonize()
+
+	for(var/obj/item/organ/internal/organ in get_internal_organs())
+		remove_organ(organ, FALSE, FALSE, TRUE, FALSE, FALSE, TRUE)
+		qdel(organ)
+
+	vessel?.clear_reagents()
+	SET_HAIR_STYLE(src, /decl/sprite_accessory/hair/bald, FALSE)
+	update_body()
+
+// SKELETONS
+// Immune to blind or deaf, but weak to physical damage.
+/mob/living/carbon/human/skeleton/post_setup(var/species_name = null, var/datum/dna/new_dna = null)
+	. = ..()
+	make_skeleton()
+
+// ZOMBIES
+// Dead and rotting, but still mobile and aggressive.
+/mob/living/carbon/human/zombie/post_setup(var/species_name = null, var/datum/dna/new_dna = null)
+	. = ..()
+	make_zombie()

code/modules/organs/external/_external.dm

@@ -719,7 +719,10 @@ This function completely restores a damaged organ to perfect condition.
 	if(length(ailments))
 		return TRUE
 
-	if(status & (ORGAN_CUT_AWAY|ORGAN_BLEEDING|ORGAN_BROKEN|ORGAN_MUTATED|ORGAN_DISLOCATED|ORGAN_DEAD))
+	if(status & (ORGAN_CUT_AWAY|ORGAN_BLEEDING|ORGAN_BROKEN|ORGAN_MUTATED|ORGAN_DISLOCATED))
+		return TRUE
+
+	if((status & ORGAN_DEAD) && !owner?.HasTrait(/decl/trait/undead))
 		return TRUE
 
 	if((brute_dam || burn_dam) && !BP_IS_PROSTHETIC(src)) //Robot limbs don't autoheal and thus don't need to process when damaged

code/modules/organs/organ.dm

@@ -415,7 +415,9 @@
 	return bodytype && !(bodytype.body_flags & BODY_FLAG_NO_PAIN) && !(status & ORGAN_DEAD)
 
 /obj/item/organ/proc/is_usable()
-	. = !(status & (ORGAN_CUT_AWAY|ORGAN_MUTATED|ORGAN_DEAD))
+	. = !(status & (ORGAN_CUT_AWAY|ORGAN_MUTATED))
+	if(. && (status & ORGAN_DEAD))
+		return owner?.HasTrait(/decl/trait/undead)
 
 /obj/item/organ/proc/can_recover()
 	return (max_damage > 0) && !(status & ORGAN_DEAD) || death_time >= REALTIMEOFDAY - ORGAN_RECOVERY_THRESHOLD

nebula.dme

@@ -2841,6 +2841,7 @@
 #include "code\modules\mob\living\human\obj_grabs.dm"
 #include "code\modules\mob\living\human\say.dm"
 #include "code\modules\mob\living\human\unarmed_attack.dm"
+#include "code\modules\mob\living\human\undead.dm"
 #include "code\modules\mob\living\human\update_icons.dm"
 #include "code\modules\mob\living\human\whisper.dm"
 #include "code\modules\mob\living\human\descriptors\_descriptors.dm"