Add Terraform setup

infrastructure/terraform/network.tf

@@ -0,0 +1,17 @@
+resource "hcloud_network" "hc_private" {
+  name     = "hc_private"
+  ip_range = var.ip_range
+}
+
+resource "hcloud_server_network" "web_network" {
+  count     = var.instances
+  server_id = hcloud_server.web[count.index].id
+  subnet_id = hcloud_network_subnet.hc_private_subnet.id
+}
+
+resource "hcloud_network_subnet" "hc_private_subnet" {
+  network_id   = hcloud_network.hc_private.id
+  type         = "cloud"
+  network_zone = "eu-central"
+  ip_range     = var.ip_range
+}

infrastructure/terraform/output.tf

@@ -0,0 +1,13 @@
+output "web_servers_status" {
+  value = {
+    for server in hcloud_server.web :
+    server.name => server.status
+  }
+}
+
+output "web_servers_ips" {
+  value = {
+    for server in hcloud_server.web :
+    server.name => server.ipv4_address
+  }
+}

infrastructure/terraform/provider.tf

@@ -0,0 +1,13 @@
+# hetzner cloud provider
+provider "hcloud" {
+    token = "${var.hcloud_token}"
+}
+
+terraform {
+  required_providers {
+    hcloud = {
+      source = "hetznercloud/hcloud"
+    }
+  }
+  required_version = ">= 0.13"
+}

infrastructure/terraform/ssh.tf

@@ -0,0 +1,4 @@
+resource "hcloud_ssh_key" "default" {
+  name       = "hetzner_key"
+  public_key = file("~/.ssh/tf_hetzner.pub")
+}

infrastructure/terraform/user_data.yml

@@ -0,0 +1,44 @@
+#cloud-config
+users:
+  - name: root
+    groups: users, admin
+    sudo: ALL=(ALL) NOPASSWD:ALL
+    shell: /bin/bash
+    ssh_authorized_keys:
+      - ssh-rsa 
+package_update: true
+package_upgrade: true
+packages:
+      - ca-certificates
+      - curl
+      - gnupg
+      - vim
+      - git
+      - zip
+      - unzip
+      - openssl
+      - libssl-dev
+      - build-essential
+      - libclang-dev
+runcmd:
+  - apt-get install pkg-config cmake clang lldb lld -y
+  - wget -P /root/ https://nodejs.org/dist/v18.18.0/node-v18.18.0-linux-x64.tar.xz
+  - tar -xf /root/node-v18.18.0-linux-x64.tar.xz --directory=/usr/local/ --strip-components=1
+  - rm /root/node-v18.18.0-linux-x64.tar.xz
+  - npm install --global yarn
+  - curl --proto '=https' --tlsv1.2 -sSf https://sh.rustup.rs | bash -s -- -y
+  - echo ". /root/.cargo/env" >> /root/.bashrc
+  - install -m 0755 -d /etc/apt/keyrings
+  - curl -fsSL https://download.docker.com/linux/debian/gpg | gpg --dearmor -o /etc/apt/keyrings/docker.gpg
+  - chmod a+r /etc/apt/keyrings/docker.gpg
+  - echo "deb [arch="$(dpkg --print-architecture)" signed-by=/etc/apt/keyrings/docker.gpg] https://download.docker.com/linux/debian "$(. /etc/os-release && echo "$VERSION_CODENAME")" stable" | tee /etc/apt/sources.list.d/docker.list > /dev/null
+  - apt-get update -y
+  - apt-get install -y docker-ce docker-ce-cli containerd.io docker-buildx-plugin docker-compose-plugin
+  - apt-get install -y docker-compose
+  - apt-get install axel
+  - /root/.cargo/bin/cargo install cargo-nextest
+  - apt-get install postgresql -y
+  - /root/.cargo/bin/cargo install sqlx-cli --version 0.5.13
+  - service postgresql stop
+  - git clone https://github.com/matter-labs/zksync-era.git /root/zksync-era
+  - mv /root/.cargo/bin/cargo /usr/bin && export ZKSYNC_HOME=/root/zksync-era && export PATH=$ZKSYNC_HOME/bin:$PATH && cd /root/zksync-era && zk && zk init && zk server

infrastructure/terraform/variable.tf

@@ -0,0 +1,35 @@
+variable "hcloud_token" {
+
+}
+
+variable "location" {
+    default = "nbg1"
+}
+
+variable "http_protocol" {
+    default = "http"
+}
+
+variable "http_port" {
+    default = "80"
+}
+
+variable "instances" {
+    default = "1"
+}
+
+variable "server_type" {
+    default = "cpx31"
+}
+
+variable "os_type" {
+    default = "debian-12"
+}
+
+variable "disk_size" {
+    default = "60"
+}
+
+variable "ip_range" {
+    default = "10.0.1.0/24"
+}

infrastructure/terraform/volumes.tf

@@ -0,0 +1,14 @@
+resource "hcloud_volume" "web_server_volume" {
+  count    = var.instances
+  name     = "zk-server-volume-${count.index}"
+  size     = var.disk_size
+  location = var.location
+  format   = "xfs"
+}
+
+resource "hcloud_volume_attachment" "web_vol_attachment" {
+  count     = var.instances
+  volume_id = hcloud_volume.web_server_volume[count.index].id
+  server_id = hcloud_server.web[count.index].id
+  automount = true
+}

infrastructure/terraform/web_servers.tf

@@ -0,0 +1,12 @@
+resource "hcloud_server" "web" {
+  count       = var.instances
+  name        = "zksync-${count.index}"
+  image       = var.os_type
+  server_type = var.server_type
+  location    = var.location
+  ssh_keys    = [hcloud_ssh_key.default.id]
+  labels = {
+    type = "web"
+  }
+  user_data = file("user_data.yml")
+}