nixos/games: init

hosts/miku-nixos/default.nix

@@ -11,14 +11,14 @@ in
   imports = [
     ./hardware-configuration.nix
     ../../nixos
-    ../../nixos/games.nix
     inputs.hardware.nixosModules.common-cpu-intel
   ];
 
   nixos = {
     audio.lowLatency.enable = true;
     cross-compiling.enable = true;
     dev.enable = true;
+    games.enable = true;
     server = {
       plex.enable = true;
       rtorrent.enable = true;

hosts/sankyuu-nixos/default.nix

@@ -2,7 +2,7 @@
 # your system.  Help is available in the configuration.nix(5) man page
 # and in the NixOS manual (accessible by running ‘nixos-help’).
 
-{ config, pkgs, flake, lib, ... }:
+{ config, pkgs, flake, ... }:
 
 let
   inherit (flake) inputs;
@@ -11,7 +11,6 @@ in
   imports = [
     ./hardware-configuration.nix
     ../../nixos
-    ../../nixos/games.nix
     inputs.hardware.nixosModules.lenovo-thinkpad-t14-amd-gen1
   ];
 
@@ -55,6 +54,10 @@ in
       # The audio device from this notebook doesn't seem to like short buffers too much
       quantum = 128;
     };
+    games = {
+      enable = true;
+      gpu = "amd";
+    };
     laptop.tlp = {
       cpuFreqGovernor = "schedutil";
       batteryThreshold = {
@@ -67,9 +70,6 @@ in
   programs.steam.gamescopeSession.args = [
     "-w 1600"
     "-h 900"
-    "--fsr-sharpness 10"
-    "-U"
-    "--adaptive-sync"
   ];
 
   # Used for firmware updates

nixos/default.nix

@@ -7,6 +7,7 @@
     ./desktop
     ./dev
     ./fonts.nix
+    ./games
     ./home.nix
     ./laptop
     ./minimal.nix

nixos/games/corectrl.nix

@@ -0,0 +1,21 @@
+{ lib, config, ... }:
+
+let
+  inherit (config.meta) username;
+  cfg = config.nixos.games.corectrl;
+in
+{
+  options.nixos.games.corectrl.enable = lib.mkEnableOption "corectrl config" // {
+    default = config.nixos.games.enable && (config.nixos.games.gpu == "amd");
+  };
+
+  config = lib.mkIf cfg.enable {
+    programs.corectrl = {
+      enable = true;
+      gpuOverclock.enable = true;
+    };
+
+    # Added user to groups
+    users.users.${username}.extraGroups = [ "corectrl" ];
+  };
+}

nixos/games/default.nix

@@ -0,0 +1,58 @@
+{ pkgs, lib, config, ... }:
+
+let
+  cfg = config.nixos.games;
+  nvidia-offload = lib.findFirst (p: lib.isDerivation p && p.name == "nvidia-offload")
+    null
+    config.environment.systemPackages;
+in
+{
+  imports = [
+    ./corectrl.nix
+    ./osu.nix
+    ./ratbag.nix
+    ./retroarch.nix
+    ./steam.nix
+  ];
+
+  options.nixos.games = {
+    enable = lib.mkEnableOption "games config";
+    gpu = lib.mkOption {
+      type = lib.types.nullOr (lib.types.enum [ "amd" "intel" "nvidia" ]);
+      default = null;
+      description = "GPU maker.";
+    };
+  };
+
+  config = lib.mkIf cfg.enable {
+    # Fix: MESA-INTEL: warning: Performance support disabled, consider sysctl dev.i915.perf_stream_paranoid=0
+    boot.kernelParams = lib.mkIf (cfg.gpu == "intel") [ "dev.i915.perf_stream_paranoid=0" ];
+
+    environment = {
+      systemPackages = with pkgs; [
+        lutris
+      ];
+
+      # Use nvidia-offload script in gamemode
+      variables.GAMEMODERUNEXEC = lib.mkIf (cfg.gpu == "nvidia" && nvidia-offload != null)
+        "${nvidia-offload}/bin/nvidia-offload";
+    };
+
+    programs.gamemode = {
+      enable = true;
+      settings = {
+        general = {
+          softrealtime = "auto";
+          renice = 10;
+        };
+        custom = {
+          start = "${pkgs.libnotify}/bin/notify-send 'GameMode started'";
+          end = "${pkgs.libnotify}/bin/notify-send 'GameMode ended'";
+        };
+      };
+    };
+
+    # Alternative driver for Xbox One/Series S/Series X controllers
+    hardware.xone.enable = true;
+  };
+}

nixos/games/osu.nix

@@ -0,0 +1,37 @@
+{ pkgs, lib, config, ... }:
+
+let
+  cfg = config.nixos.games.osu;
+in
+{
+  options.nixos.games.osu.enable = lib.mkEnableOption "osu! config" // {
+    default = config.nixos.games.enable;
+  };
+
+  config = lib.mkIf cfg.enable {
+    environment.systemPackages = with pkgs; let
+      import-osu-songs = pkgs.writeShellApplication {
+        name = "import-osu-songs";
+        runtimeInputs = [ pkgs.coreutils ];
+        text = ''
+          declare -r $osu_dir="$HOME/.osu"
+          if [[ ! -d "$osu_dir" ]]; then
+            >&2 echo "'$osu_dir' directory not found! Start 'osu-stable' once to create it."
+            exit 1
+          fi
+          declare -r osu_song_dir="$osu_dir/drive_c/osu/Songs"
+          mkdir -p "$osu_song_dir"
+          cp -v "''${@}" "$osu_song_dir"
+        '';
+      };
+    in
+    [
+      gaming.osu-lazer-bin
+      gaming.osu-stable
+      import-osu-songs
+    ];
+
+    # Enable opentabletdriver
+    hardware.opentabletdriver.enable = true;
+  };
+}

nixos/games/ratbag.nix

@@ -0,0 +1,17 @@
+{ pkgs, lib, config, ... }:
+
+let
+  cfg = config.nixos.games.ratbag;
+in
+{
+  options.nixos.games.ratbag.enable = lib.mkEnableOption "Ratbag/Piper (e.g. Logitech devices) config" // {
+    default = config.nixos.games.enable;
+  };
+
+  config = lib.mkIf cfg.enable {
+    environment.systemPackages = with pkgs; [ piper ];
+
+    # Enable ratbagd (i.e.: piper) for Logitech devices
+    services.ratbagd.enable = true;
+  };
+}

nixos/games/retroarch.nix

@@ -0,0 +1,26 @@
+{ pkgs, lib, config, ... }:
+
+let
+  cfg = config.nixos.games.retroarch;
+in
+{
+  options.nixos.games.retroarch = {
+    enable = lib.mkEnableOption "RetroArch config" // {
+      default = config.nixos.games.enable;
+    };
+    package = lib.mkPackageOption pkgs "retroarch" {
+      default = "retroarchFull";
+    };
+  };
+
+  config = lib.mkIf cfg.enable {
+    environment.systemPackages = [
+      cfg.package
+    ];
+
+    services.xserver.desktopManager.retroarch = {
+      enable = true;
+      package = cfg.package;
+    };
+  };
+}

nixos/games/steam.nix

@@ -0,0 +1,39 @@
+{ pkgs, lib, config, ... }:
+
+let
+  cfg = config.nixos.games.steam;
+in
+{
+  options.nixos.games.steam = {
+    enable = lib.mkEnableOption "Steam config" // {
+      default = config.nixos.games.enable;
+    };
+  };
+
+  config = lib.mkIf cfg.enable {
+    environment.systemPackages = with pkgs; [
+      gamescope
+      mangohud
+    ];
+
+    programs = {
+      gamescope = {
+        args = [ "--rt" ];
+        capSysNice = true;
+      };
+
+      steam = {
+        enable = true;
+        remotePlay.openFirewall = true;
+        gamescopeSession = {
+          enable = true;
+          args = [
+            "--fsr-sharpness 10"
+            "-U"
+            "--adaptive-sync"
+          ];
+        };
+      };
+    };
+  };
+}