Gun Safety PSA - Keep your gun safeties on to prevent accidental discharges!

code/__DEFINES/guns.dm

@@ -69,6 +69,11 @@
 #define MANUFACTURER_PGF "the Etherbor Industries emblem"
 #define MANUFACTURER_IMPORT "Lanchester Import Co."
 
+// Misfire chances if the gun's safety is off
+#define GUN_NO_SAFETY_MALFUNCTION_CHANCE_LOW 5
+#define GUN_NO_SAFETY_MALFUNCTION_CHANCE_MEDIUM 40
+#define GUN_NO_SAFETY_MALFUNCTION_CHANCE_HIGH 80
+
 /////////////////
 // ATTACHMENTS //
 /////////////////

code/game/objects/items/storage/storage.dm

@@ -28,6 +28,12 @@
 			if(EXPLODE_LIGHT)
 				SSexplosions.lowobj += A
 
+/obj/item/storage/throw_impact(atom/hit_atom, datum/thrownthing/throwingdatum)
+	. = ..()
+	for(var/obj/item/gun/at_risk in get_all_contents())
+		if(at_risk.safety == FALSE && prob(GUN_NO_SAFETY_MALFUNCTION_CHANCE_HIGH))
+			at_risk.discharge("is hits the ground hard")
+
 /obj/item/storage/canStrip(mob/who)
 	. = ..()
 	if(!. && rummage_if_nodrop)

code/modules/mob/living/carbon/carbon_movement.dm

@@ -3,6 +3,7 @@
 		return FALSE
 	if(!(lube&SLIDE_ICE))
 		log_combat(src, (O ? O : get_turf(src)), "slipped on the", null, ((lube & SLIDE) ? "(LUBE)" : null))
+	trip_with_gun()
 	return loc.handle_slip(src, knockdown_amount, O, lube, paralyze, force_drop)
 
 /mob/living/carbon/Process_Spacemove(movement_dir = 0)

code/modules/projectiles/ammunition/_firing.dm

@@ -15,11 +15,11 @@
 			return FALSE
 		AddComponent(/datum/component/pellet_cloud, projectile_type, pellets)
 		SEND_SIGNAL(src, COMSIG_PELLET_CLOUD_INIT, target, user, fired_from, randomspread, spread, zone_override, params, distro)
+	if(user)
+		if(click_cooldown_override)
+			user.changeNext_move(click_cooldown_override)
 
-	if(click_cooldown_override)
-		user.changeNext_move(click_cooldown_override)
-
-	user.newtonian_move(get_dir(target, user))
+		user.newtonian_move(get_dir(target, user))
 	update_appearance()
 	return TRUE
 
@@ -45,7 +45,11 @@
 		qdel(reagents)
 
 /obj/item/ammo_casing/proc/throw_proj(atom/target, turf/targloc, mob/living/user, params, spread)
-	var/turf/curloc = get_turf(user)
+	var/turf/curloc
+	if(user)
+		curloc = get_turf(user)
+	else
+		curloc = get_turf(src)
 	if (!istype(targloc) || !istype(curloc) || !BB)
 		return FALSE
 
@@ -60,7 +64,10 @@
 		if(target) //if the target is right on our location we'll skip the travelling code in the proj's fire()
 			direct_target = target
 	if(!direct_target)
-		BB.preparePixelProjectile(target, user, params, spread)
+		if(user)
+			BB.preparePixelProjectile(target, user, params, spread)
+		else
+			BB.preparePixelProjectile(target, curloc, params, spread)
 	BB.fire(null, direct_target)
 	BB = null
 	return TRUE

code/modules/projectiles/gun.dm

@@ -726,6 +726,11 @@
 	if(zoomed)
 		zoom(user, user.dir)
 
+/obj/item/gun/throw_impact(atom/hit_atom, datum/thrownthing/throwingdatum)
+	. = ..()
+	if(prob(GUN_NO_SAFETY_MALFUNCTION_CHANCE_HIGH))
+		discharge("hits the ground hard", 80)
+
 /obj/item/gun/update_overlays()
 	. = ..()
 	if(ismob(loc) && has_safety)
@@ -945,6 +950,45 @@
 		flash_loc.vis_contents -= muzzle_flash
 	muzzle_flash.applied = FALSE
 
+// for guns firing on their own without a user
+/obj/item/gun/proc/discharge(cause, seek_chance = 50)
+	var/target
+	if(!safety)
+		// someone is very unlucky and about to be shot
+		if(prob(seek_chance))
+			for(var/mob/living/target_mob in range(6, get_turf(src)))
+				if(!isInSight(src, target_mob))
+					continue
+				target = target_mob
+				break
+		if(!target)
+			var/fire_dir = pick(GLOB.alldirs)
+			target = get_ranged_target_turf(get_turf(src),fire_dir,6)
+		if(!chambered || !chambered.BB)
+			visible_message(span_danger("\The [src] [cause ? "[cause], suddenly going off" : "suddenly goes off"] without its safteies on! Luckily it wasn't live."))
+			playsound(src, dry_fire_sound, 30, TRUE)
+		else
+			visible_message(span_danger("\The [src] [cause ? "[cause], suddenly going off" : "suddenly goes off"] without its safeties on!"))
+			unsafe_shot(target)
+
+/obj/item/gun/proc/unsafe_shot(target)
+	if(chambered)
+		chambered.fire_casing(target,null, null, null, suppressed, ran_zone(BODY_ZONE_CHEST, 50), 0, src)
+		playsound(src, fire_sound, 100, TRUE)
+
+/mob/living/proc/trip_with_gun()
+	for(var/obj/item/gun/at_risk in get_all_contents())
+		var/chance_to_fire = GUN_NO_SAFETY_MALFUNCTION_CHANCE_HIGH
+		if(ishuman(src))
+			var/mob/living/carbon/human/holder = src
+			// the gun is slightly more secure in a holster
+			if(at_risk == holder.s_store)
+				chance_to_fire = GUN_NO_SAFETY_MALFUNCTION_CHANCE_MEDIUM
+		if(at_risk.safety == FALSE && prob(chance_to_fire))
+			if(at_risk.process_fire(src,src,FALSE, null,  pick(BODY_ZONE_L_LEG,BODY_ZONE_R_LEG)) == TRUE)
+				visible_message(span_danger("\The [at_risk.name]'s trigger gets caught as [src] falls, suddenly going off into [src]'s leg! Should have had the safeties on."), span_danger("\The [at_risk.name]'s trigger gets caught on something as you fall, suddenly going off into your leg without it's safeties on!"))
+				emote("scream")
+
 //I need to refactor this into an attachment
 /datum/action/toggle_scope_zoom
 	name = "Toggle Scope"

code/modules/projectiles/guns/ballistic.dm

@@ -373,3 +373,8 @@ GLOBAL_LIST_INIT(gun_saw_types, typecacheof(list(
 		if(AC.BB)
 			process_fire(user, user, FALSE)
 			. = TRUE
+
+/obj/item/gun/ballistic/unsafe_shot(target, empty_chamber = TRUE)
+	. = ..()
+	process_chamber(empty_chamber,TRUE)
+

code/modules/projectiles/guns/energy.dm

@@ -39,6 +39,8 @@
 /obj/item/gun/energy/emp_act(severity)
 	. = ..()
 	if(!(. & EMP_PROTECT_CONTENTS))
+		if(prob(GUN_NO_SAFETY_MALFUNCTION_CHANCE_HIGH))
+			discharge("malfuctions from the EMP")
 		cell.use(round(cell.charge / severity))
 		chambered = null //we empty the chamber
 		recharge_newshot() //and try to charge a new shot
@@ -323,3 +325,7 @@
 		. += "\The [name] has [round(cell.charge/shot.e_cost)] shots remaining on <b>[shot.select_name]</b> mode."
 	else
 		. += span_notice("\The [name] doesn't seem to have a cell!")
+
+/obj/item/gun/energy/unsafe_shot(target)
+	. = ..()
+	process_chamber()

code/modules/shuttle/on_move.dm

@@ -291,6 +291,7 @@ All ShuttleMove procs go here
 
 /************************************Item move procs************************************/
 
+
 /obj/item/storage/pod/afterShuttleMove(turf/oldT, list/movement_force, shuttle_dir, shuttle_preferred_direction, move_dir, rotation)
 	. = ..()
 	// If the pod was launched, the storage will always open. The reserved_level check
@@ -299,6 +300,17 @@ All ShuttleMove procs go here
 	if (oldT && !is_reserved_level(oldT))
 		unlocked = TRUE
 
+/obj/item/gun/lateShuttleMove(turf/oldT, list/movement_force, move_dir)
+	. = ..()
+	if(prob(GUN_NO_SAFETY_MALFUNCTION_CHANCE_HIGH))
+		discharge("is thrown around by the force of the take off")
+
+/obj/item/lateShuttleMove(turf/oldT, list/movement_force, move_dir)
+	. = ..()
+	for(var/obj/item/gun/at_risk in get_all_contents())
+		if(at_risk.safety == FALSE && prob(GUN_NO_SAFETY_MALFUNCTION_CHANCE_HIGH))
+			at_risk.discharge("is thrown around by the force of the take off")
+
 /************************************Mob move procs************************************/
 
 /mob/onShuttleMove(turf/newT, turf/oldT, list/movement_force, move_dir, obj/docking_port/stationary/old_dock, obj/docking_port/mobile/moving_dock, list/obj/docking_port/mobile/towed_shuttles)
@@ -325,6 +337,7 @@ All ShuttleMove procs go here
 	var/knockdown = movement_force["KNOCKDOWN"]
 	if(knockdown)
 		Paralyze(knockdown)
+		trip_with_gun()
 
 
 /mob/living/simple_animal/hostile/megafauna/onShuttleMove(turf/newT, turf/oldT, list/movement_force, move_dir, obj/docking_port/stationary/old_dock, obj/docking_port/mobile/moving_dock, list/obj/docking_port/mobile/towed_shuttles)