init: atomic-browser at 0.37.0

- Use pnpm2nix-nzbr which supports pnpm version 6 lockfiles.
- Because atomic-browser is using pnpm workspaces, `installInPlace` and `distDir="."`

A follow up PR will create a module for this

Co-authored-by: Anish Lakhwara <[email protected]>

flake.nix

@@ -17,6 +17,8 @@
   inputs.rust-overlay.inputs.nixpkgs.follows = "nixpkgs";
   inputs.dream2nix.url = "github:nix-community/dream2nix";
   inputs.dream2nix.inputs.nixpkgs.follows = "nixpkgs";
+  inputs.pnpm2nix-nzbr.url = "github:nzbr/pnpm2nix-nzbr";
+  inputs.pnpm2nix-nzbr.inputs.nixpkgs.follows = "nixpkgs";
 
   outputs = {
     self,
@@ -26,6 +28,7 @@
     sops-nix,
     rust-overlay,
     dream2nix,
+    pnpm2nix-nzbr,
     ...
   }: let
     inherit
@@ -72,6 +75,7 @@
 
       pkgsByName = import ./pkgs/by-name {
         inherit (pkgs) lib;
+        inherit (pkgs) mkPnpmPackage;
         inherit callPackage dream2nix pkgs;
       };
 
@@ -105,7 +109,10 @@
       rawNixosConfigs;
 
     eachDefaultSystemOutputs = flake-utils.lib.eachDefaultSystem (system: let
-      pkgs = importNixpkgs system [rust-overlay.overlays.default];
+      pkgs = importNixpkgs system [
+        rust-overlay.overlays.default
+        pnpm2nix-nzbr.overlays.default
+      ];
       treefmtEval = loadTreefmt pkgs;
       toplevel = name: config: nameValuePair "nixosConfigs/${name}" config.config.system.build.toplevel;
     in {

pkgs/by-name/atomic-browser/package.nix

@@ -0,0 +1,36 @@
+{
+  fetchFromGitHub,
+  lib,
+  mkPnpmPackage,
+}: let
+  inherit
+    (lib)
+    licenses
+    maintainers
+    ;
+in
+mkPnpmPackage rec {
+  pname = "atomic-browser";
+  version = "v0.37.0";
+
+  monorepoSrc = fetchFromGitHub {
+    owner = "atomicdata-dev";
+    repo = "atomic-server";
+    rev = "v0.37.0";
+    hash = "sha256-+Lk2MvkTj+B+G6cNbWAbPrN5ECiyMJ4HSiiLzBLd74g=";
+  };
+
+  src = "${monorepoSrc}/browser";
+
+  # These 2 options are needed to work with pnpm workspaces, which atomic-browser is using
+  # https://github.com/nzbr/pnpm2nix-nzbr/issues/29#issuecomment-1918811838
+  installInPlace = true;
+  distDir = ".";
+
+  meta = {
+    description = "Create, share, fetch and model linked Atomic Data! There are three components: a javascript / typescript library, a react library, and a complete GUI: Atomic-Data Browser.";
+    homepage = "https://github.com/atomicdata-dev/atomic-server/tree/develop/browser";
+    license = licenses.mit;
+    maintainers = with maintainers; [];
+  };
+}

pkgs/by-name/default.nix

@@ -2,6 +2,7 @@
   lib,
   callPackage,
   dream2nix,
+  mkPnpmPackage,
   pkgs,
 }: let
   baseDirectory = ./.;