Windows GPU wheels

.ci/test_windows.ps1

@@ -48,8 +48,23 @@ elseif ($env:TASK -eq "sdist") {
   cp $env:BUILD_SOURCESDIRECTORY/build/lightgbmlib.jar $env:BUILD_ARTIFACTSTAGINGDIRECTORY/lightgbmlib_win.jar
 }
 elseif ($env:TASK -eq "bdist") {
+  # Install the Intel CPU runtime, so we can run tests against OpenCL
+  curl -o opencl_runtime_18.1_x64_setup.msi http://registrationcenter-download.intel.com/akdlm/irc_nas/vcp/13794/opencl_runtime_18.1_x64_setup.msi
+  $msiarglist = "/i opencl_runtime_18.1_x64_setup.msi /quiet /norestart /log msi.log"
+  $return = Start-Process msiexec -ArgumentList $msiarglist -Wait -passthru
+  Get-Content msi.log
+  If (@(0,3010) -contains $return.exitcode) {
+    Write-Output "OpenCL install successful"
+  } else {
+    Write-Output "OpenCL install failed, aborting"
+    exit 1
+  }
+  RefreshEnv
+  Write-Output "Current OpenCL drivers:"
+  Get-ItemProperty -Path Registry::HKEY_LOCAL_MACHINE\SOFTWARE\Khronos\OpenCL\Vendors
+
   cd $env:BUILD_SOURCESDIRECTORY/python-package
-  python setup.py bdist_wheel --plat-name=win-amd64 --universal ; Check-Output $?
+  python setup.py bdist_wheel --opencl-python-package --plat-name=win-amd64 --universal ; Check-Output $?
   cd dist; pip install @(Get-ChildItem *.whl) ; Check-Output $?
   cp @(Get-ChildItem *.whl) $env:BUILD_ARTIFACTSTAGINGDIRECTORY
 } elseif (($env:APPVEYOR -eq "true") -and ($env:TASK -eq "python")) {
@@ -69,6 +84,11 @@ if (($env:TASK -eq "sdist") -or (($env:APPVEYOR -eq "true") -and ($env:TASK -eq
 }
 pytest $tests ; Check-Output $?
 
+if ($env:TASK -eq "bdist") {
+  # Make sure we can do both CPU and GPU; see tests/python_package_test/test_dual.py
+  $env:LIGHTGBM_TEST_DUAL_CPU_GPU = "1"
+  pytest $env:BUILD_SOURCESDIRECTORY\tests\python_package_test\test_dual.py ; Check-Output $?
+}
 if (($env:TASK -eq "regular") -or (($env:APPVEYOR -eq "true") -and ($env:TASK -eq "python"))) {
   cd $env:BUILD_SOURCESDIRECTORY/examples/python-guide
   @("import matplotlib", "matplotlib.use('Agg')") + (Get-Content "plot_example.py") | Set-Content "plot_example.py"

CMakeLists.txt

@@ -1,4 +1,6 @@
-if(USE_GPU OR APPLE)
+if(__OPENCL_PYTHON_PACKAGE)
+  cmake_minimum_required(VERSION 3.11)
+elseif(USE_GPU OR APPLE)
   cmake_minimum_required(VERSION 3.2)
 else()
   cmake_minimum_required(VERSION 2.8)
@@ -20,6 +22,20 @@ if(APPLE)
     OPTION(APPLE_OUTPUT_DYLIB "Output dylib shared library" OFF)
 endif(APPLE)
 
+if(__OPENCL_PYTHON_PACKAGE)
+  set(__OPENCL_PYTHON_PACKAGE ON CACHE BOOL "" FORCE)
+  set(USE_GPU OFF CACHE BOOL "" FORCE)
+  set(USE_MPI OFF CACHE BOOL "")
+  set(USE_OPENMP ON CACHE BOOL "")
+  set(USE_SWIG OFF CACHE BOOL "")
+  set(USE_HDFS OFF CACHE BOOL "")
+  set(USE_R35 OFF CACHE BOOL "")
+  set(USE_TIMETAG OFF CACHE BOOL "")
+  set(USE_DEBUG OFF CACHE BOOL "")
+  set(BUILD_FOR_R OFF CACHE BOOL "")
+  message(WARNING "\nWARNING: building integrated OpenCL enabled components intended for Python package")
+endif()
+
 if(CMAKE_CXX_COMPILER_ID STREQUAL "GNU")
   if(CMAKE_CXX_COMPILER_VERSION VERSION_LESS "4.8.2")
     message(FATAL_ERROR "Insufficient gcc version")
@@ -123,6 +139,11 @@ if(USE_GPU)
     ADD_DEFINITIONS(-DUSE_GPU)
 endif(USE_GPU)
 
+if(__OPENCL_PYTHON_PACKAGE)
+    include(CMakeOpenCLPythonPackage.txt)
+    ADD_DEFINITIONS(-DUSE_GPU)
+endif()
+
 if(USE_HDFS)
     find_package(JNI REQUIRED)
     find_path(HDFS_INCLUDE_DIR hdfs.h REQUIRED)
@@ -246,7 +267,13 @@ else()
 endif(BUILD_STATIC_LIB)
 
 if(MSVC)
-    set_target_properties(_lightgbm PROPERTIES OUTPUT_NAME "lib_lightgbm")
+  set_target_properties(_lightgbm PROPERTIES OUTPUT_NAME "lib_lightgbm")
+  # TODO: use uniquely named dll (in setup.py, lightgbm/libpath.py) to avoid runtime conflicts
+  #if(__OPENCL_PYTHON_PACKAGE)
+  #  set_target_properties(_lightgbm PROPERTIES OUTPUT_NAME "lib_lightgbm-${OPENCL_PYTHON_PACKAGE_STAMP}")
+  #else()
+  #  set_target_properties(_lightgbm PROPERTIES OUTPUT_NAME "lib_lightgbm")
+  #endif()
 endif(MSVC)
 
 if(USE_SWIG)
@@ -303,16 +330,35 @@ if(USE_GPU)
   TARGET_LINK_LIBRARIES(_lightgbm ${OpenCL_LIBRARY} ${Boost_LIBRARIES})
 endif(USE_GPU)
 
+if(__OPENCL_PYTHON_PACKAGE)
+  # targets OpenCL and Boost are added in CMakeOpenCLPythonPackage.txt
+  add_dependencies(lightgbm OpenCL Boost)
+  add_dependencies(_lightgbm OpenCL Boost)
+  # variables OPENCL_PYTHON_PACKAGE_* are set in CMakeOpenCLPythonPackage.txt
+  target_include_directories(lightgbm PRIVATE ${OPENCL_PYTHON_PACKAGE_INCLUDES})
+  target_include_directories(_lightgbm PRIVATE ${OPENCL_PYTHON_PACKAGE_INCLUDES})
+  target_compile_definitions(lightgbm PRIVATE ${OPENCL_PYTHON_PACKAGE_DEFINITIONS})
+  target_compile_definitions(_lightgbm PRIVATE ${OPENCL_PYTHON_PACKAGE_DEFINITIONS})
+  target_link_libraries(lightgbm PRIVATE ${OPENCL_PYTHON_PACKAGE_LIBRARIES})
+  target_link_libraries(_lightgbm PRIVATE ${OPENCL_PYTHON_PACKAGE_LIBRARIES})
+endif()
+
 if(USE_HDFS)
   TARGET_LINK_LIBRARIES(lightgbm ${HDFS_CXX_LIBRARIES})
   TARGET_LINK_LIBRARIES(_lightgbm ${HDFS_CXX_LIBRARIES})
 endif(USE_HDFS)
 
-if(WIN32 AND (MINGW OR CYGWIN))
-    TARGET_LINK_LIBRARIES(lightgbm Ws2_32)
-    TARGET_LINK_LIBRARIES(_lightgbm Ws2_32)
-    TARGET_LINK_LIBRARIES(lightgbm IPHLPAPI)
-    TARGET_LINK_LIBRARIES(_lightgbm IPHLPAPI)
+if(WIN32)
+    if (MINGW OR CYGWIN)
+      TARGET_LINK_LIBRARIES(lightgbm Ws2_32)
+      TARGET_LINK_LIBRARIES(_lightgbm Ws2_32)
+      TARGET_LINK_LIBRARIES(lightgbm IPHLPAPI)
+      TARGET_LINK_LIBRARIES(_lightgbm IPHLPAPI)
+    endif()
+else()
+    if(__OPENCL_PYTHON_PACKAGE)
+      target_link_libraries(lightgbm PRIVATE pthread dl)
+    endif()
 endif()
 
 if(BUILD_FOR_R)

CMakeOpenCLPythonPackage.txt

@@ -0,0 +1,113 @@
+
+set(BUILD_SHARED_LIBS OFF CACHE BOOL "" FORCE)
+set(BOOST_VERSION_DOT "1.73")
+string(REPLACE "." "_" BOOST_VERSION_UNDERSCORE ${BOOST_VERSION_DOT})
+
+set(OPENCL_HEADER_REPOSITORY "https://github.com/KhronosGroup/OpenCL-Headers.git")
+set(OPENCL_HEADER_TAG "3f7c1f77f8e1a3c9b48765c713ca19013e95b91e")
+
+# FIXME -- remove reference to OpenCL ICD Loader fork after decision on whether or not to include Linux build
+#set(OPENCL_LOADER_REPOSITORY "https://github.com/KhronosGroup/OpenCL-ICD-Loader.git")
+#set(OPENCL_LOADER_TAG "bbdf079426d859fb8a68c332b41b714f9c87d6ad")
+set(OPENCL_LOADER_REPOSITORY "https://github.com/tpboudreau/OpenCL-ICD-Loader.git")
+set(OPENCL_LOADER_TAG "3d93e6b630a3592e4ab40f3fcc69a70d5ab8cc42")
+
+set(BOOST_REPOSITORY "https://github.com/boostorg/boost.git")
+set(BOOST_TAG "boost-${BOOST_VERSION_DOT}.0")
+execute_process(COMMAND git rev-parse HEAD WORKING_DIRECTORY ${PROJECT_SOURCE_DIR} OUTPUT_VARIABLE LIGHTGBM_TAG OUTPUT_STRIP_TRAILING_WHITESPACE ERROR_QUIET)
+string(SHA1 OPENCL_PYTHON_PACKAGE_STAMP "${OPENCL_HEADER_REPOSITORY}@${OPENCL_HEADER_TAG};${OPENCL_LOADER_REPOSITORY}@${OPENCL_LOADER_TAG};${BOOST_REPOSITORY}@${BOOST_TAG};lightgbm@${LIGHTGBM_TAG}")
+message(STATUS "OpenCL Python package build stamp: ${OPENCL_PYTHON_PACKAGE_STAMP}")
+
+# Build Independent OpenCL library
+include(FetchContent)
+FetchContent_Declare(OpenCL-Headers GIT_REPOSITORY ${OPENCL_HEADER_REPOSITORY} GIT_TAG ${OPENCL_HEADER_TAG})
+FetchContent_GetProperties(OpenCL-Headers)
+if(NOT OpenCL-Headers_POPULATED)
+  FetchContent_Populate(OpenCL-Headers)
+  message(STATUS "Populated OpenCL Headers")
+endif()
+set(OPENCL_ICD_LOADER_HEADERS_DIR ${opencl-headers_SOURCE_DIR} CACHE PATH "") # for OpenCL ICD Loader
+set(OpenCL_INCLUDE_DIR ${opencl-headers_SOURCE_DIR} CACHE PATH "") # for Boost::Compute
+
+FetchContent_Declare(OpenCL-ICD-Loader GIT_REPOSITORY ${OPENCL_LOADER_REPOSITORY} GIT_TAG ${OPENCL_LOADER_TAG})
+FetchContent_GetProperties(OpenCL-ICD-Loader)
+if(NOT OpenCL-ICD-Loader_POPULATED)
+  FetchContent_Populate(OpenCL-ICD-Loader)
+  if(WIN32)
+    set(USE_DYNAMIC_VCXX_RUNTIME ON)
+  else()
+    set(OPENCL_ICD_LOADER_PIC ON)
+  endif()
+  add_subdirectory(${opencl-icd-loader_SOURCE_DIR} ${opencl-icd-loader_BINARY_DIR} EXCLUDE_FROM_ALL)
+  message(STATUS "Populated OpenCL ICD Loader")
+endif()
+list(APPEND OPENCL_PYTHON_PACKAGE_INCLUDES ${OPENCL_ICD_LOADER_HEADERS_DIR})
+if(WIN32)
+  list(APPEND OPENCL_PYTHON_PACKAGE_LIBRARIES ${opencl-icd-loader_BINARY_DIR}/Release/OpenCL.lib cfgmgr32.lib runtimeobject.lib)
+else()
+  list(APPEND OPENCL_PYTHON_PACKAGE_LIBRARIES ${opencl-icd-loader_BINARY_DIR}/libOpenCL.a)
+endif()
+list(APPEND OPENCL_PYTHON_PACKAGE_DEFINITIONS CL_TARGET_OPENCL_VERSION=120)
+
+# Build Independent Boost libraries
+include(ExternalProject)
+include(ProcessorCount)
+ProcessorCount(J)
+set(BOOST_BASE "${PROJECT_BINARY_DIR}/Boost")
+if(WIN32)
+  set(BOOST_BOOTSTRAP "${BOOST_BASE}/source/bootstrap.bat")
+  set(BOOST_BUILD "${BOOST_BASE}/source/b2.exe")
+  set(BOOST_FLAGS "")
+  list(APPEND BOOST_SUBMODULES "libs/*" "tools/*")
+else()
+  set(BOOST_BOOTSTRAP "${BOOST_BASE}/source/bootstrap.sh")
+  set(BOOST_BUILD "${BOOST_BASE}/source/b2")
+  set(BOOST_FLAGS -fPIC)
+  list(APPEND BOOST_SUBMODULES "libs/compute" "libs/chrono" "libs/config" "libs/filesystem" "libs/headers" "libs/io" "libs/predef" "libs/system" "libs/uuid" "tools/*")
+endif()
+ExternalProject_Add(Boost
+  TMP_DIR "${BOOST_BASE}/tmp"
+  STAMP_DIR "${BOOST_BASE}/stamp"
+  DOWNLOAD_DIR "${BOOST_BASE}/download"
+  SOURCE_DIR "${BOOST_BASE}/source"
+  BINARY_DIR "${BOOST_BASE}/source"
+  INSTALL_DIR "${BOOST_BASE}/install"
+  GIT_REPOSITORY ${BOOST_REPOSITORY}
+  GIT_TAG ${BOOST_TAG}
+  GIT_SUBMODULES ${BOOST_SUBMODULES}
+  GIT_SHALLOW ON
+  UPDATE_COMMAND ""
+  PATCH_COMMAND ""
+  CONFIGURE_COMMAND ${BOOST_BOOTSTRAP}
+  BUILD_COMMAND ${BOOST_BUILD} -sBOOST_ROOT=${BOOST_BASE}/source -a -q -j ${J} --with-headers --with-chrono --with-filesystem --with-system link=static runtime-link=shared variant=release threading=multi cxxflags="${BOOST_FLAGS}"
+  INSTALL_COMMAND ""
+)
+set(BOOST_INCLUDE ${BOOST_BASE}/source CACHE PATH "")
+set(BOOST_LIBRARY ${BOOST_BASE}/source/stage/lib CACHE PATH "")
+list(APPEND OPENCL_PYTHON_PACKAGE_INCLUDES ${BOOST_INCLUDE})
+if(WIN32)
+  if(MSVC)
+    if(${MSVC_VERSION} GREATER 1929)
+      set(MSVC_TOOLCHAIN_ID "unknown")
+    elseif(${MSVC_VERSION} GREATER 1919)
+      set(MSVC_TOOLCHAIN_ID "142")
+    elseif(${MSVC_VERSION} GREATER 1909)
+      set(MSVC_TOOLCHAIN_ID "141")
+    elseif(${MSVC_VERSION} GREATER 1899)
+      set(MSVC_TOOLCHAIN_ID "140")
+    else()
+      set(MSVC_TOOLCHAIN_ID "unknown")
+    endif()
+    list(APPEND OPENCL_PYTHON_PACKAGE_LIBRARIES ${BOOST_LIBRARY}/libboost_filesystem-vc${MSVC_TOOLCHAIN_ID}-mt-x64-${BOOST_VERSION_UNDERSCORE}.lib)
+    list(APPEND OPENCL_PYTHON_PACKAGE_LIBRARIES ${BOOST_LIBRARY}/libboost_system-vc${MSVC_TOOLCHAIN_ID}-mt-x64-${BOOST_VERSION_UNDERSCORE}.lib)
+    list(APPEND OPENCL_PYTHON_PACKAGE_LIBRARIES ${BOOST_LIBRARY}/libboost_chrono-vc${MSVC_TOOLCHAIN_ID}-mt-x64-${BOOST_VERSION_UNDERSCORE}.lib)
+  else()
+    message(WARNING "MinGW Boost library names not yet specified")
+  endif()
+else()
+  list(APPEND OPENCL_PYTHON_PACKAGE_LIBRARIES ${BOOST_LIBRARY}/libboost_filesystem.a)
+  list(APPEND OPENCL_PYTHON_PACKAGE_LIBRARIES ${BOOST_LIBRARY}/libboost_system.a)
+endif()
+
+set(BUILD_SHARED_LIBS ON CACHE BOOL "" FORCE)
+