How to add terrain label data

Label data can be uploaded to enhance the terrains uploaded to R3. Town, city, village, airport, dock labels can be overlaid onto the map to assist with AAR discussion and bearing.

Exporting terrain label data

Getting the map label data is simple and only requires CBA to be loaded:

1. Create a new mission in the editor on your terrain of choice, place a unit and click play
2. After you have loaded into your character, press escape and copy and paste the following into the Debug console text area:

diag_log "R3 POI Finder | Init";

private _mapName = worldName;
private _data = "";
private _mapCenter = getArray (ConfigFile >> "CfgWorlds" >> _mapName >> "centerPosition");
private _mapSize = 2000000;

{
    private _poiType = _x;
    private _mapLocations = nearestLocations [_mapCenter, [_x], _mapSize];
    diag_log format["R3 POI Finder | Number of %1 locations: %2.", _poiType, count _mapLocations];

    {
        private _singlePoiData = format['{"label":"%1","type":"%2","x":%3,"y":%4}',
            text _x,
            toLower _poiType,
            getPos _x select 0, 
            getPos _x select 1
        ];

        private _seperator = if (_data == "") then { "" } else { "," };
        _data = [[_data, _singlePoiData], _seperator] call CBA_fnc_join;

    } forEach _mapLocations;

} forEach ["Name","NameLocal","NameVillage","NameCity","NameCityCapital","Airport","NameMarine","Strategic","StrongPointArea"];

copyToClipboard _data; 

diag_log "R3 POI Finder | All locations found and saved to clipboard";

null = [] spawn {
    hint "Finished! The data is in your clipboard, paste it into the R3 tiler website!";
    sleep 5;
    call BIS_fnc_endMission;
};

3. Press LOCAL EXEC and that's it! You will now have the label data on your clipboard
4. Go immediately to the R3 tiling website and paste the data into the box that appears after clicking Missing town labels, add? link next to your terrain