Implement TeleporterOwnerUpgradeable

contracts/src/CrossChainApplications/ERC20Bridge/ERC20Bridge.sol

@@ -10,13 +10,11 @@ import "./BridgeToken.sol";
 import "../../Teleporter/ITeleporterMessenger.sol";
 import "../../Teleporter/ITeleporterReceiver.sol";
 import "../../Teleporter/SafeERC20TransferFrom.sol";
-import "../../Teleporter/upgrades/TeleporterRegistry.sol";
-import "../../Teleporter/upgrades/TeleporterUpgradeable.sol";
+import "../../Teleporter/upgrades/TeleporterOwnerUpgradeable.sol";
 import "@subnet-evm-contracts/interfaces/IWarpMessenger.sol";
 import "@openzeppelin/contracts/token/ERC20/ERC20.sol";
 import "@openzeppelin/contracts/token/ERC20/utils/SafeERC20.sol";
 import "@openzeppelin/contracts/security/ReentrancyGuard.sol";
-import "@openzeppelin/contracts/access/Ownable.sol";
 
 /**
  * @dev Implementation of the {IERC20Bridge} interface.
@@ -28,8 +26,7 @@ contract ERC20Bridge is
     IERC20Bridge,
     ITeleporterReceiver,
     ReentrancyGuard,
-    TeleporterUpgradeable,
-    Ownable
+    TeleporterOwnerUpgradeable
 {
     using SafeERC20 for IERC20;
 
@@ -79,7 +76,7 @@ contract ERC20Bridge is
      */
     constructor(
         address teleporterRegistryAddress
-    ) TeleporterUpgradeable(teleporterRegistryAddress) {
+    ) TeleporterOwnerUpgradeable(teleporterRegistryAddress) {
         currentChainID = WarpMessenger(WARP_PRECOMPILE_ADDRESS)
             .getBlockchainID();
     }
@@ -324,23 +321,6 @@ contract ERC20Bridge is
         }
     }
 
-    /**
-     * @dev See {TeleporterUpgradeable-updateMinTeleporterVersion}
-     *
-     * Updates the minimum Teleporter version allowed for receiving on this contract
-     * to the latest version registered in the {TeleporterRegistry}.
-     * Restricted to only owners of the contract.
-     * Emits a {MinTeleporterVersionUpdated} event.
-     */
-    function updateMinTeleporterVersion() external override onlyOwner {
-        uint256 oldMinTeleporterVersion = minTeleporterVersion;
-        minTeleporterVersion = teleporterRegistry.getLatestVersion();
-        emit MinTeleporterVersionUpdated(
-            oldMinTeleporterVersion,
-            minTeleporterVersion
-        );
-    }
-
     /**
      * @dev Encodes the parameters for the Create action to be decoded and executed on the destination.
      */

contracts/src/CrossChainApplications/ERC20Bridge/tests/ERC20BridgeTests.t.sol

@@ -636,33 +636,6 @@ contract ERC20BridgeTest is Test {
         new ERC20Bridge(address(0));
     }
 
-    function testUpdateMinTeleporterVersion() public {
-        // Check that updating minimum Teleporter version fails if it's not the contract owner.
-        vm.prank(address(0));
-        vm.expectRevert("Ownable: caller is not the owner");
-        erc20Bridge.updateMinTeleporterVersion();
-
-        // Check that the owner can update the minimum Teleporter version.
-        vm.mockCall(
-            MOCK_TELEPORTER_REGISTRY_ADDRESS,
-            abi.encodeWithSelector(
-                WarpProtocolRegistry.getLatestVersion.selector
-            ),
-            abi.encode(2)
-        );
-        vm.expectCall(
-            MOCK_TELEPORTER_REGISTRY_ADDRESS,
-            abi.encodeWithSelector(
-                WarpProtocolRegistry.getLatestVersion.selector
-            )
-        );
-
-        vm.expectEmit(true, true, true, true, address(erc20Bridge));
-        emit MinTeleporterVersionUpdated(1, 2);
-        erc20Bridge.updateMinTeleporterVersion();
-        assertEq(erc20Bridge.minTeleporterVersion(), 2);
-    }
-
     function _initMockTeleporterRegistry() internal {
         vm.mockCall(
             MOCK_TELEPORTER_REGISTRY_ADDRESS,

contracts/src/CrossChainApplications/ExampleMessenger/ExampleCrossChainMessenger.sol

@@ -8,11 +8,9 @@ pragma solidity 0.8.18;
 import "../../Teleporter/ITeleporterMessenger.sol";
 import "../../Teleporter/SafeERC20TransferFrom.sol";
 import "../../Teleporter/ITeleporterReceiver.sol";
-import "../../Teleporter/upgrades/TeleporterRegistry.sol";
-import "../../Teleporter/upgrades/TeleporterUpgradeable.sol";
+import "../../Teleporter/upgrades/TeleporterOwnerUpgradeable.sol";
 import "@openzeppelin/contracts/token/ERC20/IERC20.sol";
 import "@openzeppelin/contracts/security/ReentrancyGuard.sol";
-import "@openzeppelin/contracts/access/Ownable.sol";
 
 /**
  * @dev ExampleCrossChainMessenger is an example contract that demonstrates how to send and receive
@@ -21,8 +19,7 @@ import "@openzeppelin/contracts/access/Ownable.sol";
 contract ExampleCrossChainMessenger is
     ITeleporterReceiver,
     ReentrancyGuard,
-    TeleporterUpgradeable,
-    Ownable
+    TeleporterOwnerUpgradeable
 {
     using SafeERC20 for IERC20;
 
@@ -57,7 +54,7 @@ contract ExampleCrossChainMessenger is
 
     constructor(
         address teleporterRegistryAddress
-    ) TeleporterUpgradeable(teleporterRegistryAddress) {}
+    ) TeleporterOwnerUpgradeable(teleporterRegistryAddress) {}
 
     /**
      * @dev See {ITeleporterReceiver-receiveTeleporterMessage}.
@@ -126,23 +123,6 @@ contract ExampleCrossChainMessenger is
             );
     }
 
-    /**
-     * @dev See {TeleporterUpgradeable-updateMinTeleporterVersion}
-     *
-     * Updates the minimum Teleporter version allowed for receiving on this contract
-     * to the latest version registered in the {TeleporterRegistry}. Also restricts this function to
-     * the owner of this contract.
-     * Emits a {MinTeleporterVersionUpdated} event.
-     */
-    function updateMinTeleporterVersion() external override onlyOwner {
-        uint256 oldMinTeleporterVersion = minTeleporterVersion;
-        minTeleporterVersion = teleporterRegistry.getLatestVersion();
-        emit MinTeleporterVersionUpdated(
-            oldMinTeleporterVersion,
-            minTeleporterVersion
-        );
-    }
-
     /**
      * @dev Returns the current message from another chain.
      */

contracts/src/CrossChainApplications/VerifiedBlockHash/BlockHashReceiver.sol

@@ -7,18 +7,12 @@ pragma solidity 0.8.18;
 
 import "../../Teleporter/ITeleporterMessenger.sol";
 import "../../Teleporter/ITeleporterReceiver.sol";
-import "../../Teleporter/upgrades/TeleporterRegistry.sol";
-import "../../Teleporter/upgrades/TeleporterUpgradeable.sol";
-import "@openzeppelin/contracts/access/Ownable.sol";
+import "../../Teleporter/upgrades/TeleporterOwnerUpgradeable.sol";
 
 /**
  * Contract for receiving latest block hashes from another chain.
  */
-contract BlockHashReceiver is
-    ITeleporterReceiver,
-    TeleporterUpgradeable,
-    Ownable
-{
+contract BlockHashReceiver is ITeleporterReceiver, TeleporterOwnerUpgradeable {
     // Source chain information
     bytes32 public immutable sourceChainID;
     address public immutable sourcePublisherContractAddress;
@@ -41,7 +35,7 @@ contract BlockHashReceiver is
         address teleporterRegistryAddress,
         bytes32 publisherChainID,
         address publisherContractAddress
-    ) TeleporterUpgradeable(teleporterRegistryAddress) {
+    ) TeleporterOwnerUpgradeable(teleporterRegistryAddress) {
         sourceChainID = publisherChainID;
         sourcePublisherContractAddress = publisherContractAddress;
     }
@@ -88,23 +82,6 @@ contract BlockHashReceiver is
         }
     }
 
-    /**
-     * @dev See {TeleporterUpgradeable-updateMinTeleporterVersion}
-     *
-     * Updates the minimum Teleporter version allowed for receiving on this contract
-     * to the latest version registered in the {TeleporterRegistry}.
-     * Restricted to only owners of the contract.
-     * Emits a {MinTeleporterVersionUpdated} event.
-     */
-    function updateMinTeleporterVersion() external override onlyOwner {
-        uint256 oldMinTeleporterVersion = minTeleporterVersion;
-        minTeleporterVersion = teleporterRegistry.getLatestVersion();
-        emit MinTeleporterVersionUpdated(
-            oldMinTeleporterVersion,
-            minTeleporterVersion
-        );
-    }
-
     /**
      * @dev Returns the latest block information.
      */

contracts/src/Teleporter/upgrades/README.md

@@ -52,7 +52,7 @@ The `TeleporterUpgradeable` contract saves the Teleporter registry in a state va
 
 Every derived contract of `TeleporterUpgradeable` must implement `TeleporterUpgradeable.updateMinTeleporterVersion`, which updates the `minTeleporterVersion` used by the `onlyAllowedTeleporter` modifier and emits the `MinTeleporterVersionUpdated` event. The `updateMinTeleporterVersion` function should be called by the dapp when it completes delivery of messages from the old Teleporter contract, and now wants to update the `minTeleporterVersion` to only allow the new Teleporter version.
 
-To prevent anyone from calling the dapp's `updateMinTeleporterVersion`, which would disallow messages from old Teleporter versions from being received, this function should be safeguarded with access controls. For example, the ERC20Bridge inherits `Ownable`,  and restricts the `updateMinTeleporterVersion` function call to the owner of the contract.
+To prevent anyone from calling the dapp's `updateMinTeleporterVersion`, which would disallow messages from old Teleporter versions from being received, this function should be safeguarded with access controls. For example, [TeleporterOwnerUpgrade](./TeleporterOwnerUpgradeable.sol) is a contract that inherits `TeleporterUpgradeable` and restricts `updateMinTeleporterVersion` calls to the owner of the contract. The [ERC20Bridge](../../CrossChainApplications/ERC20Bridge/ERC20Bridge.sol) contract is an example of inheriting `TeleporterOwnerUpgradeable`.
 
 ```solidity
     function updateMinTeleporterVersion() external override onlyOwner {

contracts/src/Teleporter/upgrades/TeleporterOwnerUpgradeable.sol

@@ -0,0 +1,39 @@
+// (c) 2023, Ava Labs, Inc. All rights reserved.
+// See the file LICENSE for licensing terms.
+
+// SPDX-License-Identifier: Ecosystem
+
+pragma solidity 0.8.18;
+
+import "./TeleporterUpgradeable.sol";
+import "@openzeppelin/contracts/access/Ownable.sol";
+
+/**
+ * @dev Contract that implements the {TeleporterUpgradeable} interface and allows
+ * only owners of the contract to update the minimum Teleporter version.
+ */
+abstract contract TeleporterOwnerUpgradeable is TeleporterUpgradeable, Ownable {
+    constructor(
+        address teleporterRegistryAddress
+    ) TeleporterUpgradeable(teleporterRegistryAddress) {}
+
+    /**
+     * @dev See {TeleporterUpgradeable-updateMinTeleporterVersion}
+     *
+     * Updates the minimum Teleporter version allowed for receiving on this contract
+     * to the latest version registered in the {TeleporterRegistry}.
+     * Restricted to only owners of the contract.
+     * Emits a {MinTeleporterVersionUpdated} event if the minimum Teleporter version
+     * was updated.
+     */
+    function updateMinTeleporterVersion() external override onlyOwner {
+        uint256 oldMinTeleporterVersion = minTeleporterVersion;
+        minTeleporterVersion = teleporterRegistry.getLatestVersion();
+        if (minTeleporterVersion > oldMinTeleporterVersion) {
+            emit MinTeleporterVersionUpdated(
+                oldMinTeleporterVersion,
+                minTeleporterVersion
+            );
+        }
+    }
+}

contracts/src/Teleporter/upgrades/tests/TeleporterOwnerUpgradeableTests.t.sol

@@ -0,0 +1,101 @@
+// (c) 2023, Ava Labs, Inc. All rights reserved.
+// See the file LICENSE for licensing terms.
+
+// SPDX-License-Identifier: Ecosystem
+
+pragma solidity 0.8.18;
+
+import "forge-std/Test.sol";
+import "../TeleporterOwnerUpgradeable.sol";
+import "./TeleporterUpgradeableTests.t.sol";
+
+contract ExampleOwnerUpgradeableApp is TeleporterOwnerUpgradeable {
+    constructor(
+        address teleporterRegistryAddress
+    ) TeleporterOwnerUpgradeable(teleporterRegistryAddress) {}
+}
+
+contract TeleporterOwnerUpgradeableTest is TeleporterUpgradeableTest {
+    ExampleOwnerUpgradeableApp app;
+
+    function setUp() public virtual override {
+        TeleporterUpgradeableTest.setUp();
+        app = new ExampleOwnerUpgradeableApp(address(teleporterRegistry));
+    }
+
+    function testOwnerUpdateMinTeleporterVersion() public {
+        uint256 minTeleporterVersion = app.minTeleporterVersion();
+
+        // Check that call to update minimum Teleporter version reverts for non-owners
+        vm.prank(teleporterAddress);
+        vm.expectRevert("Ownable: caller is not the owner");
+        app.updateMinTeleporterVersion();
+
+        // Check that minimum Teleporter version was not updated
+        assertEq(app.minTeleporterVersion(), minTeleporterVersion);
+
+        _addProtocolVersion(teleporterRegistry, teleporterAddress);
+
+        // Check that call to update minimum Teleporter version succeeds for owners
+        vm.prank(address(this));
+        vm.expectEmit(true, true, true, true, address(app));
+        emit MinTeleporterVersionUpdated(
+            minTeleporterVersion,
+            minTeleporterVersion + 1
+        );
+        app.updateMinTeleporterVersion();
+
+        assertEq(app.minTeleporterVersion(), minTeleporterVersion + 1);
+    }
+
+    function testOwnerTransfer() public {
+        uint256 minTeleporterVersion = app.minTeleporterVersion();
+        _addProtocolVersion(teleporterRegistry, teleporterAddress);
+
+        // Check that call to transfer ownership reverts for non-owners
+        vm.prank(teleporterAddress);
+        vm.expectRevert("Ownable: caller is not the owner");
+        app.transferOwnership(address(0));
+
+        // Check that ownership was not transferred
+        assertEq(app.owner(), address(this));
+
+        // Check that call for non owners reverts
+        vm.prank(teleporterAddress);
+        vm.expectRevert("Ownable: caller is not the owner");
+        app.updateMinTeleporterVersion();
+
+        // Check that after ownership transfer call succeeds
+        app.transferOwnership(teleporterAddress);
+        vm.prank(teleporterAddress);
+        vm.expectEmit(true, true, true, true, address(app));
+        emit MinTeleporterVersionUpdated(
+            minTeleporterVersion,
+            minTeleporterVersion + 1
+        );
+        app.updateMinTeleporterVersion();
+
+        // Check that call with old owner reverts
+        vm.prank(address(this));
+        vm.expectRevert("Ownable: caller is not the owner");
+        app.updateMinTeleporterVersion();
+    }
+
+    function testRenounceOwnership() public {
+        // Check that call to renounce ownership reverts for non-owners
+        vm.prank(teleporterAddress);
+        vm.expectRevert("Ownable: caller is not the owner");
+        app.renounceOwnership();
+
+        // Check that ownership was not renounced
+        assertEq(app.owner(), address(this));
+
+        // Check that update Teleporter version call for owner succeeds
+        app.updateMinTeleporterVersion();
+
+        // Check that after ownership renounce call reverts
+        app.renounceOwnership();
+        vm.expectRevert("Ownable: caller is not the owner");
+        app.updateMinTeleporterVersion();
+    }
+}