bleep: init at 0.0.7

maintainers/maintainer-list.nix

@@ -10802,6 +10802,12 @@
     githubId = 4032;
     name = "Kristoffer Thømt Ravneberg";
   };
+  kristianan = {
+    email = "[email protected]";
+    github = "KristianAN";
+    githubId = 80984519;
+    name = "Kristian Alvestad Nedevold-Hansen";
+  };
   kristian-brucaj = {
     email = "[email protected]";
     github = "Flameslice";

pkgs/by-name/bl/bleep/package.nix

@@ -0,0 +1,75 @@
+{
+  stdenvNoCC,
+  fetchzip,
+  autoPatchelfHook,
+  installShellFiles,
+  makeWrapper,
+  lib,
+  zlib,
+}:
+let
+  platform =
+    {
+      x86_64-linux = "x86_64-pc-linux";
+      x86_64-darwin = "x86_64-apple-darwin";
+      aarch64-darwin = "arm64-apple-darwin";
+    }
+    ."${stdenvNoCC.system}" or (throw "unsupported system ${stdenvNoCC.hostPlatform.system}");
+
+  hash =
+    {
+      x86_64-linux = "sha256-dB8reN5rTlY5czFH7BaRya7qBa6czAIH2NkFWZh81ek=";
+      x86_64-darwin = "sha256-tpUcduCPCbVVaYZZOhWdPlN6SW3LGZPWSO9bDStVDms=";
+      aarch64-darwin = "sha256-V8QGF3Dpuy9I6CqKsJRHBHRdaLhc4XKZkv/rI7zs+qQ=";
+    }
+    ."${stdenvNoCC.system}" or (throw "unsupported system ${stdenvNoCC.hostPlatform.system}");
+in
+stdenvNoCC.mkDerivation (finalAttrs: {
+  pname = "bleep";
+  version = "0.0.7";
+
+  src = fetchzip {
+    url = "https://github.com/oyvindberg/bleep/releases/download/v${finalAttrs.version}/bleep-${platform}.tar.gz";
+    hash = hash;
+  };
+
+  nativeBuildInputs = [
+    installShellFiles
+    makeWrapper
+  ] ++ lib.optional stdenvNoCC.isLinux autoPatchelfHook;
+
+  buildInputs = [ zlib ];
+
+  installPhase = ''
+    runHook preInstall
+    install -Dm755 bleep -t $out/bin/
+    runHook postInstall
+  '';
+
+  dontAutoPatchelf = true;
+
+  postFixup =
+    lib.optionalString stdenvNoCC.isLinux ''
+      autoPatchelf $out
+    ''
+    + ''
+      export PATH=$PATH:$out/bin
+      installShellCompletion --cmd bleep \
+        --bash <(bleep install-tab-completions-bash --stdout) \
+        --zsh <(bleep install-tab-completions-zsh --stdout) \
+    '';
+
+  meta = {
+    homepage = "https://bleep.build/";
+    sourceProvenance = [ lib.sourceTypes.binaryNativeCode ];
+    license = lib.licenses.mit;
+    description = "Bleeping fast scala build tool";
+    mainProgram = "bleep";
+    platforms = [
+      "x86_64-linux"
+      "x86_64-darwin"
+      "aarch64-darwin"
+    ];
+    maintainers = with lib.maintainers; [ kristianan ];
+  };
+})