Porting Quirks from S.P.L.U.R.T.

modular_zzplurt/code/datums/quirks/neutral_quirks/modularlimbs.dm

@@ -0,0 +1,67 @@
+/datum/quirk/modularlimbs
+	name = "Modular Limbs"
+	desc = "Your limbs are able to be attached and detached easily... Unfortunately, everyone around you can alter your limbs too!"
+	icon = FA_ICON_HAND
+	value = 0
+
+/datum/quirk/modularlimbs/add()
+	var/mob/living/carbon/human/C = quirk_holder
+	add_verb(C,/mob/living/proc/alterlimbs)
+
+/datum/quirk/modularlimbs/remove()
+	var/mob/living/carbon/human/C = quirk_holder
+	remove_verb(C,/mob/living/proc/alterlimbs)
+
+/mob/living/proc/alterlimbs()
+	set name = "Alter Limbs"
+	set desc = "Remove or attach a limb!"
+	set category = "IC"
+	set src in view(usr.client)
+
+	var/mob/living/carbon/human/U = usr
+	var/mob/living/carbon/human/C = src
+
+	var/obj/item/I = U.get_active_held_item()
+	if(istype(I,/obj/item/bodypart))
+		var/obj/item/bodypart/L = I
+		if(!C.Adjacent(U))
+			to_chat(U, span_warning("You must be adjacent to [C] to do this!"))
+			return
+		if(C.get_bodypart(L.body_zone))
+			to_chat(U, span_warning("[C] already has a limb attached there!"))
+			return
+		C.visible_message(span_warning("[U] is attempting to attach [L] onto [C]!"), span_userdanger("[U] is attempting to re-attach one of your limbs!"))
+		if(do_after(U, 40, target = C) && C.Adjacent(U))
+			L.try_attach_limb(C)
+			C.visible_message(span_warning("[U] successfully attaches [L] onto [C]"), span_userdanger("[U] has successfully attached a [L.name] onto you; you can use that limb again!"))
+			return
+		else
+			to_chat(U, span_warning("You and [C] must both stand still for you to remove one of their limbs!"))
+			return
+	else
+		if(!C.Adjacent(U))
+			to_chat(U, span_warning("You must be adjacent to [C] to do this!"))
+			return
+		if(U.zone_selected == BODY_ZONE_CHEST || U.zone_selected == BODY_ZONE_HEAD)
+			to_chat(U, span_warning("You must target either an arm or a leg!"))
+			return
+		if(U.zone_selected == BODY_ZONE_PRECISE_GROIN || U.zone_selected == BODY_ZONE_PRECISE_EYES || U.zone_selected == BODY_ZONE_PRECISE_MOUTH)
+			to_chat(U, span_warning("There is no limb here; select an arm or a leg!"))
+			return
+		if(!C.get_bodypart(U.zone_selected))
+			to_chat(U, span_warning("They are already missing that limb!"))
+			return
+		C.visible_message(span_warning("[U] is attempting to remove one of [C]'s limbs!"), span_userdanger("[U] is attempting to disconnect one of your limbs!"))
+		var/obj/item/bodypart/B = C.get_bodypart(U.zone_selected)
+		if(C.Adjacent(U) && do_after(U, 40, target = C))
+			var/obj/item/bodypart/D = C.get_bodypart(U.zone_selected)
+			if(B != D)
+				to_chat(U, span_warning("You cannot target a different limb while already removing another!"))
+				return
+			D.drop_limb()
+			C.update_equipment_speed_mods()
+			C.visible_message(span_warning("[U] smoothly disconnects [C]'s [D.name]!"), span_userdanger("[U] has forcefully disconnected your [D.name]!"))
+			return
+		else
+			to_chat(U, span_warning("You and [C] must both stand still for you to remove one of their limbs!"))
+			return

modular_zzplurt/code/datums/quirks/neutral_quirks/radfiend.dm

@@ -0,0 +1,94 @@
+#define TRAIT_RAD_FIEND "rad_fiend"
+
+GLOBAL_LIST_INIT(traits_by_type_radfiend, list(
+	/obj/item/toy/plush/skyrat = list(
+		"TRAIT_RAD_FIEND" = TRAIT_RAD_FIEND, //SPLURT addition - for sodium sensetivity quirk
+	),
+))
+
+/datum/quirk/rad_fiend
+	name = "Rad Fiend"
+	desc = "You've been blessed by Cherenkov's warming light, causing you to emit a subtle glow at all times. Only -very- intense radiation is capable of penetrating your protective barrier"
+	icon = FA_ICON_RADIATION
+	value = 2
+	mob_trait = TRAIT_RAD_FIEND
+	gain_text = span_notice("You feel empowered by Cherenkov's glow.")
+	lose_text = span_notice("You realize that rads aren't so rad.")
+
+/datum/quirk/rad_fiend/add()
+	// Define quirk holder mob
+	var/mob/living/carbon/human/quirk_mob = quirk_holder
+	// Add glow control action
+	var/datum/action/rad_fiend/update_glow/quirk_action = new
+	quirk_action.Grant(quirk_mob)
+
+/datum/quirk/rad_fiend/remove()
+	// Define quirk holder mob
+	var/mob/living/carbon/human/quirk_mob = quirk_holder
+
+	// Remove glow control action
+	var/datum/action/rad_fiend/update_glow/quirk_action = locate() in quirk_mob.actions
+	quirk_action.Remove(quirk_mob)
+
+	// Remove glow effect
+	quirk_mob.remove_filter("rad_fiend_glow")
+
+/datum/action/rad_fiend
+	name = "Broken Rad Action"
+	desc = "Report this to a coder."
+	button_icon_state = "static"
+
+/datum/action/rad_fiend/update_glow
+	name = "Modify Glow"
+	desc = "Change your radioactive glow color."
+	button_icon_state = "blank"
+
+	// Glow color to use
+	var/glow_color = "#39ff14" // Neon green
+
+	// Thickness of glow outline
+	var/glow_range = 2
+
+
+/datum/action/rad_fiend/update_glow/Grant()
+	. = ..()
+
+	// Define user mob
+	var/mob/living/carbon/human/action_mob = owner
+
+	// Add outline effect
+	action_mob.add_filter("rad_fiend_glow", 1, list("type" = "outline", "color" = glow_color+"30", "size" = glow_range))
+
+/datum/action/rad_fiend/update_glow/Remove()
+	. = ..()
+
+	// Define user mob
+	var/mob/living/carbon/human/action_mob = owner
+
+	// Remove glow
+	action_mob.remove_filter("rad_fiend_glow")
+
+/datum/action/rad_fiend/update_glow/Trigger(trigger_flags)
+	. = ..()
+
+	// Define user mob
+	var/mob/living/carbon/human/action_mob = owner
+
+	// Ask user for color input
+	var/input_color = input(action_mob, "Select a color to use for your glow outline.", "Select Glow Color", glow_color) as color|null
+
+	// Check if color input was given
+	// Reset to stored color when not given input
+	glow_color = (input_color ? input_color : glow_color)
+
+	// Ask user for range input
+	var/input_range = input(action_mob, "How much do you glow? Value may range between 1 to 2.", "Select Glow Range", glow_range) as num|null
+
+	// Check if range input was given
+	// Reset to stored color when not given input
+	// Input is clamped in the 1-4 range
+	glow_range = (input_range ? clamp(input_range, 1, 4) : glow_range)
+
+	// Update outline effect
+	action_mob.remove_filter("rad_fiend_glow")
+	action_mob.add_filter("rad_fiend_glow", 1, list("type" = "outline", "color" = glow_color+"30", "size" = glow_range))

modular_zzplurt/code/datums/quirks/neutral_quirks/sodiumsensetivity.dm

@@ -0,0 +1,26 @@
+#define TRAIT_SALT_SENSITIVE "salt_sensitive"
+
+GLOBAL_LIST_INIT(traits_by_type_saltsensetive, list(
+	/obj/item/toy/plush/skyrat = list(
+		"TRAIT_SALT_SENSITIVE" = TRAIT_SALT_SENSITIVE, //SPLURT addition - for sodium sensetivity quirk
+	),
+))
+
+/datum/quirk/sodiumsensetivity
+	name = "Sodium Sensitivity"
+	desc = "Your body is sensitive to sodium, and is burnt upon contact. Ingestion or contact with it is not advised."
+	icon = FA_ICON_BIOHAZARD
+	value = 0
+	mob_trait = TRAIT_SALT_SENSITIVE
+	medical_record_text = "Patient should not come into contact with sodium."
+
+/datum/reagent/consumable/salt/expose_mob(mob/living/M, method=TOUCH, reac_volume)
+	. = ..()
+	if(HAS_TRAIT(M, TRAIT_SALT_SENSITIVE)) // haha snails go brrr
+		M.adjustFireLoss(2)
+		M.emote("scream")
+
+/datum/reagent/consumable/salt/on_mob_life(mob/living/M)
+	. = ..()
+	if(HAS_TRAIT(M, TRAIT_SALT_SENSITIVE))
+		M.adjustFireLoss(1) // equal to a standard toxin

tgstation.dme

@@ -1,4 +1,4 @@
 // All manual changes should be made outside the BEGIN_ and END_ blocks.
 // New source code should be placed in .dm files: choose File/New --> Code File.
 // BEGIN_INTERNALS
 // END_INTERNALS
@@ -9101,6 +9101,9 @@
 #include "modular_zubbers\master_files\skyrat\modules\cortical_borer\code\cortical_borer_antag.dm"
 #include "modular_zubbers\master_files\skyrat\modules\opposing_force\code\opposing_force_subsystem.dm"
 #include "modular_zubbers\master_files\skyrat\modules\verbs\code\subtle.dm"
+#include "modular_zzplurt\code\datums\quirks\neutral_quirks\modularlimbs.dm"
+#include "modular_zzplurt\code\datums\quirks\neutral_quirks\radfiend.dm"
+#include "modular_zzplurt\code\datums\quirks\neutral_quirks\sodiumsensetivity.dm"
 #include "modular_zzplurt\code\_globalvars\mobs.dm"
 #include "modular_zzplurt\code\controllers\configuration\entries\discord.dm"
 #include "modular_zzplurt\code\controllers\subsystem\discord.dm"