Add a conversion mechanism between NLPModel to OptimizationProblem

lib/OptimizationNLPModels/LICENSE

@@ -0,0 +1,21 @@
+MIT License
+
+Copyright (c) 2023 Vaibhav Dixit <[email protected]> and contributors
+
+Permission is hereby granted, free of charge, to any person obtaining a copy
+of this software and associated documentation files (the "Software"), to deal
+in the Software without restriction, including without limitation the rights
+to use, copy, modify, merge, publish, distribute, sublicense, and/or sell
+copies of the Software, and to permit persons to whom the Software is
+furnished to do so, subject to the following conditions:
+
+The above copyright notice and this permission notice shall be included in all
+copies or substantial portions of the Software.
+
+THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS OR
+IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF MERCHANTABILITY,
+FITNESS FOR A PARTICULAR PURPOSE AND NONINFRINGEMENT. IN NO EVENT SHALL THE
+AUTHORS OR COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER
+LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE, ARISING FROM,
+OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE USE OR OTHER DEALINGS IN THE
+SOFTWARE.

lib/OptimizationNLPModels/Project.toml

@@ -0,0 +1,21 @@
+name = "OptimizationNLPModels"
+uuid = "064b21be-54cf-11ef-1646-cdfee32b588f"
+authors = ["Vaibhav Dixit <[email protected]> and contributors"]
+version = "0.0.1"
+
+[deps]
+ADTypes = "47edcb42-4c32-4615-8424-f2b9edc5f35b"
+NLPModels = "a4795742-8479-5a88-8948-cc11e1c8c1a6"
+Optimization = "7f7a1694-90dd-40f0-9382-eb1efda571ba"
+Reexport = "189a3867-3050-52da-a836-e630ba90ab69"
+
+[extras]
+NLPModelsTest = "7998695d-6960-4d3a-85c4-e1bceb8cd856"
+OptimizationOptimJL = "36348300-93cb-4f02-beb5-3c3902f8871e"
+Test = "8dfed614-e22c-5e08-85e1-65c5234f0b40"
+Zygote = "e88e6eb3-aa80-5325-afca-941959d7151f"
+Ipopt = "b6b21f68-93f8-5de0-b562-5493be1d77c9"
+OptimizationMOI = "fd9f6733-72f4-499f-8506-86b2bdd0dea1"
+
+[targets]
+test = ["Test", "NLPModelsTest", "OptimizationOptimJL", "Zygote", "Ipopt", "OptimizationMOI"]

lib/OptimizationNLPModels/src/OptimizationNLPModels.jl

@@ -0,0 +1,42 @@
+module OptimizationNLPModels
+
+using Reexport
+@reexport using NLPModels, Optimization, ADTypes
+
+function SciMLBase.OptimizationFunction(nlpmodel::AbstractNLPModel,
+        adtype::ADTypes.AbstractADType = SciMLBase.NoAD(); kwargs...)
+    f(x, p) = NLPModels.obj(nlpmodel, x)
+    grad(G, u, p) = NLPModels.grad!(nlpmodel, u, G)
+    hess(H, u, p) = (H .= NLPModels.hess(nlpmodel, u))
+    hv(Hv, u, v, p) = NLPModels.hprod!(nlpmodel, u, v, Hv)
+
+    if !unconstrained(nlpmodel)
+        cons(res, x, p) = NLPModels.cons!(nlpmodel, x, res)
+        cons_j(J, x, p) = (J .= NLPModels.jac(nlpmodel, x))
+        cons_jvp(Jv, v, x, p) = NLPModels.jprod!(nlpmodel, x, v, Jv)
+
+        return OptimizationFunction(
+            f, adtype; grad, hess, hv, cons, cons_j, cons_jvp, kwargs...)
+    end
+
+    return OptimizationFunction(f, adtype; grad, hess, hv, kwargs...)
+end
+
+function OptimizationProblem(nlpmodel::AbstractNLPModel,
+        adtype::ADTypes.AbstractADType = SciMLBase.NoAD(); kwargs...)
+    f = OptimizationFunction(nlpmodel, adtype; kwargs...)
+    u0 = nlpmodel.meta.x0
+    lb = nlpmodel.meta.lvar
+    ub = nlpmodel.meta.uvar
+    lcons = nlpmodel.meta.lcon
+    ucons = nlpmodel.meta.ucon
+    sense = nlpmodel.meta.minimize ? Optimization.MinSense : Optimization.MaxSense
+
+    # The number of variables, geometry of u0, etc.. are valid and were checked when the
+    # nlpmodel was created.
+
+    return Optimization.OptimizationProblem(
+        f, u0; lb = lb, ub = ub, lcons = lcons, ucons = ucons, sense = sense, kwargs...)
+end
+
+end

lib/OptimizationNLPModels/test/runtests.jl

@@ -0,0 +1,62 @@
+using OptimizationNLPModels, Optimization, NLPModelsTest, Ipopt, OptimizationMOI, Zygote,
+      OptimizationOptimJL
+using Test
+
+@testset "NLPModels" begin
+    # First problem: Problem 5 in the Hock-Schittkowski suite
+    # Problem with box bounds
+    hs5f(u, p) = sin(u[1] + u[2]) + (u[1] - u[2])^2 - (3 / 2) * u[1] + (5 / 2)u[2] + 1
+    f = Optimization.OptimizationFunction(hs5f, Optimization.AutoZygote())
+    lb = [-1.5; -3]
+    ub = [4.0; 3.0]
+    u0 = [0.0; 0.0]
+    oprob = Optimization.OptimizationProblem(
+        f, u0, lb = lb, ub = ub, sense = Optimization.MinSense)
+
+    nlpmo = NLPModelsTest.HS5()
+    converted = OptimizationNLPModels.OptimizationProblem(nlpmo, Optimization.AutoZygote())
+
+    sol_native = solve(oprob, Ipopt.Optimizer())
+    sol_converted = solve(converted, Ipopt.Optimizer())
+
+    @test sol_converted.retcode == sol_native.retcode
+    @test sol_converted.u ≈ sol_native.u
+
+    # Second problem: Brown and Dennis function
+    # Problem without bounds
+    function brown_dennis(u, p)
+        return sum([((u[1] + (i / 5) * u[2] - exp(i / 5))^2 +
+                     (u[3] + sin(i / 5) * u[4] - cos(i / 5))^2)^2 for i in 1:20])
+    end
+    f = Optimization.OptimizationFunction(brown_dennis, Optimization.AutoZygote())
+    u0 = [25.0; 5.0; -5.0; -1.0]
+    oprob = Optimization.OptimizationProblem(f, u0, sense = Optimization.MinSense)
+
+    nlpmo = NLPModelsTest.BROWNDEN()
+    converted = OptimizationNLPModels.OptimizationProblem(nlpmo, Optimization.AutoZygote())
+
+    sol_native = solve(oprob, BFGS())
+    sol_converted = solve(converted, BFGS())
+
+    @test sol_converted.retcode == sol_native.retcode
+    @test sol_converted.u ≈ sol_native.u
+
+    # Third problem: Problem 10 in the Hock-Schittkowski suite
+    # Problem with inequality bounds
+    hs10(u, p) = u[1] - u[2]
+    hs10_cons(res, u, p) = (res .= -3.0 * u[1]^2 + 2.0 * u[1] * u[2] - u[2]^2 + 1.0)
+    lcons = [0.0]
+    ucons = [Inf]
+    u0 = [-10.0; 10.0]
+    f = Optimization.OptimizationFunction(hs10, Optimization.AutoForwardDiff(); cons = hs10_cons)
+    oprob = Optimization.OptimizationProblem(f, u0, lcons = lcons, ucons = ucons)
+
+    nlpmo = NLPModelsTest.HS10()
+    converted = OptimizationNLPModels.OptimizationProblem(nlpmo, Optimization.AutoForwardDiff())
+
+    sol_native = solve(oprob, Ipopt.Optimizer())
+    sol_converted = solve(converted, Ipopt.Optimizer())
+
+    @test sol_converted.retcode == sol_native.retcode
+    @test sol_converted.u ≈ sol_native.u
+end