agrupa os recursos e define o output do projeto

modules/groupResources/groupByKind/outputs.tf

@@ -0,0 +1,21 @@
+locals {
+  kinds = distinct([
+    for resource in var.resources : resource.kind
+    if resource.apiGroup == var.apiGroup
+  ])
+}
+
+module "resources" {
+  source   = "./resources/"
+  for_each = toset(local.kinds)
+
+  apiGroup  = var.apiGroup
+  kind      = each.key
+  resources = var.resources
+}
+
+output "kinds" {
+  value = {
+    for kind, result in module.resources : kind => result.resources
+  }
+}

modules/groupResources/groupByKind/resources/outputs.tf

@@ -0,0 +1,6 @@
+output "resources" {
+  value = {
+    for resource in var.resources : resource.metadata.name => resource
+    if resource.apiGroup == var.apiGroup && resource.kind == var.kind
+  }
+}

modules/groupResources/groupByKind/resources/variables.tf

@@ -0,0 +1,11 @@
+variable "apiGroup" {
+  type = string
+}
+
+variable "kind" {
+  type = string
+}
+
+variable "resources" {
+  type = any
+}

modules/groupResources/groupByKind/variables.tf

@@ -0,0 +1,7 @@
+variable "apiGroup" {
+  type = string
+}
+
+variable "resources" {
+  type = any
+}

modules/groupResources/outputs.tf

@@ -0,0 +1,19 @@
+locals {
+  apiGroups = distinct([
+    for resource in var.resources : resource.apiGroup
+  ])
+}
+
+module "kinds" {
+  source = "./groupByKind/"
+  for_each = toset(local.apiGroups)
+
+  apiGroup = each.key
+  resources = var.resources
+}
+
+output "groupedResources" {
+  value = {
+    for apiGroup, result in module.kinds : apiGroup => result.kinds
+  }
+}

modules/groupResources/variables.tf

@@ -0,0 +1,3 @@
+variable "resources" {
+  type = any
+}

outputs.tf

@@ -0,0 +1,9 @@
+module "groupResources" {
+  source = "./modules/groupResources/"
+
+  resources = module.resources[*].instance
+}
+
+output "resources" {
+  value = module.groupResources.groupedResources
+}