new CMake structure

CMakeLists.txt

@@ -0,0 +1,49 @@
+cmake_minimum_required(VERSION 3.1 FATAL_ERROR)
+project(CGAL-Community-Plugins)
+
+if (NOT ParaView_BINARY_DIR)
+  find_package(ParaView REQUIRED)
+endif()
+
+include(GNUInstallDirs)
+set(CMAKE_RUNTIME_OUTPUT_DIRECTORY "${CMAKE_BINARY_DIR}/${CMAKE_INSTALL_BINDIR}")
+set(CMAKE_LIBRARY_OUTPUT_DIRECTORY "${CMAKE_BINARY_DIR}/${CMAKE_INSTALL_LIBDIR}")
+set(CMAKE_ARCHIVE_OUTPUT_DIRECTORY "${CMAKE_BINARY_DIR}/${CMAKE_INSTALL_LIBDIR}")
+
+if(PARAVIEW_USE_FILE)
+  # ParaView 5.6
+  # ------------
+  #If the plugin is used internally we don't need to include.
+  if (NOT ParaView_BINARY_DIR)
+      include(${PARAVIEW_USE_FILE})
+  endif(NOT ParaView_BINARY_DIR)
+  add_subdirectory(Plugins/CGAL)
+else()
+  # ParaView 6 or later
+  # --------------------
+  #  `paraview_plugin_build` uses `add_subdirectory` so it has to be in a sub-directory
+  paraview_plugin_scan(
+    PLUGIN_FILES "${CMAKE_CURRENT_SOURCE_DIR}/Plugins/CGAL/CGAL.plugin"
+    ENABLE_BY_DEFAULT ON
+    HIDE_PLUGINS_FROM_CACHE ON
+    PROVIDES_PLUGINS  plugins
+    REQUIRES_MODULES  required_modules
+    )
+
+  foreach (module IN LISTS required_modules)
+    if (NOT TARGET "${module}")
+      message("Missing required module: ${module}")
+      return ()
+    endif ()
+  endforeach ()
+
+  #Message("CMAKE_INSTALL_BINDIR" "${CMAKE_INSTALL_BINDIR}")
+  #Message("CMAKE_INSTALL_LIBDIR" "${CMAKE_INSTALL_LIBDIR}")
+  #Message("PARAVIEW_PLUGIN_SUBDIR" "${PARAVIEW_PLUGIN_SUBDIR}")
+
+  paraview_plugin_build(
+    RUNTIME_DESTINATION "${CMAKE_INSTALL_BINDIR}"
+    LIBRARY_DESTINATION "${CMAKE_INSTALL_LIBDIR}"
+    LIBRARY_SUBDIRECTORY "${PARAVIEW_PLUGIN_SUBDIR}"
+    PLUGINS ${plugins})
+endif()

Plugins/CGAL/CGAL.plugin

@@ -0,0 +1,8 @@
+NAME
+  CGALFilter
+DESCRIPTION
+  Set of CGAL plugins
+CONDITION
+REQUIRES_MODULES
+  VTK::FiltersCore
+  VTK::CommonExecutionModel

Plugins/CGAL/CGALFilters/CMakeLists.txt

@@ -0,0 +1,33 @@
+find_package(CGAL REQUIRED)
+if(CGAL_FOUND)
+  include( ${CGAL_USE_FILE} )
+endif(CGAL_FOUND)
+
+#Paraview's macro to add the plugin. It takes care of all the vtk
+#and paraview parts of the process, like link and integration
+#in the UI
+if(ParaView_FOUND AND PARAVIEW_USE_FILE)
+  ## ParaView 5.6
+  add_paraview_plugin(CGALFilter "1.0"
+    SERVER_MANAGER_XML vtkCGALFilters.xml
+    SERVER_MANAGER_SOURCES vtkCGAL3DPolyhedralMesher.cxx
+                           vtkCGALBoolean.cxx)
+
+  target_link_libraries(CGALFilter PRIVATE CGAL::CGAL)
+
+else()
+  ## ParaView 6.0 or later
+  set(classes
+    vtkCGAL3DPolyhedralMesher
+    vtkCGALBoolean)
+
+  vtk_module_add_module(CGALFilters
+    CLASSES ${classes})
+
+  paraview_add_server_manager_xmls(
+    XMLS  vtkCGALFilters.xml)
+
+  # Link with CGAL
+  target_link_libraries(CGALFilters PRIVATE CGAL::CGAL)
+
+endif()

Plugins/CGAL/CGALFilters/vtk.module

@@ -0,0 +1,8 @@
+NAME
+  CGALFilters
+DEPENDS
+  VTK::FiltersCore
+  VTK::FiltersGeometry
+  VTK::CommonSystem
+PRIVATE_DEPENDS
+  VTK::CommonCore

CGAL3DPolyhedralMesher/vtkCGAL3DPolyhedralMesher.h → Plugins/CGAL/CGALFilters/vtkCGAL3DPolyhedralMesher.h

@@ -2,10 +2,11 @@
 #define vtkCGAL3DPolyhedralMesher_h
 
 #include "vtkPolyDataAlgorithm.h"
+#include <CGALFiltersModule.h>
 
 class vtkPointSet;
 
-class vtkCGAL3DPolyhedralMesher : public vtkPolyDataAlgorithm
+class CGALFILTERS_EXPORT vtkCGAL3DPolyhedralMesher : public vtkPolyDataAlgorithm
 {
 public:
   static vtkCGAL3DPolyhedralMesher* New();