add a simple warning system

.github/workflows/test-basic-1.yaml

@@ -25,6 +25,7 @@ jobs:
       with:
         name: tek
         signingKey: '${{ secrets.CACHIX_SIGNING_KEY }}'
+    - run: rm -rf /opt/hostedtoolcache
     - run: git config --global user.name hix
     - run: git config --global user.email [email protected]
     - run: nix run .#test-basic-1

.github/workflows/test-basic-2.yaml

@@ -23,6 +23,7 @@ jobs:
       with:
         name: tek
         signingKey: '${{ secrets.CACHIX_SIGNING_KEY }}'
+    - run: rm -rf /opt/hostedtoolcache
     - run: git config --global user.name hix
     - run: git config --global user.email [email protected]
     - run: nix run .#test-basic-2

.github/workflows/test-basic-3.yaml

@@ -23,6 +23,7 @@ jobs:
       with:
         name: tek
         signingKey: '${{ secrets.CACHIX_SIGNING_KEY }}'
+    - run: rm -rf /opt/hostedtoolcache
     - run: git config --global user.name hix
     - run: git config --global user.email [email protected]
     - run: nix run .#test-basic-3

.github/workflows/test-managed.yaml

@@ -23,6 +23,7 @@ jobs:
       with:
         name: tek
         signingKey: '${{ secrets.CACHIX_SIGNING_KEY }}'
+    - run: rm -rf /opt/hostedtoolcache
     - run: git config --global user.name hix
     - run: git config --global user.email [email protected]
     - run: nix run .#test-managed

lib/doc/chapters.nix

@@ -69,6 +69,8 @@
 
   mod-managed = options.moduleWithout [] "managed" { inherit config lib util; };
 
+  mod-ui = options.module "ui" { inherit config lib util; inherit (util) outputs; };
+
   generalModules = [
     (options.importMod "systems" { inherit config lib; })
     (options.importMod "system" { inherit config lib; })
@@ -113,6 +115,8 @@
         (opt "package" "Package" mod-package)
         (opt "general" "General" mod-general)
         (text prose.ifd)
+        (text prose.ui)
+        (opt "ui" "UI" mod-ui)
       ];
     }
     {

lib/doc/prose.nix

@@ -431,6 +431,12 @@ in {
   exposed.
   '';
 
+  ui = ''
+  ## User Interface {#ui}
+
+  Options for UI behavior:
+  '';
+
   environments = ''
   ## Environments {#envs}
 

lib/internal/warn.nix

@@ -0,0 +1,51 @@
+{util}: let
+
+  inherit (util) config lib;
+  inherit (util.console) chevrons bold;
+  inherit (util.console.s) colors;
+
+  inherit (config.ui.warnings) all keys;
+
+  enabled = key: keys.${key} or all;
+
+  warnWith = handler: key: message:
+  handler (enabled key) ''
+  ${message}
+  Disable this warning by setting ${bold (colors.yellow ''ui.warnings.keys."${key}" = false;'')}
+  '';
+
+  deprecatedWith = handler: key: desc: replacement: let
+    suggestion = if replacement == null then "" else " in favor of ${colors.blue replacement}";
+    message = "${desc} is deprecated${suggestion}.";
+  in warnWith handler "deprecated.${key}" message;
+
+  appHandler = exe: isEnabled: message: let
+    warning = config.pkgs.writeText "hix-warning" ''
+    ${chevrons} Warning: ${message}
+    '';
+    wrapped =
+      if isEnabled
+      then util.script "hix-warn-wrapper" ''
+      echo -e "$(cat ${warning})"
+      exec ${exe}
+      ''
+      else exe
+      ;
+  in util.app wrapped;
+
+  warnEval = warnWith lib.warnIf;
+
+  deprecatedOutput = category: name:
+  warnEval "${category}.${name}" "The ${category} .#${name}";
+
+  deprecatedApp = name: replacement: exe:
+  deprecatedWith (appHandler exe) "app.${name}" "The app ${colors.blue ".#${name}"}" replacement;
+
+in {
+  inherit
+  warnWith
+  deprecatedWith
+  deprecatedOutput
+  deprecatedApp
+  ;
+}

lib/outputs/hpack.nix

@@ -1,12 +1,12 @@
 {util}: let
 
-  inherit (util) config;
+  inherit (util) config internal;
 
 in {
 
   legacyApps = {
-    hpack = config.hpack.script;
-    hpack-quiet = config.hpack.scriptQuiet;
+    hpack = internal.warn.deprecatedApp "hpack" ".#gen-cabal" config.hpack.script;
+    hpack-quiet = internal.warn.deprecatedApp "hpack-quiet" ".#gen-cabal-quiet" config.hpack.scriptQuiet;
   };
 
 }

modules/all-modules.nix

@@ -17,6 +17,7 @@ let
     ./hackage.nix
     ./cli.nix
     ./managed.nix
+    ./ui.nix
     inputsConfig
   ];
 

modules/ui.nix

@@ -0,0 +1,34 @@
+{ lib, ... }: let
+
+  inherit (lib) types;
+
+in {
+
+  options = {
+
+    ui.warnings = {
+
+      all = lib.mkOption {
+        description = ''
+        Whether to enable all warnings.
+        Set this to `false` to suppress all warnings and use [](#opt-ui-ui.warnings.keys) to enable them
+        selectively.
+        '';
+        type = types.bool;
+        default = true;
+      };
+
+      keys = lib.mkOption {
+        description = ''
+        The set of warnings that should be enabled or disabled individually.
+        Keys are warning IDs and values are booleans, where `true` enables a warning and `false` disables it.
+        If a key is not present in this set, the warning is printed if [](#opt-ui-ui.warnings.all) is `true`.
+        '';
+        type = types.attrsOf types.bool;
+        default = {};
+      };
+    };
+
+  };
+
+}